LAPACK  3.6.1 LAPACK: Linear Algebra PACKage
 subroutine clahr2 ( integer N, integer K, integer NB, complex, dimension( lda, * ) A, integer LDA, complex, dimension( nb ) TAU, complex, dimension( ldt, nb ) T, integer LDT, complex, dimension( ldy, nb ) Y, integer LDY )

CLAHR2 reduces the specified number of first columns of a general rectangular matrix A so that elements below the specified subdiagonal are zero, and returns auxiliary matrices which are needed to apply the transformation to the unreduced part of A.

Purpose:
``` CLAHR2 reduces the first NB columns of A complex general n-BY-(n-k+1)
matrix A so that elements below the k-th subdiagonal are zero. The
reduction is performed by an unitary similarity transformation
Q**H * A * Q. The routine returns the matrices V and T which determine
Q as a block reflector I - V*T*v**H, and also the matrix Y = A * V * T.

This is an auxiliary routine called by CGEHRD.```
Parameters
 [in] N ``` N is INTEGER The order of the matrix A.``` [in] K ``` K is INTEGER The offset for the reduction. Elements below the k-th subdiagonal in the first NB columns are reduced to zero. K < N.``` [in] NB ``` NB is INTEGER The number of columns to be reduced.``` [in,out] A ``` A is COMPLEX array, dimension (LDA,N-K+1) On entry, the n-by-(n-k+1) general matrix A. On exit, the elements on and above the k-th subdiagonal in the first NB columns are overwritten with the corresponding elements of the reduced matrix; the elements below the k-th subdiagonal, with the array TAU, represent the matrix Q as a product of elementary reflectors. The other columns of A are unchanged. See Further Details.``` [in] LDA ``` LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).``` [out] TAU ``` TAU is COMPLEX array, dimension (NB) The scalar factors of the elementary reflectors. See Further Details.``` [out] T ``` T is COMPLEX array, dimension (LDT,NB) The upper triangular matrix T.``` [in] LDT ``` LDT is INTEGER The leading dimension of the array T. LDT >= NB.``` [out] Y ``` Y is COMPLEX array, dimension (LDY,NB) The n-by-nb matrix Y.``` [in] LDY ``` LDY is INTEGER The leading dimension of the array Y. LDY >= N.```
Date
September 2012
Further Details:
```  The matrix Q is represented as a product of nb elementary reflectors

Q = H(1) H(2) . . . H(nb).

Each H(i) has the form

H(i) = I - tau * v * v**H

where tau is a complex scalar, and v is a complex vector with
v(1:i+k-1) = 0, v(i+k) = 1; v(i+k+1:n) is stored on exit in
A(i+k+1:n,i), and tau in TAU(i).

The elements of the vectors v together form the (n-k+1)-by-nb matrix
V which is needed, with T and Y, to apply the transformation to the
unreduced part of the matrix, using an update of the form:
A := (I - V*T*V**H) * (A - Y*V**H).

The contents of A on exit are illustrated by the following example
with n = 7, k = 3 and nb = 2:

( a   a   a   a   a )
( a   a   a   a   a )
( a   a   a   a   a )
( h   h   a   a   a )
( v1  h   a   a   a )
( v1  v2  a   a   a )
( v1  v2  a   a   a )

where a denotes an element of the original matrix A, h denotes a
modified element of the upper Hessenberg matrix H, and vi denotes an
element of the vector defining H(i).

This subroutine is a slight modification of LAPACK-3.0's DLAHRD
incorporating improvements proposed by Quintana-Orti and Van de
Gejin. Note that the entries of A(1:K,2:NB) differ from those
returned by the original LAPACK-3.0's DLAHRD routine. (This
subroutine is not backward compatible with LAPACK-3.0's DLAHRD.)```
References:
Gregorio Quintana-Orti and Robert van de Geijn, "Improving the performance of reduction to Hessenberg form," ACM Transactions on Mathematical Software, 32(2):180-194, June 2006.

Definition at line 183 of file clahr2.f.

183 *
184 * -- LAPACK auxiliary routine (version 3.4.2) --
185 * -- LAPACK is a software package provided by Univ. of Tennessee, --
186 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
187 * September 2012
188 *
189 * .. Scalar Arguments ..
190  INTEGER k, lda, ldt, ldy, n, nb
191 * ..
192 * .. Array Arguments ..
193  COMPLEX a( lda, * ), t( ldt, nb ), tau( nb ),
194  \$ y( ldy, nb )
195 * ..
196 *
197 * =====================================================================
198 *
199 * .. Parameters ..
200  COMPLEX zero, one
201  parameter ( zero = ( 0.0e+0, 0.0e+0 ),
202  \$ one = ( 1.0e+0, 0.0e+0 ) )
203 * ..
204 * .. Local Scalars ..
205  INTEGER i
206  COMPLEX ei
207 * ..
208 * .. External Subroutines ..
209  EXTERNAL caxpy, ccopy, cgemm, cgemv, clacpy,
211 * ..
212 * .. Intrinsic Functions ..
213  INTRINSIC min
214 * ..
215 * .. Executable Statements ..
216 *
217 * Quick return if possible
218 *
219  IF( n.LE.1 )
220  \$ RETURN
221 *
222  DO 10 i = 1, nb
223  IF( i.GT.1 ) THEN
224 *
225 * Update A(K+1:N,I)
226 *
227 * Update I-th column of A - Y * V**H
228 *
229  CALL clacgv( i-1, a( k+i-1, 1 ), lda )
230  CALL cgemv( 'NO TRANSPOSE', n-k, i-1, -one, y(k+1,1), ldy,
231  \$ a( k+i-1, 1 ), lda, one, a( k+1, i ), 1 )
232  CALL clacgv( i-1, a( k+i-1, 1 ), lda )
233 *
234 * Apply I - V * T**H * V**H to this column (call it b) from the
235 * left, using the last column of T as workspace
236 *
237 * Let V = ( V1 ) and b = ( b1 ) (first I-1 rows)
238 * ( V2 ) ( b2 )
239 *
240 * where V1 is unit lower triangular
241 *
242 * w := V1**H * b1
243 *
244  CALL ccopy( i-1, a( k+1, i ), 1, t( 1, nb ), 1 )
245  CALL ctrmv( 'Lower', 'Conjugate transpose', 'UNIT',
246  \$ i-1, a( k+1, 1 ),
247  \$ lda, t( 1, nb ), 1 )
248 *
249 * w := w + V2**H * b2
250 *
251  CALL cgemv( 'Conjugate transpose', n-k-i+1, i-1,
252  \$ one, a( k+i, 1 ),
253  \$ lda, a( k+i, i ), 1, one, t( 1, nb ), 1 )
254 *
255 * w := T**H * w
256 *
257  CALL ctrmv( 'Upper', 'Conjugate transpose', 'NON-UNIT',
258  \$ i-1, t, ldt,
259  \$ t( 1, nb ), 1 )
260 *
261 * b2 := b2 - V2*w
262 *
263  CALL cgemv( 'NO TRANSPOSE', n-k-i+1, i-1, -one,
264  \$ a( k+i, 1 ),
265  \$ lda, t( 1, nb ), 1, one, a( k+i, i ), 1 )
266 *
267 * b1 := b1 - V1*w
268 *
269  CALL ctrmv( 'Lower', 'NO TRANSPOSE',
270  \$ 'UNIT', i-1,
271  \$ a( k+1, 1 ), lda, t( 1, nb ), 1 )
272  CALL caxpy( i-1, -one, t( 1, nb ), 1, a( k+1, i ), 1 )
273 *
274  a( k+i-1, i-1 ) = ei
275  END IF
276 *
277 * Generate the elementary reflector H(I) to annihilate
278 * A(K+I+1:N,I)
279 *
280  CALL clarfg( n-k-i+1, a( k+i, i ), a( min( k+i+1, n ), i ), 1,
281  \$ tau( i ) )
282  ei = a( k+i, i )
283  a( k+i, i ) = one
284 *
285 * Compute Y(K+1:N,I)
286 *
287  CALL cgemv( 'NO TRANSPOSE', n-k, n-k-i+1,
288  \$ one, a( k+1, i+1 ),
289  \$ lda, a( k+i, i ), 1, zero, y( k+1, i ), 1 )
290  CALL cgemv( 'Conjugate transpose', n-k-i+1, i-1,
291  \$ one, a( k+i, 1 ), lda,
292  \$ a( k+i, i ), 1, zero, t( 1, i ), 1 )
293  CALL cgemv( 'NO TRANSPOSE', n-k, i-1, -one,
294  \$ y( k+1, 1 ), ldy,
295  \$ t( 1, i ), 1, one, y( k+1, i ), 1 )
296  CALL cscal( n-k, tau( i ), y( k+1, i ), 1 )
297 *
298 * Compute T(1:I,I)
299 *
300  CALL cscal( i-1, -tau( i ), t( 1, i ), 1 )
301  CALL ctrmv( 'Upper', 'No Transpose', 'NON-UNIT',
302  \$ i-1, t, ldt,
303  \$ t( 1, i ), 1 )
304  t( i, i ) = tau( i )
305 *
306  10 CONTINUE
307  a( k+nb, nb ) = ei
308 *
309 * Compute Y(1:K,1:NB)
310 *
311  CALL clacpy( 'ALL', k, nb, a( 1, 2 ), lda, y, ldy )
312  CALL ctrmm( 'RIGHT', 'Lower', 'NO TRANSPOSE',
313  \$ 'UNIT', k, nb,
314  \$ one, a( k+1, 1 ), lda, y, ldy )
315  IF( n.GT.k+nb )
316  \$ CALL cgemm( 'NO TRANSPOSE', 'NO TRANSPOSE', k,
317  \$ nb, n-k-nb, one,
318  \$ a( 1, 2+nb ), lda, a( k+1+nb, 1 ), lda, one, y,
319  \$ ldy )
320  CALL ctrmm( 'RIGHT', 'Upper', 'NO TRANSPOSE',
321  \$ 'NON-UNIT', k, nb,
322  \$ one, t, ldt, y, ldy )
323 *
324  RETURN
325 *
326 * End of CLAHR2
327 *
subroutine cscal(N, CA, CX, INCX)
CSCAL
Definition: cscal.f:54
subroutine cgemv(TRANS, M, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
CGEMV
Definition: cgemv.f:160
subroutine ctrmv(UPLO, TRANS, DIAG, N, A, LDA, X, INCX)
CTRMV
Definition: ctrmv.f:149
subroutine clacpy(UPLO, M, N, A, LDA, B, LDB)
CLACPY copies all or part of one two-dimensional array to another.
Definition: clacpy.f:105
subroutine ccopy(N, CX, INCX, CY, INCY)
CCOPY
Definition: ccopy.f:52
subroutine clacgv(N, X, INCX)
CLACGV conjugates a complex vector.
Definition: clacgv.f:76
subroutine ctrmm(SIDE, UPLO, TRANSA, DIAG, M, N, ALPHA, A, LDA, B, LDB)
CTRMM
Definition: ctrmm.f:179
subroutine caxpy(N, CA, CX, INCX, CY, INCY)
CAXPY
Definition: caxpy.f:53
subroutine cgemm(TRANSA, TRANSB, M, N, K, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
CGEMM
Definition: cgemm.f:189
subroutine clarfg(N, ALPHA, X, INCX, TAU)
CLARFG generates an elementary reflector (Householder matrix).
Definition: clarfg.f:108

Here is the call graph for this function:

Here is the caller graph for this function: