LAPACK  3.6.1
LAPACK: Linear Algebra PACKage
subroutine ztgsna ( character  JOB,
character  HOWMNY,
logical, dimension( * )  SELECT,
integer  N,
complex*16, dimension( lda, * )  A,
integer  LDA,
complex*16, dimension( ldb, * )  B,
integer  LDB,
complex*16, dimension( ldvl, * )  VL,
integer  LDVL,
complex*16, dimension( ldvr, * )  VR,
integer  LDVR,
double precision, dimension( * )  S,
double precision, dimension( * )  DIF,
integer  MM,
integer  M,
complex*16, dimension( * )  WORK,
integer  LWORK,
integer, dimension( * )  IWORK,
integer  INFO 
)

ZTGSNA

Download ZTGSNA + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 ZTGSNA estimates reciprocal condition numbers for specified
 eigenvalues and/or eigenvectors of a matrix pair (A, B).

 (A, B) must be in generalized Schur canonical form, that is, A and
 B are both upper triangular.
Parameters
[in]JOB
          JOB is CHARACTER*1
          Specifies whether condition numbers are required for
          eigenvalues (S) or eigenvectors (DIF):
          = 'E': for eigenvalues only (S);
          = 'V': for eigenvectors only (DIF);
          = 'B': for both eigenvalues and eigenvectors (S and DIF).
[in]HOWMNY
          HOWMNY is CHARACTER*1
          = 'A': compute condition numbers for all eigenpairs;
          = 'S': compute condition numbers for selected eigenpairs
                 specified by the array SELECT.
[in]SELECT
          SELECT is LOGICAL array, dimension (N)
          If HOWMNY = 'S', SELECT specifies the eigenpairs for which
          condition numbers are required. To select condition numbers
          for the corresponding j-th eigenvalue and/or eigenvector,
          SELECT(j) must be set to .TRUE..
          If HOWMNY = 'A', SELECT is not referenced.
[in]N
          N is INTEGER
          The order of the square matrix pair (A, B). N >= 0.
[in]A
          A is COMPLEX*16 array, dimension (LDA,N)
          The upper triangular matrix A in the pair (A,B).
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A. LDA >= max(1,N).
[in]B
          B is COMPLEX*16 array, dimension (LDB,N)
          The upper triangular matrix B in the pair (A, B).
[in]LDB
          LDB is INTEGER
          The leading dimension of the array B. LDB >= max(1,N).
[in]VL
          VL is COMPLEX*16 array, dimension (LDVL,M)
          IF JOB = 'E' or 'B', VL must contain left eigenvectors of
          (A, B), corresponding to the eigenpairs specified by HOWMNY
          and SELECT.  The eigenvectors must be stored in consecutive
          columns of VL, as returned by ZTGEVC.
          If JOB = 'V', VL is not referenced.
[in]LDVL
          LDVL is INTEGER
          The leading dimension of the array VL. LDVL >= 1; and
          If JOB = 'E' or 'B', LDVL >= N.
[in]VR
          VR is COMPLEX*16 array, dimension (LDVR,M)
          IF JOB = 'E' or 'B', VR must contain right eigenvectors of
          (A, B), corresponding to the eigenpairs specified by HOWMNY
          and SELECT.  The eigenvectors must be stored in consecutive
          columns of VR, as returned by ZTGEVC.
          If JOB = 'V', VR is not referenced.
[in]LDVR
          LDVR is INTEGER
          The leading dimension of the array VR. LDVR >= 1;
          If JOB = 'E' or 'B', LDVR >= N.
[out]S
          S is DOUBLE PRECISION array, dimension (MM)
          If JOB = 'E' or 'B', the reciprocal condition numbers of the
          selected eigenvalues, stored in consecutive elements of the
          array.
          If JOB = 'V', S is not referenced.
[out]DIF
          DIF is DOUBLE PRECISION array, dimension (MM)
          If JOB = 'V' or 'B', the estimated reciprocal condition
          numbers of the selected eigenvectors, stored in consecutive
          elements of the array.
          If the eigenvalues cannot be reordered to compute DIF(j),
          DIF(j) is set to 0; this can only occur when the true value
          would be very small anyway.
          For each eigenvalue/vector specified by SELECT, DIF stores
          a Frobenius norm-based estimate of Difl.
          If JOB = 'E', DIF is not referenced.
[in]MM
          MM is INTEGER
          The number of elements in the arrays S and DIF. MM >= M.
[out]M
          M is INTEGER
          The number of elements of the arrays S and DIF used to store
          the specified condition numbers; for each selected eigenvalue
          one element is used. If HOWMNY = 'A', M is set to N.
[out]WORK
          WORK is COMPLEX*16 array, dimension (MAX(1,LWORK))
          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
[in]LWORK
          LWORK is INTEGER
          The dimension of the array WORK. LWORK >= max(1,N).
          If JOB = 'V' or 'B', LWORK >= max(1,2*N*N).
[out]IWORK
          IWORK is INTEGER array, dimension (N+2)
          If JOB = 'E', IWORK is not referenced.
[out]INFO
          INFO is INTEGER
          = 0: Successful exit
          < 0: If INFO = -i, the i-th argument had an illegal value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
November 2011
Further Details:
  The reciprocal of the condition number of the i-th generalized
  eigenvalue w = (a, b) is defined as

          S(I) = (|v**HAu|**2 + |v**HBu|**2)**(1/2) / (norm(u)*norm(v))

  where u and v are the right and left eigenvectors of (A, B)
  corresponding to w; |z| denotes the absolute value of the complex
  number, and norm(u) denotes the 2-norm of the vector u. The pair
  (a, b) corresponds to an eigenvalue w = a/b (= v**HAu/v**HBu) of the
  matrix pair (A, B). If both a and b equal zero, then (A,B) is
  singular and S(I) = -1 is returned.

  An approximate error bound on the chordal distance between the i-th
  computed generalized eigenvalue w and the corresponding exact
  eigenvalue lambda is

          chord(w, lambda) <=   EPS * norm(A, B) / S(I),

  where EPS is the machine precision.

  The reciprocal of the condition number of the right eigenvector u
  and left eigenvector v corresponding to the generalized eigenvalue w
  is defined as follows. Suppose

                   (A, B) = ( a   *  ) ( b  *  )  1
                            ( 0  A22 ),( 0 B22 )  n-1
                              1  n-1     1 n-1

  Then the reciprocal condition number DIF(I) is

          Difl[(a, b), (A22, B22)]  = sigma-min( Zl )

  where sigma-min(Zl) denotes the smallest singular value of

         Zl = [ kron(a, In-1) -kron(1, A22) ]
              [ kron(b, In-1) -kron(1, B22) ].

  Here In-1 is the identity matrix of size n-1 and X**H is the conjugate
  transpose of X. kron(X, Y) is the Kronecker product between the
  matrices X and Y.

  We approximate the smallest singular value of Zl with an upper
  bound. This is done by ZLATDF.

  An approximate error bound for a computed eigenvector VL(i) or
  VR(i) is given by

                      EPS * norm(A, B) / DIF(i).

  See ref. [2-3] for more details and further references.
Contributors:
Bo Kagstrom and Peter Poromaa, Department of Computing Science, Umea University, S-901 87 Umea, Sweden.
References:
  [1] B. Kagstrom; A Direct Method for Reordering Eigenvalues in the
      Generalized Real Schur Form of a Regular Matrix Pair (A, B), in
      M.S. Moonen et al (eds), Linear Algebra for Large Scale and
      Real-Time Applications, Kluwer Academic Publ. 1993, pp 195-218.

  [2] B. Kagstrom and P. Poromaa; Computing Eigenspaces with Specified
      Eigenvalues of a Regular Matrix Pair (A, B) and Condition
      Estimation: Theory, Algorithms and Software, Report
      UMINF - 94.04, Department of Computing Science, Umea University,
      S-901 87 Umea, Sweden, 1994. Also as LAPACK Working Note 87.
      To appear in Numerical Algorithms, 1996.

  [3] B. Kagstrom and P. Poromaa, LAPACK-Style Algorithms and Software
      for Solving the Generalized Sylvester Equation and Estimating the
      Separation between Regular Matrix Pairs, Report UMINF - 93.23,
      Department of Computing Science, Umea University, S-901 87 Umea,
      Sweden, December 1993, Revised April 1994, Also as LAPACK Working
      Note 75.
      To appear in ACM Trans. on Math. Software, Vol 22, No 1, 1996.

Definition at line 313 of file ztgsna.f.

313 *
314 * -- LAPACK computational routine (version 3.4.0) --
315 * -- LAPACK is a software package provided by Univ. of Tennessee, --
316 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
317 * November 2011
318 *
319 * .. Scalar Arguments ..
320  CHARACTER howmny, job
321  INTEGER info, lda, ldb, ldvl, ldvr, lwork, m, mm, n
322 * ..
323 * .. Array Arguments ..
324  LOGICAL select( * )
325  INTEGER iwork( * )
326  DOUBLE PRECISION dif( * ), s( * )
327  COMPLEX*16 a( lda, * ), b( ldb, * ), vl( ldvl, * ),
328  $ vr( ldvr, * ), work( * )
329 * ..
330 *
331 * =====================================================================
332 *
333 * .. Parameters ..
334  DOUBLE PRECISION zero, one
335  INTEGER idifjb
336  parameter ( zero = 0.0d+0, one = 1.0d+0, idifjb = 3 )
337 * ..
338 * .. Local Scalars ..
339  LOGICAL lquery, somcon, wantbh, wantdf, wants
340  INTEGER i, ierr, ifst, ilst, k, ks, lwmin, n1, n2
341  DOUBLE PRECISION bignum, cond, eps, lnrm, rnrm, scale, smlnum
342  COMPLEX*16 yhax, yhbx
343 * ..
344 * .. Local Arrays ..
345  COMPLEX*16 dummy( 1 ), dummy1( 1 )
346 * ..
347 * .. External Functions ..
348  LOGICAL lsame
349  DOUBLE PRECISION dlamch, dlapy2, dznrm2
350  COMPLEX*16 zdotc
351  EXTERNAL lsame, dlamch, dlapy2, dznrm2, zdotc
352 * ..
353 * .. External Subroutines ..
354  EXTERNAL dlabad, xerbla, zgemv, zlacpy, ztgexc, ztgsyl
355 * ..
356 * .. Intrinsic Functions ..
357  INTRINSIC abs, dcmplx, max
358 * ..
359 * .. Executable Statements ..
360 *
361 * Decode and test the input parameters
362 *
363  wantbh = lsame( job, 'B' )
364  wants = lsame( job, 'E' ) .OR. wantbh
365  wantdf = lsame( job, 'V' ) .OR. wantbh
366 *
367  somcon = lsame( howmny, 'S' )
368 *
369  info = 0
370  lquery = ( lwork.EQ.-1 )
371 *
372  IF( .NOT.wants .AND. .NOT.wantdf ) THEN
373  info = -1
374  ELSE IF( .NOT.lsame( howmny, 'A' ) .AND. .NOT.somcon ) THEN
375  info = -2
376  ELSE IF( n.LT.0 ) THEN
377  info = -4
378  ELSE IF( lda.LT.max( 1, n ) ) THEN
379  info = -6
380  ELSE IF( ldb.LT.max( 1, n ) ) THEN
381  info = -8
382  ELSE IF( wants .AND. ldvl.LT.n ) THEN
383  info = -10
384  ELSE IF( wants .AND. ldvr.LT.n ) THEN
385  info = -12
386  ELSE
387 *
388 * Set M to the number of eigenpairs for which condition numbers
389 * are required, and test MM.
390 *
391  IF( somcon ) THEN
392  m = 0
393  DO 10 k = 1, n
394  IF( SELECT( k ) )
395  $ m = m + 1
396  10 CONTINUE
397  ELSE
398  m = n
399  END IF
400 *
401  IF( n.EQ.0 ) THEN
402  lwmin = 1
403  ELSE IF( lsame( job, 'V' ) .OR. lsame( job, 'B' ) ) THEN
404  lwmin = 2*n*n
405  ELSE
406  lwmin = n
407  END IF
408  work( 1 ) = lwmin
409 *
410  IF( mm.LT.m ) THEN
411  info = -15
412  ELSE IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
413  info = -18
414  END IF
415  END IF
416 *
417  IF( info.NE.0 ) THEN
418  CALL xerbla( 'ZTGSNA', -info )
419  RETURN
420  ELSE IF( lquery ) THEN
421  RETURN
422  END IF
423 *
424 * Quick return if possible
425 *
426  IF( n.EQ.0 )
427  $ RETURN
428 *
429 * Get machine constants
430 *
431  eps = dlamch( 'P' )
432  smlnum = dlamch( 'S' ) / eps
433  bignum = one / smlnum
434  CALL dlabad( smlnum, bignum )
435  ks = 0
436  DO 20 k = 1, n
437 *
438 * Determine whether condition numbers are required for the k-th
439 * eigenpair.
440 *
441  IF( somcon ) THEN
442  IF( .NOT.SELECT( k ) )
443  $ GO TO 20
444  END IF
445 *
446  ks = ks + 1
447 *
448  IF( wants ) THEN
449 *
450 * Compute the reciprocal condition number of the k-th
451 * eigenvalue.
452 *
453  rnrm = dznrm2( n, vr( 1, ks ), 1 )
454  lnrm = dznrm2( n, vl( 1, ks ), 1 )
455  CALL zgemv( 'N', n, n, dcmplx( one, zero ), a, lda,
456  $ vr( 1, ks ), 1, dcmplx( zero, zero ), work, 1 )
457  yhax = zdotc( n, work, 1, vl( 1, ks ), 1 )
458  CALL zgemv( 'N', n, n, dcmplx( one, zero ), b, ldb,
459  $ vr( 1, ks ), 1, dcmplx( zero, zero ), work, 1 )
460  yhbx = zdotc( n, work, 1, vl( 1, ks ), 1 )
461  cond = dlapy2( abs( yhax ), abs( yhbx ) )
462  IF( cond.EQ.zero ) THEN
463  s( ks ) = -one
464  ELSE
465  s( ks ) = cond / ( rnrm*lnrm )
466  END IF
467  END IF
468 *
469  IF( wantdf ) THEN
470  IF( n.EQ.1 ) THEN
471  dif( ks ) = dlapy2( abs( a( 1, 1 ) ), abs( b( 1, 1 ) ) )
472  ELSE
473 *
474 * Estimate the reciprocal condition number of the k-th
475 * eigenvectors.
476 *
477 * Copy the matrix (A, B) to the array WORK and move the
478 * (k,k)th pair to the (1,1) position.
479 *
480  CALL zlacpy( 'Full', n, n, a, lda, work, n )
481  CALL zlacpy( 'Full', n, n, b, ldb, work( n*n+1 ), n )
482  ifst = k
483  ilst = 1
484 *
485  CALL ztgexc( .false., .false., n, work, n, work( n*n+1 ),
486  $ n, dummy, 1, dummy1, 1, ifst, ilst, ierr )
487 *
488  IF( ierr.GT.0 ) THEN
489 *
490 * Ill-conditioned problem - swap rejected.
491 *
492  dif( ks ) = zero
493  ELSE
494 *
495 * Reordering successful, solve generalized Sylvester
496 * equation for R and L,
497 * A22 * R - L * A11 = A12
498 * B22 * R - L * B11 = B12,
499 * and compute estimate of Difl[(A11,B11), (A22, B22)].
500 *
501  n1 = 1
502  n2 = n - n1
503  i = n*n + 1
504  CALL ztgsyl( 'N', idifjb, n2, n1, work( n*n1+n1+1 ),
505  $ n, work, n, work( n1+1 ), n,
506  $ work( n*n1+n1+i ), n, work( i ), n,
507  $ work( n1+i ), n, scale, dif( ks ), dummy,
508  $ 1, iwork, ierr )
509  END IF
510  END IF
511  END IF
512 *
513  20 CONTINUE
514  work( 1 ) = lwmin
515  RETURN
516 *
517 * End of ZTGSNA
518 *
subroutine zlacpy(UPLO, M, N, A, LDA, B, LDB)
ZLACPY copies all or part of one two-dimensional array to another.
Definition: zlacpy.f:105
double precision function dlamch(CMACH)
DLAMCH
Definition: dlamch.f:65
subroutine ztgexc(WANTQ, WANTZ, N, A, LDA, B, LDB, Q, LDQ, Z, LDZ, IFST, ILST, INFO)
ZTGEXC
Definition: ztgexc.f:202
subroutine zgemv(TRANS, M, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
ZGEMV
Definition: zgemv.f:160
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine dlabad(SMALL, LARGE)
DLABAD
Definition: dlabad.f:76
complex *16 function zdotc(N, ZX, INCX, ZY, INCY)
ZDOTC
Definition: zdotc.f:54
double precision function dznrm2(N, X, INCX)
DZNRM2
Definition: dznrm2.f:56
subroutine ztgsyl(TRANS, IJOB, M, N, A, LDA, B, LDB, C, LDC, D, LDD, E, LDE, F, LDF, SCALE, DIF, WORK, LWORK, IWORK, INFO)
ZTGSYL
Definition: ztgsyl.f:297
double precision function dlapy2(X, Y)
DLAPY2 returns sqrt(x2+y2).
Definition: dlapy2.f:65
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55

Here is the call graph for this function:

Here is the caller graph for this function: