LAPACK  3.6.1
LAPACK: Linear Algebra PACKage
subroutine dorbdb2 ( integer  M,
integer  P,
integer  Q,
double precision, dimension(ldx11,*)  X11,
integer  LDX11,
double precision, dimension(ldx21,*)  X21,
integer  LDX21,
double precision, dimension(*)  THETA,
double precision, dimension(*)  PHI,
double precision, dimension(*)  TAUP1,
double precision, dimension(*)  TAUP2,
double precision, dimension(*)  TAUQ1,
double precision, dimension(*)  WORK,
integer  LWORK,
integer  INFO 
)

DORBDB2

Download DORBDB2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 DORBDB2 simultaneously bidiagonalizes the blocks of a tall and skinny
 matrix X with orthonomal columns:

                            [ B11 ]
      [ X11 ]   [ P1 |    ] [  0  ]
      [-----] = [---------] [-----] Q1**T .
      [ X21 ]   [    | P2 ] [ B21 ]
                            [  0  ]

 X11 is P-by-Q, and X21 is (M-P)-by-Q. P must be no larger than M-P,
 Q, or M-Q. Routines DORBDB1, DORBDB3, and DORBDB4 handle cases in
 which P is not the minimum dimension.

 The orthogonal matrices P1, P2, and Q1 are P-by-P, (M-P)-by-(M-P),
 and (M-Q)-by-(M-Q), respectively. They are represented implicitly by
 Householder vectors.

 B11 and B12 are P-by-P bidiagonal matrices represented implicitly by
 angles THETA, PHI.
Parameters
[in]M
          M is INTEGER
           The number of rows X11 plus the number of rows in X21.
[in]P
          P is INTEGER
           The number of rows in X11. 0 <= P <= min(M-P,Q,M-Q).
[in]Q
          Q is INTEGER
           The number of columns in X11 and X21. 0 <= Q <= M.
[in,out]X11
          X11 is DOUBLE PRECISION array, dimension (LDX11,Q)
           On entry, the top block of the matrix X to be reduced. On
           exit, the columns of tril(X11) specify reflectors for P1 and
           the rows of triu(X11,1) specify reflectors for Q1.
[in]LDX11
          LDX11 is INTEGER
           The leading dimension of X11. LDX11 >= P.
[in,out]X21
          X21 is DOUBLE PRECISION array, dimension (LDX21,Q)
           On entry, the bottom block of the matrix X to be reduced. On
           exit, the columns of tril(X21) specify reflectors for P2.
[in]LDX21
          LDX21 is INTEGER
           The leading dimension of X21. LDX21 >= M-P.
[out]THETA
          THETA is DOUBLE PRECISION array, dimension (Q)
           The entries of the bidiagonal blocks B11, B21 are defined by
           THETA and PHI. See Further Details.
[out]PHI
          PHI is DOUBLE PRECISION array, dimension (Q-1)
           The entries of the bidiagonal blocks B11, B21 are defined by
           THETA and PHI. See Further Details.
[out]TAUP1
          TAUP1 is DOUBLE PRECISION array, dimension (P)
           The scalar factors of the elementary reflectors that define
           P1.
[out]TAUP2
          TAUP2 is DOUBLE PRECISION array, dimension (M-P)
           The scalar factors of the elementary reflectors that define
           P2.
[out]TAUQ1
          TAUQ1 is DOUBLE PRECISION array, dimension (Q)
           The scalar factors of the elementary reflectors that define
           Q1.
[out]WORK
          WORK is DOUBLE PRECISION array, dimension (LWORK)
[in]LWORK
          LWORK is INTEGER
           The dimension of the array WORK. LWORK >= M-Q.
 
           If LWORK = -1, then a workspace query is assumed; the routine
           only calculates the optimal size of the WORK array, returns
           this value as the first entry of the WORK array, and no error
           message related to LWORK is issued by XERBLA.
[out]INFO
          INFO is INTEGER
           = 0:  successful exit.
           < 0:  if INFO = -i, the i-th argument had an illegal value.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
July 2012
Further Details:
  The upper-bidiagonal blocks B11, B21 are represented implicitly by
  angles THETA(1), ..., THETA(Q) and PHI(1), ..., PHI(Q-1). Every entry
  in each bidiagonal band is a product of a sine or cosine of a THETA
  with a sine or cosine of a PHI. See [1] or DORCSD for details.

  P1, P2, and Q1 are represented as products of elementary reflectors.
  See DORCSD2BY1 for details on generating P1, P2, and Q1 using DORGQR
  and DORGLQ.
References:
[1] Brian D. Sutton. Computing the complete CS decomposition. Numer. Algorithms, 50(1):33-65, 2009.

Definition at line 204 of file dorbdb2.f.

204 *
205 * -- LAPACK computational routine (version 3.6.1) --
206 * -- LAPACK is a software package provided by Univ. of Tennessee, --
207 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
208 * July 2012
209 *
210 * .. Scalar Arguments ..
211  INTEGER info, lwork, m, p, q, ldx11, ldx21
212 * ..
213 * .. Array Arguments ..
214  DOUBLE PRECISION phi(*), theta(*)
215  DOUBLE PRECISION taup1(*), taup2(*), tauq1(*), work(*),
216  $ x11(ldx11,*), x21(ldx21,*)
217 * ..
218 *
219 * ====================================================================
220 *
221 * .. Parameters ..
222  DOUBLE PRECISION negone, one
223  parameter ( negone = -1.0d0, one = 1.0d0 )
224 * ..
225 * .. Local Scalars ..
226  DOUBLE PRECISION c, s
227  INTEGER childinfo, i, ilarf, iorbdb5, llarf, lorbdb5,
228  $ lworkmin, lworkopt
229  LOGICAL lquery
230 * ..
231 * .. External Subroutines ..
232  EXTERNAL dlarf, dlarfgp, dorbdb5, drot, dscal, xerbla
233 * ..
234 * .. External Functions ..
235  DOUBLE PRECISION dnrm2
236  EXTERNAL dnrm2
237 * ..
238 * .. Intrinsic Function ..
239  INTRINSIC atan2, cos, max, sin, sqrt
240 * ..
241 * .. Executable Statements ..
242 *
243 * Test input arguments
244 *
245  info = 0
246  lquery = lwork .EQ. -1
247 *
248  IF( m .LT. 0 ) THEN
249  info = -1
250  ELSE IF( p .LT. 0 .OR. p .GT. m-p ) THEN
251  info = -2
252  ELSE IF( q .LT. 0 .OR. q .LT. p .OR. m-q .LT. p ) THEN
253  info = -3
254  ELSE IF( ldx11 .LT. max( 1, p ) ) THEN
255  info = -5
256  ELSE IF( ldx21 .LT. max( 1, m-p ) ) THEN
257  info = -7
258  END IF
259 *
260 * Compute workspace
261 *
262  IF( info .EQ. 0 ) THEN
263  ilarf = 2
264  llarf = max( p-1, m-p, q-1 )
265  iorbdb5 = 2
266  lorbdb5 = q-1
267  lworkopt = max( ilarf+llarf-1, iorbdb5+lorbdb5-1 )
268  lworkmin = lworkopt
269  work(1) = lworkopt
270  IF( lwork .LT. lworkmin .AND. .NOT.lquery ) THEN
271  info = -14
272  END IF
273  END IF
274  IF( info .NE. 0 ) THEN
275  CALL xerbla( 'DORBDB2', -info )
276  RETURN
277  ELSE IF( lquery ) THEN
278  RETURN
279  END IF
280 *
281 * Reduce rows 1, ..., P of X11 and X21
282 *
283  DO i = 1, p
284 *
285  IF( i .GT. 1 ) THEN
286  CALL drot( q-i+1, x11(i,i), ldx11, x21(i-1,i), ldx21, c, s )
287  END IF
288  CALL dlarfgp( q-i+1, x11(i,i), x11(i,i+1), ldx11, tauq1(i) )
289  c = x11(i,i)
290  x11(i,i) = one
291  CALL dlarf( 'R', p-i, q-i+1, x11(i,i), ldx11, tauq1(i),
292  $ x11(i+1,i), ldx11, work(ilarf) )
293  CALL dlarf( 'R', m-p-i+1, q-i+1, x11(i,i), ldx11, tauq1(i),
294  $ x21(i,i), ldx21, work(ilarf) )
295  s = sqrt( dnrm2( p-i, x11(i+1,i), 1 )**2
296  $ + dnrm2( m-p-i+1, x21(i,i), 1 )**2 )
297  theta(i) = atan2( s, c )
298 *
299  CALL dorbdb5( p-i, m-p-i+1, q-i, x11(i+1,i), 1, x21(i,i), 1,
300  $ x11(i+1,i+1), ldx11, x21(i,i+1), ldx21,
301  $ work(iorbdb5), lorbdb5, childinfo )
302  CALL dscal( p-i, negone, x11(i+1,i), 1 )
303  CALL dlarfgp( m-p-i+1, x21(i,i), x21(i+1,i), 1, taup2(i) )
304  IF( i .LT. p ) THEN
305  CALL dlarfgp( p-i, x11(i+1,i), x11(i+2,i), 1, taup1(i) )
306  phi(i) = atan2( x11(i+1,i), x21(i,i) )
307  c = cos( phi(i) )
308  s = sin( phi(i) )
309  x11(i+1,i) = one
310  CALL dlarf( 'L', p-i, q-i, x11(i+1,i), 1, taup1(i),
311  $ x11(i+1,i+1), ldx11, work(ilarf) )
312  END IF
313  x21(i,i) = one
314  CALL dlarf( 'L', m-p-i+1, q-i, x21(i,i), 1, taup2(i),
315  $ x21(i,i+1), ldx21, work(ilarf) )
316 *
317  END DO
318 *
319 * Reduce the bottom-right portion of X21 to the identity matrix
320 *
321  DO i = p + 1, q
322  CALL dlarfgp( m-p-i+1, x21(i,i), x21(i+1,i), 1, taup2(i) )
323  x21(i,i) = one
324  CALL dlarf( 'L', m-p-i+1, q-i, x21(i,i), 1, taup2(i),
325  $ x21(i,i+1), ldx21, work(ilarf) )
326  END DO
327 *
328  RETURN
329 *
330 * End of DORBDB2
331 *
subroutine dlarfgp(N, ALPHA, X, INCX, TAU)
DLARFGP generates an elementary reflector (Householder matrix) with non-negative beta.
Definition: dlarfgp.f:106
subroutine drot(N, DX, INCX, DY, INCY, C, S)
DROT
Definition: drot.f:53
subroutine dlarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
DLARF applies an elementary reflector to a general rectangular matrix.
Definition: dlarf.f:126
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
double precision function dnrm2(N, X, INCX)
DNRM2
Definition: dnrm2.f:56
subroutine dorbdb5(M1, M2, N, X1, INCX1, X2, INCX2, Q1, LDQ1, Q2, LDQ2, WORK, LWORK, INFO)
DORBDB5
Definition: dorbdb5.f:158
subroutine dscal(N, DA, DX, INCX)
DSCAL
Definition: dscal.f:55

Here is the call graph for this function:

Here is the caller graph for this function: