LAPACK  3.6.1 LAPACK: Linear Algebra PACKage
 subroutine zgetrf ( integer M, integer N, complex*16, dimension( lda, * ) A, integer LDA, integer, dimension( * ) IPIV, integer INFO )

ZGETRF VARIANT: Crout Level 3 BLAS version of the algorithm.

Purpose:

``` ZGETRF computes an LU factorization of a general M-by-N matrix A
using partial pivoting with row interchanges.

The factorization has the form
A = P * L * U
where P is a permutation matrix, L is lower triangular with unit
diagonal elements (lower trapezoidal if m > n), and U is upper
triangular (upper trapezoidal if m < n).

This is the Crout Level 3 BLAS version of the algorithm.```
Parameters
 [in] M ``` M is INTEGER The number of rows of the matrix A. M >= 0.``` [in] N ``` N is INTEGER The number of columns of the matrix A. N >= 0.``` [in,out] A ``` A is COMPLEX*16 array, dimension (LDA,N) On entry, the M-by-N matrix to be factored. On exit, the factors L and U from the factorization A = P*L*U; the unit diagonal elements of L are not stored.``` [in] LDA ``` LDA is INTEGER The leading dimension of the array A. LDA >= max(1,M).``` [out] IPIV ``` IPIV is INTEGER array, dimension (min(M,N)) The pivot indices; for 1 <= i <= min(M,N), row i of the matrix was interchanged with row IPIV(i).``` [out] INFO ``` INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value > 0: if INFO = i, U(i,i) is exactly zero. The factorization has been completed, but the factor U is exactly singular, and division by zero will occur if it is used to solve a system of equations.```
Date
November 2011

Definition at line 102 of file zgetrf.f.

102 *
103 * -- LAPACK computational routine (version 3.1) --
104 * -- LAPACK is a software package provided by Univ. of Tennessee, --
105 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
106 * November 2011
107 *
108 * .. Scalar Arguments ..
109  INTEGER info, lda, m, n
110 * ..
111 * .. Array Arguments ..
112  INTEGER ipiv( * )
113  COMPLEX*16 a( lda, * )
114 * ..
115 *
116 * =====================================================================
117 *
118 * .. Parameters ..
119  COMPLEX*16 one
120  parameter ( one = ( 1.0d+0, 0.0d+0 ) )
121 * ..
122 * .. Local Scalars ..
123  INTEGER i, iinfo, j, jb, nb
124 * ..
125 * .. External Subroutines ..
126  EXTERNAL zgemm, zgetf2, zlaswp, ztrsm, xerbla
127 * ..
128 * .. External Functions ..
129  INTEGER ilaenv
130  EXTERNAL ilaenv
131 * ..
132 * .. Intrinsic Functions ..
133  INTRINSIC max, min
134 * ..
135 * .. Executable Statements ..
136 *
137 * Test the input parameters.
138 *
139  info = 0
140  IF( m.LT.0 ) THEN
141  info = -1
142  ELSE IF( n.LT.0 ) THEN
143  info = -2
144  ELSE IF( lda.LT.max( 1, m ) ) THEN
145  info = -4
146  END IF
147  IF( info.NE.0 ) THEN
148  CALL xerbla( 'ZGETRF', -info )
149  RETURN
150  END IF
151 *
152 * Quick return if possible
153 *
154  IF( m.EQ.0 .OR. n.EQ.0 )
155  \$ RETURN
156 *
157 * Determine the block size for this environment.
158 *
159  nb = ilaenv( 1, 'ZGETRF', ' ', m, n, -1, -1 )
160  IF( nb.LE.1 .OR. nb.GE.min( m, n ) ) THEN
161 *
162 * Use unblocked code.
163 *
164  CALL zgetf2( m, n, a, lda, ipiv, info )
165  ELSE
166 *
167 * Use blocked code.
168 *
169  DO 20 j = 1, min( m, n ), nb
170  jb = min( min( m, n )-j+1, nb )
171 *
172 * Update current block.
173 *
174  CALL zgemm( 'No transpose', 'No transpose',
175  \$ m-j+1, jb, j-1, -one,
176  \$ a( j, 1 ), lda, a( 1, j ), lda, one,
177  \$ a( j, j ), lda )
178
179 *
180 * Factor diagonal and subdiagonal blocks and test for exact
181 * singularity.
182 *
183  CALL zgetf2( m-j+1, jb, a( j, j ), lda, ipiv( j ), iinfo )
184 *
185 * Adjust INFO and the pivot indices.
186 *
187  IF( info.EQ.0 .AND. iinfo.GT.0 )
188  \$ info = iinfo + j - 1
189  DO 10 i = j, min( m, j+jb-1 )
190  ipiv( i ) = j - 1 + ipiv( i )
191  10 CONTINUE
192 *
193 * Apply interchanges to column 1:J-1
194 *
195  CALL zlaswp( j-1, a, lda, j, j+jb-1, ipiv, 1 )
196 *
197  IF ( j+jb.LE.n ) THEN
198 *
199 * Apply interchanges to column J+JB:N
200 *
201  CALL zlaswp( n-j-jb+1, a( 1, j+jb ), lda, j, j+jb-1,
202  \$ ipiv, 1 )
203 *
204  CALL zgemm( 'No transpose', 'No transpose',
205  \$ jb, n-j-jb+1, j-1, -one,
206  \$ a( j, 1 ), lda, a( 1, j+jb ), lda, one,
207  \$ a( j, j+jb ), lda )
208 *
209 * Compute block row of U.
210 *
211  CALL ztrsm( 'Left', 'Lower', 'No transpose', 'Unit',
212  \$ jb, n-j-jb+1, one, a( j, j ), lda,
213  \$ a( j, j+jb ), lda )
214  END IF
215
216  20 CONTINUE
217
218  END IF
219  RETURN
220 *
221 * End of ZGETRF
222 *
subroutine zgetf2(M, N, A, LDA, IPIV, INFO)
ZGETF2 computes the LU factorization of a general m-by-n matrix using partial pivoting with row inter...
Definition: zgetf2.f:110
subroutine zlaswp(N, A, LDA, K1, K2, IPIV, INCX)
ZLASWP performs a series of row interchanges on a general rectangular matrix.
Definition: zlaswp.f:116
subroutine zgemm(TRANSA, TRANSB, M, N, K, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
ZGEMM
Definition: zgemm.f:189
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
integer function ilaenv(ISPEC, NAME, OPTS, N1, N2, N3, N4)
Definition: tstiee.f:83
subroutine ztrsm(SIDE, UPLO, TRANSA, DIAG, M, N, ALPHA, A, LDA, B, LDB)
ZTRSM
Definition: ztrsm.f:182

Here is the call graph for this function:

Here is the caller graph for this function: