LAPACK  3.6.1 LAPACK: Linear Algebra PACKage
 subroutine clatdf ( integer IJOB, integer N, complex, dimension( ldz, * ) Z, integer LDZ, complex, dimension( * ) RHS, real RDSUM, real RDSCAL, integer, dimension( * ) IPIV, integer, dimension( * ) JPIV )

CLATDF uses the LU factorization of the n-by-n matrix computed by sgetc2 and computes a contribution to the reciprocal Dif-estimate.

Purpose:
``` CLATDF computes the contribution to the reciprocal Dif-estimate
by solving for x in Z * x = b, where b is chosen such that the norm
of x is as large as possible. It is assumed that LU decomposition
of Z has been computed by CGETC2. On entry RHS = f holds the
contribution from earlier solved sub-systems, and on return RHS = x.

The factorization of Z returned by CGETC2 has the form
Z = P * L * U * Q, where P and Q are permutation matrices. L is lower
triangular with unit diagonal elements and U is upper triangular.```
Parameters
 [in] IJOB ``` IJOB is INTEGER IJOB = 2: First compute an approximative null-vector e of Z using CGECON, e is normalized and solve for Zx = +-e - f with the sign giving the greater value of 2-norm(x). About 5 times as expensive as Default. IJOB .ne. 2: Local look ahead strategy where all entries of the r.h.s. b is chosen as either +1 or -1. Default.``` [in] N ``` N is INTEGER The number of columns of the matrix Z.``` [in] Z ``` Z is COMPLEX array, dimension (LDZ, N) On entry, the LU part of the factorization of the n-by-n matrix Z computed by CGETC2: Z = P * L * U * Q``` [in] LDZ ``` LDZ is INTEGER The leading dimension of the array Z. LDA >= max(1, N).``` [in,out] RHS ``` RHS is COMPLEX array, dimension (N). On entry, RHS contains contributions from other subsystems. On exit, RHS contains the solution of the subsystem with entries according to the value of IJOB (see above).``` [in,out] RDSUM ``` RDSUM is REAL On entry, the sum of squares of computed contributions to the Dif-estimate under computation by CTGSYL, where the scaling factor RDSCAL (see below) has been factored out. On exit, the corresponding sum of squares updated with the contributions from the current sub-system. If TRANS = 'T' RDSUM is not touched. NOTE: RDSUM only makes sense when CTGSY2 is called by CTGSYL.``` [in,out] RDSCAL ``` RDSCAL is REAL On entry, scaling factor used to prevent overflow in RDSUM. On exit, RDSCAL is updated w.r.t. the current contributions in RDSUM. If TRANS = 'T', RDSCAL is not touched. NOTE: RDSCAL only makes sense when CTGSY2 is called by CTGSYL.``` [in] IPIV ``` IPIV is INTEGER array, dimension (N). The pivot indices; for 1 <= i <= N, row i of the matrix has been interchanged with row IPIV(i).``` [in] JPIV ``` JPIV is INTEGER array, dimension (N). The pivot indices; for 1 <= j <= N, column j of the matrix has been interchanged with column JPIV(j).```
Date
June 2016
Further Details:
This routine is a further developed implementation of algorithm BSOLVE in [1] using complete pivoting in the LU factorization.
Contributors:
Bo Kagstrom and Peter Poromaa, Department of Computing Science, Umea University, S-901 87 Umea, Sweden.
References:
[1] Bo Kagstrom and Lars Westin, Generalized Schur Methods with Condition Estimators for Solving the Generalized Sylvester Equation, IEEE Transactions on Automatic Control, Vol. 34, No. 7, July 1989, pp 745-751.

[2] Peter Poromaa, On Efficient and Robust Estimators for the Separation between two Regular Matrix Pairs with Applications in Condition Estimation. Report UMINF-95.05, Department of Computing Science, Umea University, S-901 87 Umea, Sweden,

Definition at line 171 of file clatdf.f.

171 *
172 * -- LAPACK auxiliary routine (version 3.6.1) --
173 * -- LAPACK is a software package provided by Univ. of Tennessee, --
174 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
175 * June 2016
176 *
177 * .. Scalar Arguments ..
178  INTEGER ijob, ldz, n
179  REAL rdscal, rdsum
180 * ..
181 * .. Array Arguments ..
182  INTEGER ipiv( * ), jpiv( * )
183  COMPLEX rhs( * ), z( ldz, * )
184 * ..
185 *
186 * =====================================================================
187 *
188 * .. Parameters ..
189  INTEGER maxdim
190  parameter ( maxdim = 2 )
191  REAL zero, one
192  parameter ( zero = 0.0e+0, one = 1.0e+0 )
193  COMPLEX cone
194  parameter ( cone = ( 1.0e+0, 0.0e+0 ) )
195 * ..
196 * .. Local Scalars ..
197  INTEGER i, info, j, k
198  REAL rtemp, scale, sminu, splus
199  COMPLEX bm, bp, pmone, temp
200 * ..
201 * .. Local Arrays ..
202  REAL rwork( maxdim )
203  COMPLEX work( 4*maxdim ), xm( maxdim ), xp( maxdim )
204 * ..
205 * .. External Subroutines ..
206  EXTERNAL caxpy, ccopy, cgecon, cgesc2, classq, claswp,
207  \$ cscal
208 * ..
209 * .. External Functions ..
210  REAL scasum
211  COMPLEX cdotc
212  EXTERNAL scasum, cdotc
213 * ..
214 * .. Intrinsic Functions ..
215  INTRINSIC abs, REAL, sqrt
216 * ..
217 * .. Executable Statements ..
218 *
219  IF( ijob.NE.2 ) THEN
220 *
221 * Apply permutations IPIV to RHS
222 *
223  CALL claswp( 1, rhs, ldz, 1, n-1, ipiv, 1 )
224 *
225 * Solve for L-part choosing RHS either to +1 or -1.
226 *
227  pmone = -cone
228  DO 10 j = 1, n - 1
229  bp = rhs( j ) + cone
230  bm = rhs( j ) - cone
231  splus = one
232 *
233 * Lockahead for L- part RHS(1:N-1) = +-1
234 * SPLUS and SMIN computed more efficiently than in BSOLVE[1].
235 *
236  splus = splus + REAL( CDOTC( N-J, Z( J+1, J ), 1, Z( J+1, \$ J ), 1 ) )
237  sminu = REAL( CDOTC( N-J, Z( J+1, J ), 1, RHS( J+1 ), 1 ) )
238  splus = splus*REAL( RHS( J ) )
239  IF( splus.GT.sminu ) THEN
240  rhs( j ) = bp
241  ELSE IF( sminu.GT.splus ) THEN
242  rhs( j ) = bm
243  ELSE
244 *
245 * In this case the updating sums are equal and we can
246 * choose RHS(J) +1 or -1. The first time this happens we
247 * choose -1, thereafter +1. This is a simple way to get
248 * good estimates of matrices like Byers well-known example
249 * (see [1]). (Not done in BSOLVE.)
250 *
251  rhs( j ) = rhs( j ) + pmone
252  pmone = cone
253  END IF
254 *
255 * Compute the remaining r.h.s.
256 *
257  temp = -rhs( j )
258  CALL caxpy( n-j, temp, z( j+1, j ), 1, rhs( j+1 ), 1 )
259  10 CONTINUE
260 *
261 * Solve for U- part, lockahead for RHS(N) = +-1. This is not done
262 * In BSOLVE and will hopefully give us a better estimate because
263 * any ill-conditioning of the original matrix is transfered to U
264 * and not to L. U(N, N) is an approximation to sigma_min(LU).
265 *
266  CALL ccopy( n-1, rhs, 1, work, 1 )
267  work( n ) = rhs( n ) + cone
268  rhs( n ) = rhs( n ) - cone
269  splus = zero
270  sminu = zero
271  DO 30 i = n, 1, -1
272  temp = cone / z( i, i )
273  work( i ) = work( i )*temp
274  rhs( i ) = rhs( i )*temp
275  DO 20 k = i + 1, n
276  work( i ) = work( i ) - work( k )*( z( i, k )*temp )
277  rhs( i ) = rhs( i ) - rhs( k )*( z( i, k )*temp )
278  20 CONTINUE
279  splus = splus + abs( work( i ) )
280  sminu = sminu + abs( rhs( i ) )
281  30 CONTINUE
282  IF( splus.GT.sminu )
283  \$ CALL ccopy( n, work, 1, rhs, 1 )
284 *
285 * Apply the permutations JPIV to the computed solution (RHS)
286 *
287  CALL claswp( 1, rhs, ldz, 1, n-1, jpiv, -1 )
288 *
289 * Compute the sum of squares
290 *
291  CALL classq( n, rhs, 1, rdscal, rdsum )
292  RETURN
293  END IF
294 *
295 * ENTRY IJOB = 2
296 *
297 * Compute approximate nullvector XM of Z
298 *
299  CALL cgecon( 'I', n, z, ldz, one, rtemp, work, rwork, info )
300  CALL ccopy( n, work( n+1 ), 1, xm, 1 )
301 *
302 * Compute RHS
303 *
304  CALL claswp( 1, xm, ldz, 1, n-1, ipiv, -1 )
305  temp = cone / sqrt( cdotc( n, xm, 1, xm, 1 ) )
306  CALL cscal( n, temp, xm, 1 )
307  CALL ccopy( n, xm, 1, xp, 1 )
308  CALL caxpy( n, cone, rhs, 1, xp, 1 )
309  CALL caxpy( n, -cone, xm, 1, rhs, 1 )
310  CALL cgesc2( n, z, ldz, rhs, ipiv, jpiv, scale )
311  CALL cgesc2( n, z, ldz, xp, ipiv, jpiv, scale )
312  IF( scasum( n, xp, 1 ).GT.scasum( n, rhs, 1 ) )
313  \$ CALL ccopy( n, xp, 1, rhs, 1 )
314 *
315 * Compute the sum of squares
316 *
317  CALL classq( n, rhs, 1, rdscal, rdsum )
318  RETURN
319 *
320 * End of CLATDF
321 *
322
real function scasum(N, CX, INCX)
SCASUM
Definition: scasum.f:54
subroutine classq(N, X, INCX, SCALE, SUMSQ)
CLASSQ updates a sum of squares represented in scaled form.
Definition: classq.f:108
subroutine cscal(N, CA, CX, INCX)
CSCAL
Definition: cscal.f:54
complex function cdotc(N, CX, INCX, CY, INCY)
CDOTC
Definition: cdotc.f:54
subroutine cgesc2(N, A, LDA, RHS, IPIV, JPIV, SCALE)
CGESC2 solves a system of linear equations using the LU factorization with complete pivoting computed...
Definition: cgesc2.f:117
subroutine ccopy(N, CX, INCX, CY, INCY)
CCOPY
Definition: ccopy.f:52
subroutine cgecon(NORM, N, A, LDA, ANORM, RCOND, WORK, RWORK, INFO)
CGECON
Definition: cgecon.f:126
subroutine caxpy(N, CA, CX, INCX, CY, INCY)
CAXPY
Definition: caxpy.f:53
subroutine claswp(N, A, LDA, K1, K2, IPIV, INCX)
CLASWP performs a series of row interchanges on a general rectangular matrix.
Definition: claswp.f:116

Here is the call graph for this function:

Here is the caller graph for this function: