subroutine drotm	(	integer	N,
		double precision, dimension(*)	DX,
		integer	INCX,
		double precision, dimension(*)	DY,
		integer	INCY,
		double precision, dimension(5)	DPARAM
	)

DROTM

Purpose:

    APPLY THE MODIFIED GIVENS TRANSFORMATION, H, TO THE 2 BY N MATRIX

    (DX**T) , WHERE **T INDICATES TRANSPOSE. THE ELEMENTS OF DX ARE IN
    (DY**T)

    DX(LX+I*INCX), I = 0 TO N-1, WHERE LX = 1 IF INCX .GE. 0, ELSE
    LX = (-INCX)*N, AND SIMILARLY FOR SY USING LY AND INCY.
    WITH DPARAM(1)=DFLAG, H HAS ONE OF THE FOLLOWING FORMS..

    DFLAG=-1.D0     DFLAG=0.D0        DFLAG=1.D0     DFLAG=-2.D0

      (DH11  DH12)    (1.D0  DH12)    (DH11  1.D0)    (1.D0  0.D0)
    H=(          )    (          )    (          )    (          )
      (DH21  DH22),   (DH21  1.D0),   (-1.D0 DH22),   (0.D0  1.D0).
    SEE DROTMG FOR A DESCRIPTION OF DATA STORAGE IN DPARAM.

Parameters

[in]	N	N is INTEGER number of elements in input vector(s)
[in,out]	DX	DX is DOUBLE PRECISION array, dimension N double precision vector with N elements
[in]	INCX	INCX is INTEGER storage spacing between elements of DX
[in,out]	DY	DY is DOUBLE PRECISION array, dimension N double precision vector with N elements
[in]	INCY	INCY is INTEGER storage spacing between elements of DY
[in,out]	DPARAM	DPARAM is DOUBLE PRECISION array, dimension 5 DPARAM(1)=DFLAG DPARAM(2)=DH11 DPARAM(3)=DH21 DPARAM(4)=DH12 DPARAM(5)=DH22

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 100 of file drotm.f.

*
*  -- Reference BLAS level1 routine (version 3.4.0) --
*  -- Reference BLAS is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER incx,incy,n
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION dparam(5),dx(*),dy(*)
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      DOUBLE PRECISION dflag,dh11,dh12,dh21,dh22,two,w,z,zero
      INTEGER i,kx,ky,nsteps
*     ..
*     .. Data statements ..
      DATA zero,two/0.d0,2.d0/
*     ..
*
      dflag = dparam(1)
      IF (n.LE.0 .OR. (dflag+two.EQ.zero)) RETURN
      IF (incx.EQ.incy.AND.incx.GT.0) THEN
*
         nsteps = n*incx
         IF (dflag.LT.zero) THEN
            dh11 = dparam(2)
            dh12 = dparam(4)
            dh21 = dparam(3)
            dh22 = dparam(5)
            DO i = 1,nsteps,incx
               w = dx(i)
               z = dy(i)
               dx(i) = w*dh11 + z*dh12
               dy(i) = w*dh21 + z*dh22
            END DO
         ELSE IF (dflag.EQ.zero) THEN
            dh12 = dparam(4)
            dh21 = dparam(3)
            DO i = 1,nsteps,incx
               w = dx(i)
               z = dy(i)
               dx(i) = w + z*dh12
               dy(i) = w*dh21 + z
            END DO
         ELSE
            dh11 = dparam(2)
            dh22 = dparam(5)
            DO i = 1,nsteps,incx
               w = dx(i)
               z = dy(i)
               dx(i) = w*dh11 + z
               dy(i) = -w + dh22*z
            END DO
         END IF
      ELSE
         kx = 1
         ky = 1
         IF (incx.LT.0) kx = 1 + (1-n)*incx
         IF (incy.LT.0) ky = 1 + (1-n)*incy
*
         IF (dflag.LT.zero) THEN
            dh11 = dparam(2)
            dh12 = dparam(4)
            dh21 = dparam(3)
            dh22 = dparam(5)
            DO i = 1,n
               w = dx(kx)
               z = dy(ky)
               dx(kx) = w*dh11 + z*dh12
               dy(ky) = w*dh21 + z*dh22
               kx = kx + incx
               ky = ky + incy
            END DO
         ELSE IF (dflag.EQ.zero) THEN
            dh12 = dparam(4)
            dh21 = dparam(3)
            DO i = 1,n
               w = dx(kx)
               z = dy(ky)
               dx(kx) = w + z*dh12
               dy(ky) = w*dh21 + z
               kx = kx + incx
               ky = ky + incy
            END DO
         ELSE
             dh11 = dparam(2)
             dh22 = dparam(5)
             DO i = 1,n
                w = dx(kx)
                z = dy(ky)
                dx(kx) = w*dh11 + z
                dy(ky) = -w + dh22*z
                kx = kx + incx
                ky = ky + incy
            END DO
         END IF
      END IF
      RETURN

Here is the caller graph for this function: