 LAPACK  3.6.1 LAPACK: Linear Algebra PACKage
 subroutine slaqr0 ( logical WANTT, logical WANTZ, integer N, integer ILO, integer IHI, real, dimension( ldh, * ) H, integer LDH, real, dimension( * ) WR, real, dimension( * ) WI, integer ILOZ, integer IHIZ, real, dimension( ldz, * ) Z, integer LDZ, real, dimension( * ) WORK, integer LWORK, integer INFO )

SLAQR0 computes the eigenvalues of a Hessenberg matrix, and optionally the matrices from the Schur decomposition.

Purpose:
```    SLAQR0 computes the eigenvalues of a Hessenberg matrix H
and, optionally, the matrices T and Z from the Schur decomposition
H = Z T Z**T, where T is an upper quasi-triangular matrix (the
Schur form), and Z is the orthogonal matrix of Schur vectors.

Optionally Z may be postmultiplied into an input orthogonal
matrix Q so that this routine can give the Schur factorization
of a matrix A which has been reduced to the Hessenberg form H
by the orthogonal matrix Q:  A = Q*H*Q**T = (QZ)*T*(QZ)**T.```
Parameters
 [in] WANTT ``` WANTT is LOGICAL = .TRUE. : the full Schur form T is required; = .FALSE.: only eigenvalues are required.``` [in] WANTZ ``` WANTZ is LOGICAL = .TRUE. : the matrix of Schur vectors Z is required; = .FALSE.: Schur vectors are not required.``` [in] N ``` N is INTEGER The order of the matrix H. N .GE. 0.``` [in] ILO ` ILO is INTEGER` [in] IHI ``` IHI is INTEGER It is assumed that H is already upper triangular in rows and columns 1:ILO-1 and IHI+1:N and, if ILO.GT.1, H(ILO,ILO-1) is zero. ILO and IHI are normally set by a previous call to SGEBAL, and then passed to SGEHRD when the matrix output by SGEBAL is reduced to Hessenberg form. Otherwise, ILO and IHI should be set to 1 and N, respectively. If N.GT.0, then 1.LE.ILO.LE.IHI.LE.N. If N = 0, then ILO = 1 and IHI = 0.``` [in,out] H ``` H is REAL array, dimension (LDH,N) On entry, the upper Hessenberg matrix H. On exit, if INFO = 0 and WANTT is .TRUE., then H contains the upper quasi-triangular matrix T from the Schur decomposition (the Schur form); 2-by-2 diagonal blocks (corresponding to complex conjugate pairs of eigenvalues) are returned in standard form, with H(i,i) = H(i+1,i+1) and H(i+1,i)*H(i,i+1).LT.0. If INFO = 0 and WANTT is .FALSE., then the contents of H are unspecified on exit. (The output value of H when INFO.GT.0 is given under the description of INFO below.) This subroutine may explicitly set H(i,j) = 0 for i.GT.j and j = 1, 2, ... ILO-1 or j = IHI+1, IHI+2, ... N.``` [in] LDH ``` LDH is INTEGER The leading dimension of the array H. LDH .GE. max(1,N).``` [out] WR ` WR is REAL array, dimension (IHI)` [out] WI ``` WI is REAL array, dimension (IHI) The real and imaginary parts, respectively, of the computed eigenvalues of H(ILO:IHI,ILO:IHI) are stored in WR(ILO:IHI) and WI(ILO:IHI). If two eigenvalues are computed as a complex conjugate pair, they are stored in consecutive elements of WR and WI, say the i-th and (i+1)th, with WI(i) .GT. 0 and WI(i+1) .LT. 0. If WANTT is .TRUE., then the eigenvalues are stored in the same order as on the diagonal of the Schur form returned in H, with WR(i) = H(i,i) and, if H(i:i+1,i:i+1) is a 2-by-2 diagonal block, WI(i) = sqrt(-H(i+1,i)*H(i,i+1)) and WI(i+1) = -WI(i).``` [in] ILOZ ` ILOZ is INTEGER` [in] IHIZ ``` IHIZ is INTEGER Specify the rows of Z to which transformations must be applied if WANTZ is .TRUE.. 1 .LE. ILOZ .LE. ILO; IHI .LE. IHIZ .LE. N.``` [in,out] Z ``` Z is REAL array, dimension (LDZ,IHI) If WANTZ is .FALSE., then Z is not referenced. If WANTZ is .TRUE., then Z(ILO:IHI,ILOZ:IHIZ) is replaced by Z(ILO:IHI,ILOZ:IHIZ)*U where U is the orthogonal Schur factor of H(ILO:IHI,ILO:IHI). (The output value of Z when INFO.GT.0 is given under the description of INFO below.)``` [in] LDZ ``` LDZ is INTEGER The leading dimension of the array Z. if WANTZ is .TRUE. then LDZ.GE.MAX(1,IHIZ). Otherwize, LDZ.GE.1.``` [out] WORK ``` WORK is REAL array, dimension LWORK On exit, if LWORK = -1, WORK(1) returns an estimate of the optimal value for LWORK.``` [in] LWORK ``` LWORK is INTEGER The dimension of the array WORK. LWORK .GE. max(1,N) is sufficient, but LWORK typically as large as 6*N may be required for optimal performance. A workspace query to determine the optimal workspace size is recommended. If LWORK = -1, then SLAQR0 does a workspace query. In this case, SLAQR0 checks the input parameters and estimates the optimal workspace size for the given values of N, ILO and IHI. The estimate is returned in WORK(1). No error message related to LWORK is issued by XERBLA. Neither H nor Z are accessed.``` [out] INFO ``` INFO is INTEGER = 0: successful exit .GT. 0: if INFO = i, SLAQR0 failed to compute all of the eigenvalues. Elements 1:ilo-1 and i+1:n of WR and WI contain those eigenvalues which have been successfully computed. (Failures are rare.) If INFO .GT. 0 and WANT is .FALSE., then on exit, the remaining unconverged eigenvalues are the eigen- values of the upper Hessenberg matrix rows and columns ILO through INFO of the final, output value of H. If INFO .GT. 0 and WANTT is .TRUE., then on exit (*) (initial value of H)*U = U*(final value of H) where U is an orthogonal matrix. The final value of H is upper Hessenberg and quasi-triangular in rows and columns INFO+1 through IHI. If INFO .GT. 0 and WANTZ is .TRUE., then on exit (final value of Z(ILO:IHI,ILOZ:IHIZ) = (initial value of Z(ILO:IHI,ILOZ:IHIZ)*U where U is the orthogonal matrix in (*) (regard- less of the value of WANTT.) If INFO .GT. 0 and WANTZ is .FALSE., then Z is not accessed.```
Date
September 2012
Contributors:
Karen Braman and Ralph Byers, Department of Mathematics, University of Kansas, USA
References:
K. Braman, R. Byers and R. Mathias, The Multi-Shift QR Algorithm Part I: Maintaining Well Focused Shifts, and Level 3 Performance, SIAM Journal of Matrix Analysis, volume 23, pages 929–947, 2002.
K. Braman, R. Byers and R. Mathias, The Multi-Shift QR Algorithm Part II: Aggressive Early Deflation, SIAM Journal of Matrix Analysis, volume 23, pages 948–973, 2002.

Definition at line 258 of file slaqr0.f.

258 *
259 * -- LAPACK auxiliary routine (version 3.4.2) --
260 * -- LAPACK is a software package provided by Univ. of Tennessee, --
261 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
262 * September 2012
263 *
264 * .. Scalar Arguments ..
265  INTEGER ihi, ihiz, ilo, iloz, info, ldh, ldz, lwork, n
266  LOGICAL wantt, wantz
267 * ..
268 * .. Array Arguments ..
269  REAL h( ldh, * ), wi( * ), work( * ), wr( * ),
270  \$ z( ldz, * )
271 * ..
272 *
273 * ================================================================
274 * .. Parameters ..
275 *
276 * ==== Matrices of order NTINY or smaller must be processed by
277 * . SLAHQR because of insufficient subdiagonal scratch space.
278 * . (This is a hard limit.) ====
279  INTEGER ntiny
280  parameter ( ntiny = 11 )
281 *
282 * ==== Exceptional deflation windows: try to cure rare
283 * . slow convergence by varying the size of the
284 * . deflation window after KEXNW iterations. ====
285  INTEGER kexnw
286  parameter ( kexnw = 5 )
287 *
288 * ==== Exceptional shifts: try to cure rare slow convergence
289 * . with ad-hoc exceptional shifts every KEXSH iterations.
290 * . ====
291  INTEGER kexsh
292  parameter ( kexsh = 6 )
293 *
294 * ==== The constants WILK1 and WILK2 are used to form the
295 * . exceptional shifts. ====
296  REAL wilk1, wilk2
297  parameter ( wilk1 = 0.75e0, wilk2 = -0.4375e0 )
298  REAL zero, one
299  parameter ( zero = 0.0e0, one = 1.0e0 )
300 * ..
301 * .. Local Scalars ..
302  REAL aa, bb, cc, cs, dd, sn, ss, swap
303  INTEGER i, inf, it, itmax, k, kacc22, kbot, kdu, ks,
304  \$ kt, ktop, ku, kv, kwh, kwtop, kwv, ld, ls,
305  \$ lwkopt, ndec, ndfl, nh, nho, nibble, nmin, ns,
306  \$ nsmax, nsr, nve, nw, nwmax, nwr, nwupbd
307  LOGICAL sorted
308  CHARACTER jbcmpz*2
309 * ..
310 * .. External Functions ..
311  INTEGER ilaenv
312  EXTERNAL ilaenv
313 * ..
314 * .. Local Arrays ..
315  REAL zdum( 1, 1 )
316 * ..
317 * .. External Subroutines ..
318  EXTERNAL slacpy, slahqr, slanv2, slaqr3, slaqr4, slaqr5
319 * ..
320 * .. Intrinsic Functions ..
321  INTRINSIC abs, int, max, min, mod, real
322 * ..
323 * .. Executable Statements ..
324  info = 0
325 *
326 * ==== Quick return for N = 0: nothing to do. ====
327 *
328  IF( n.EQ.0 ) THEN
329  work( 1 ) = one
330  RETURN
331  END IF
332 *
333  IF( n.LE.ntiny ) THEN
334 *
335 * ==== Tiny matrices must use SLAHQR. ====
336 *
337  lwkopt = 1
338  IF( lwork.NE.-1 )
339  \$ CALL slahqr( wantt, wantz, n, ilo, ihi, h, ldh, wr, wi,
340  \$ iloz, ihiz, z, ldz, info )
341  ELSE
342 *
343 * ==== Use small bulge multi-shift QR with aggressive early
344 * . deflation on larger-than-tiny matrices. ====
345 *
346 * ==== Hope for the best. ====
347 *
348  info = 0
349 *
350 * ==== Set up job flags for ILAENV. ====
351 *
352  IF( wantt ) THEN
353  jbcmpz( 1: 1 ) = 'S'
354  ELSE
355  jbcmpz( 1: 1 ) = 'E'
356  END IF
357  IF( wantz ) THEN
358  jbcmpz( 2: 2 ) = 'V'
359  ELSE
360  jbcmpz( 2: 2 ) = 'N'
361  END IF
362 *
363 * ==== NWR = recommended deflation window size. At this
364 * . point, N .GT. NTINY = 11, so there is enough
365 * . subdiagonal workspace for NWR.GE.2 as required.
366 * . (In fact, there is enough subdiagonal space for
367 * . NWR.GE.3.) ====
368 *
369  nwr = ilaenv( 13, 'SLAQR0', jbcmpz, n, ilo, ihi, lwork )
370  nwr = max( 2, nwr )
371  nwr = min( ihi-ilo+1, ( n-1 ) / 3, nwr )
372 *
373 * ==== NSR = recommended number of simultaneous shifts.
374 * . At this point N .GT. NTINY = 11, so there is at
375 * . enough subdiagonal workspace for NSR to be even
376 * . and greater than or equal to two as required. ====
377 *
378  nsr = ilaenv( 15, 'SLAQR0', jbcmpz, n, ilo, ihi, lwork )
379  nsr = min( nsr, ( n+6 ) / 9, ihi-ilo )
380  nsr = max( 2, nsr-mod( nsr, 2 ) )
381 *
382 * ==== Estimate optimal workspace ====
383 *
384 * ==== Workspace query call to SLAQR3 ====
385 *
386  CALL slaqr3( wantt, wantz, n, ilo, ihi, nwr+1, h, ldh, iloz,
387  \$ ihiz, z, ldz, ls, ld, wr, wi, h, ldh, n, h, ldh,
388  \$ n, h, ldh, work, -1 )
389 *
390 * ==== Optimal workspace = MAX(SLAQR5, SLAQR3) ====
391 *
392  lwkopt = max( 3*nsr / 2, int( work( 1 ) ) )
393 *
394 * ==== Quick return in case of workspace query. ====
395 *
396  IF( lwork.EQ.-1 ) THEN
397  work( 1 ) = REAL( lwkopt )
398  RETURN
399  END IF
400 *
401 * ==== SLAHQR/SLAQR0 crossover point ====
402 *
403  nmin = ilaenv( 12, 'SLAQR0', jbcmpz, n, ilo, ihi, lwork )
404  nmin = max( ntiny, nmin )
405 *
406 * ==== Nibble crossover point ====
407 *
408  nibble = ilaenv( 14, 'SLAQR0', jbcmpz, n, ilo, ihi, lwork )
409  nibble = max( 0, nibble )
410 *
411 * ==== Accumulate reflections during ttswp? Use block
412 * . 2-by-2 structure during matrix-matrix multiply? ====
413 *
414  kacc22 = ilaenv( 16, 'SLAQR0', jbcmpz, n, ilo, ihi, lwork )
415  kacc22 = max( 0, kacc22 )
416  kacc22 = min( 2, kacc22 )
417 *
418 * ==== NWMAX = the largest possible deflation window for
419 * . which there is sufficient workspace. ====
420 *
421  nwmax = min( ( n-1 ) / 3, lwork / 2 )
422  nw = nwmax
423 *
424 * ==== NSMAX = the Largest number of simultaneous shifts
425 * . for which there is sufficient workspace. ====
426 *
427  nsmax = min( ( n+6 ) / 9, 2*lwork / 3 )
428  nsmax = nsmax - mod( nsmax, 2 )
429 *
430 * ==== NDFL: an iteration count restarted at deflation. ====
431 *
432  ndfl = 1
433 *
434 * ==== ITMAX = iteration limit ====
435 *
436  itmax = max( 30, 2*kexsh )*max( 10, ( ihi-ilo+1 ) )
437 *
438 * ==== Last row and column in the active block ====
439 *
440  kbot = ihi
441 *
442 * ==== Main Loop ====
443 *
444  DO 80 it = 1, itmax
445 *
446 * ==== Done when KBOT falls below ILO ====
447 *
448  IF( kbot.LT.ilo )
449  \$ GO TO 90
450 *
451 * ==== Locate active block ====
452 *
453  DO 10 k = kbot, ilo + 1, -1
454  IF( h( k, k-1 ).EQ.zero )
455  \$ GO TO 20
456  10 CONTINUE
457  k = ilo
458  20 CONTINUE
459  ktop = k
460 *
461 * ==== Select deflation window size:
462 * . Typical Case:
463 * . If possible and advisable, nibble the entire
464 * . active block. If not, use size MIN(NWR,NWMAX)
465 * . or MIN(NWR+1,NWMAX) depending upon which has
466 * . the smaller corresponding subdiagonal entry
467 * . (a heuristic).
468 * .
469 * . Exceptional Case:
470 * . If there have been no deflations in KEXNW or
471 * . more iterations, then vary the deflation window
472 * . size. At first, because, larger windows are,
473 * . in general, more powerful than smaller ones,
474 * . rapidly increase the window to the maximum possible.
475 * . Then, gradually reduce the window size. ====
476 *
477  nh = kbot - ktop + 1
478  nwupbd = min( nh, nwmax )
479  IF( ndfl.LT.kexnw ) THEN
480  nw = min( nwupbd, nwr )
481  ELSE
482  nw = min( nwupbd, 2*nw )
483  END IF
484  IF( nw.LT.nwmax ) THEN
485  IF( nw.GE.nh-1 ) THEN
486  nw = nh
487  ELSE
488  kwtop = kbot - nw + 1
489  IF( abs( h( kwtop, kwtop-1 ) ).GT.
490  \$ abs( h( kwtop-1, kwtop-2 ) ) )nw = nw + 1
491  END IF
492  END IF
493  IF( ndfl.LT.kexnw ) THEN
494  ndec = -1
495  ELSE IF( ndec.GE.0 .OR. nw.GE.nwupbd ) THEN
496  ndec = ndec + 1
497  IF( nw-ndec.LT.2 )
498  \$ ndec = 0
499  nw = nw - ndec
500  END IF
501 *
502 * ==== Aggressive early deflation:
503 * . split workspace under the subdiagonal into
504 * . - an nw-by-nw work array V in the lower
505 * . left-hand-corner,
506 * . - an NW-by-at-least-NW-but-more-is-better
507 * . (NW-by-NHO) horizontal work array along
508 * . the bottom edge,
509 * . - an at-least-NW-but-more-is-better (NHV-by-NW)
510 * . vertical work array along the left-hand-edge.
511 * . ====
512 *
513  kv = n - nw + 1
514  kt = nw + 1
515  nho = ( n-nw-1 ) - kt + 1
516  kwv = nw + 2
517  nve = ( n-nw ) - kwv + 1
518 *
519 * ==== Aggressive early deflation ====
520 *
521  CALL slaqr3( wantt, wantz, n, ktop, kbot, nw, h, ldh, iloz,
522  \$ ihiz, z, ldz, ls, ld, wr, wi, h( kv, 1 ), ldh,
523  \$ nho, h( kv, kt ), ldh, nve, h( kwv, 1 ), ldh,
524  \$ work, lwork )
525 *
526 * ==== Adjust KBOT accounting for new deflations. ====
527 *
528  kbot = kbot - ld
529 *
530 * ==== KS points to the shifts. ====
531 *
532  ks = kbot - ls + 1
533 *
534 * ==== Skip an expensive QR sweep if there is a (partly
535 * . heuristic) reason to expect that many eigenvalues
536 * . will deflate without it. Here, the QR sweep is
537 * . skipped if many eigenvalues have just been deflated
538 * . or if the remaining active block is small.
539 *
540  IF( ( ld.EQ.0 ) .OR. ( ( 100*ld.LE.nw*nibble ) .AND. ( kbot-
541  \$ ktop+1.GT.min( nmin, nwmax ) ) ) ) THEN
542 *
543 * ==== NS = nominal number of simultaneous shifts.
544 * . This may be lowered (slightly) if SLAQR3
545 * . did not provide that many shifts. ====
546 *
547  ns = min( nsmax, nsr, max( 2, kbot-ktop ) )
548  ns = ns - mod( ns, 2 )
549 *
550 * ==== If there have been no deflations
551 * . in a multiple of KEXSH iterations,
552 * . then try exceptional shifts.
553 * . Otherwise use shifts provided by
554 * . SLAQR3 above or from the eigenvalues
555 * . of a trailing principal submatrix. ====
556 *
557  IF( mod( ndfl, kexsh ).EQ.0 ) THEN
558  ks = kbot - ns + 1
559  DO 30 i = kbot, max( ks+1, ktop+2 ), -2
560  ss = abs( h( i, i-1 ) ) + abs( h( i-1, i-2 ) )
561  aa = wilk1*ss + h( i, i )
562  bb = ss
563  cc = wilk2*ss
564  dd = aa
565  CALL slanv2( aa, bb, cc, dd, wr( i-1 ), wi( i-1 ),
566  \$ wr( i ), wi( i ), cs, sn )
567  30 CONTINUE
568  IF( ks.EQ.ktop ) THEN
569  wr( ks+1 ) = h( ks+1, ks+1 )
570  wi( ks+1 ) = zero
571  wr( ks ) = wr( ks+1 )
572  wi( ks ) = wi( ks+1 )
573  END IF
574  ELSE
575 *
576 * ==== Got NS/2 or fewer shifts? Use SLAQR4 or
577 * . SLAHQR on a trailing principal submatrix to
578 * . get more. (Since NS.LE.NSMAX.LE.(N+6)/9,
579 * . there is enough space below the subdiagonal
580 * . to fit an NS-by-NS scratch array.) ====
581 *
582  IF( kbot-ks+1.LE.ns / 2 ) THEN
583  ks = kbot - ns + 1
584  kt = n - ns + 1
585  CALL slacpy( 'A', ns, ns, h( ks, ks ), ldh,
586  \$ h( kt, 1 ), ldh )
587  IF( ns.GT.nmin ) THEN
588  CALL slaqr4( .false., .false., ns, 1, ns,
589  \$ h( kt, 1 ), ldh, wr( ks ),
590  \$ wi( ks ), 1, 1, zdum, 1, work,
591  \$ lwork, inf )
592  ELSE
593  CALL slahqr( .false., .false., ns, 1, ns,
594  \$ h( kt, 1 ), ldh, wr( ks ),
595  \$ wi( ks ), 1, 1, zdum, 1, inf )
596  END IF
597  ks = ks + inf
598 *
599 * ==== In case of a rare QR failure use
600 * . eigenvalues of the trailing 2-by-2
601 * . principal submatrix. ====
602 *
603  IF( ks.GE.kbot ) THEN
604  aa = h( kbot-1, kbot-1 )
605  cc = h( kbot, kbot-1 )
606  bb = h( kbot-1, kbot )
607  dd = h( kbot, kbot )
608  CALL slanv2( aa, bb, cc, dd, wr( kbot-1 ),
609  \$ wi( kbot-1 ), wr( kbot ),
610  \$ wi( kbot ), cs, sn )
611  ks = kbot - 1
612  END IF
613  END IF
614 *
615  IF( kbot-ks+1.GT.ns ) THEN
616 *
617 * ==== Sort the shifts (Helps a little)
618 * . Bubble sort keeps complex conjugate
619 * . pairs together. ====
620 *
621  sorted = .false.
622  DO 50 k = kbot, ks + 1, -1
623  IF( sorted )
624  \$ GO TO 60
625  sorted = .true.
626  DO 40 i = ks, k - 1
627  IF( abs( wr( i ) )+abs( wi( i ) ).LT.
628  \$ abs( wr( i+1 ) )+abs( wi( i+1 ) ) ) THEN
629  sorted = .false.
630 *
631  swap = wr( i )
632  wr( i ) = wr( i+1 )
633  wr( i+1 ) = swap
634 *
635  swap = wi( i )
636  wi( i ) = wi( i+1 )
637  wi( i+1 ) = swap
638  END IF
639  40 CONTINUE
640  50 CONTINUE
641  60 CONTINUE
642  END IF
643 *
644 * ==== Shuffle shifts into pairs of real shifts
645 * . and pairs of complex conjugate shifts
646 * . assuming complex conjugate shifts are
648 * . they are.) ====
649 *
650  DO 70 i = kbot, ks + 2, -2
651  IF( wi( i ).NE.-wi( i-1 ) ) THEN
652 *
653  swap = wr( i )
654  wr( i ) = wr( i-1 )
655  wr( i-1 ) = wr( i-2 )
656  wr( i-2 ) = swap
657 *
658  swap = wi( i )
659  wi( i ) = wi( i-1 )
660  wi( i-1 ) = wi( i-2 )
661  wi( i-2 ) = swap
662  END IF
663  70 CONTINUE
664  END IF
665 *
666 * ==== If there are only two shifts and both are
667 * . real, then use only one. ====
668 *
669  IF( kbot-ks+1.EQ.2 ) THEN
670  IF( wi( kbot ).EQ.zero ) THEN
671  IF( abs( wr( kbot )-h( kbot, kbot ) ).LT.
672  \$ abs( wr( kbot-1 )-h( kbot, kbot ) ) ) THEN
673  wr( kbot-1 ) = wr( kbot )
674  ELSE
675  wr( kbot ) = wr( kbot-1 )
676  END IF
677  END IF
678  END IF
679 *
680 * ==== Use up to NS of the the smallest magnatiude
681 * . shifts. If there aren't NS shifts available,
682 * . then use them all, possibly dropping one to
683 * . make the number of shifts even. ====
684 *
685  ns = min( ns, kbot-ks+1 )
686  ns = ns - mod( ns, 2 )
687  ks = kbot - ns + 1
688 *
689 * ==== Small-bulge multi-shift QR sweep:
690 * . split workspace under the subdiagonal into
691 * . - a KDU-by-KDU work array U in the lower
692 * . left-hand-corner,
693 * . - a KDU-by-at-least-KDU-but-more-is-better
694 * . (KDU-by-NHo) horizontal work array WH along
695 * . the bottom edge,
696 * . - and an at-least-KDU-but-more-is-better-by-KDU
697 * . (NVE-by-KDU) vertical work WV arrow along
698 * . the left-hand-edge. ====
699 *
700  kdu = 3*ns - 3
701  ku = n - kdu + 1
702  kwh = kdu + 1
703  nho = ( n-kdu+1-4 ) - ( kdu+1 ) + 1
704  kwv = kdu + 4
705  nve = n - kdu - kwv + 1
706 *
707 * ==== Small-bulge multi-shift QR sweep ====
708 *
709  CALL slaqr5( wantt, wantz, kacc22, n, ktop, kbot, ns,
710  \$ wr( ks ), wi( ks ), h, ldh, iloz, ihiz, z,
711  \$ ldz, work, 3, h( ku, 1 ), ldh, nve,
712  \$ h( kwv, 1 ), ldh, nho, h( ku, kwh ), ldh )
713  END IF
714 *
715 * ==== Note progress (or the lack of it). ====
716 *
717  IF( ld.GT.0 ) THEN
718  ndfl = 1
719  ELSE
720  ndfl = ndfl + 1
721  END IF
722 *
723 * ==== End of main loop ====
724  80 CONTINUE
725 *
726 * ==== Iteration limit exceeded. Set INFO to show where
727 * . the problem occurred and exit. ====
728 *
729  info = kbot
730  90 CONTINUE
731  END IF
732 *
733 * ==== Return the optimal value of LWORK. ====
734 *
735  work( 1 ) = REAL( lwkopt )
736 *
737 * ==== End of SLAQR0 ====
738 *
subroutine slahqr(WANTT, WANTZ, N, ILO, IHI, H, LDH, WR, WI, ILOZ, IHIZ, Z, LDZ, INFO)
SLAHQR computes the eigenvalues and Schur factorization of an upper Hessenberg matrix, using the double-shift/single-shift QR algorithm.
Definition: slahqr.f:209
subroutine slaqr3(WANTT, WANTZ, N, KTOP, KBOT, NW, H, LDH, ILOZ, IHIZ, Z, LDZ, NS, ND, SR, SI, V, LDV, NH, T, LDT, NV, WV, LDWV, WORK, LWORK)
SLAQR3 performs the orthogonal similarity transformation of a Hessenberg matrix to detect and deflate...
Definition: slaqr3.f:277
subroutine slacpy(UPLO, M, N, A, LDA, B, LDB)
SLACPY copies all or part of one two-dimensional array to another.
Definition: slacpy.f:105
subroutine slaqr5(WANTT, WANTZ, KACC22, N, KTOP, KBOT, NSHFTS, SR, SI, H, LDH, ILOZ, IHIZ, Z, LDZ, V, LDV, U, LDU, NV, WV, LDWV, NH, WH, LDWH)
SLAQR5 performs a single small-bulge multi-shift QR sweep.
Definition: slaqr5.f:261
integer function ilaenv(ISPEC, NAME, OPTS, N1, N2, N3, N4)
Definition: tstiee.f:83
subroutine slanv2(A, B, C, D, RT1R, RT1I, RT2R, RT2I, CS, SN)
SLANV2 computes the Schur factorization of a real 2-by-2 nonsymmetric matrix in standard form...
Definition: slanv2.f:129
subroutine slaqr4(WANTT, WANTZ, N, ILO, IHI, H, LDH, WR, WI, ILOZ, IHIZ, Z, LDZ, WORK, LWORK, INFO)
SLAQR4 computes the eigenvalues of a Hessenberg matrix, and optionally the matrices from the Schur de...
Definition: slaqr4.f:267

Here is the call graph for this function:

Here is the caller graph for this function: