LAPACK  3.6.1
LAPACK: Linear Algebra PACKage
subroutine zgtsvx ( character  FACT,
character  TRANS,
integer  N,
integer  NRHS,
complex*16, dimension( * )  DL,
complex*16, dimension( * )  D,
complex*16, dimension( * )  DU,
complex*16, dimension( * )  DLF,
complex*16, dimension( * )  DF,
complex*16, dimension( * )  DUF,
complex*16, dimension( * )  DU2,
integer, dimension( * )  IPIV,
complex*16, dimension( ldb, * )  B,
integer  LDB,
complex*16, dimension( ldx, * )  X,
integer  LDX,
double precision  RCOND,
double precision, dimension( * )  FERR,
double precision, dimension( * )  BERR,
complex*16, dimension( * )  WORK,
double precision, dimension( * )  RWORK,
integer  INFO 
)

ZGTSVX computes the solution to system of linear equations A * X = B for GT matrices

Download ZGTSVX + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 ZGTSVX uses the LU factorization to compute the solution to a complex
 system of linear equations A * X = B, A**T * X = B, or A**H * X = B,
 where A is a tridiagonal matrix of order N and X and B are N-by-NRHS
 matrices.

 Error bounds on the solution and a condition estimate are also
 provided.
Description:
 The following steps are performed:

 1. If FACT = 'N', the LU decomposition is used to factor the matrix A
    as A = L * U, where L is a product of permutation and unit lower
    bidiagonal matrices and U is upper triangular with nonzeros in
    only the main diagonal and first two superdiagonals.

 2. If some U(i,i)=0, so that U is exactly singular, then the routine
    returns with INFO = i. Otherwise, the factored form of A is used
    to estimate the condition number of the matrix A.  If the
    reciprocal of the condition number is less than machine precision,
    INFO = N+1 is returned as a warning, but the routine still goes on
    to solve for X and compute error bounds as described below.

 3. The system of equations is solved for X using the factored form
    of A.

 4. Iterative refinement is applied to improve the computed solution
    matrix and calculate error bounds and backward error estimates
    for it.
Parameters
[in]FACT
          FACT is CHARACTER*1
          Specifies whether or not the factored form of A has been
          supplied on entry.
          = 'F':  DLF, DF, DUF, DU2, and IPIV contain the factored form
                  of A; DL, D, DU, DLF, DF, DUF, DU2 and IPIV will not
                  be modified.
          = 'N':  The matrix will be copied to DLF, DF, and DUF
                  and factored.
[in]TRANS
          TRANS is CHARACTER*1
          Specifies the form of the system of equations:
          = 'N':  A * X = B     (No transpose)
          = 'T':  A**T * X = B  (Transpose)
          = 'C':  A**H * X = B  (Conjugate transpose)
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.
[in]NRHS
          NRHS is INTEGER
          The number of right hand sides, i.e., the number of columns
          of the matrix B.  NRHS >= 0.
[in]DL
          DL is COMPLEX*16 array, dimension (N-1)
          The (n-1) subdiagonal elements of A.
[in]D
          D is COMPLEX*16 array, dimension (N)
          The n diagonal elements of A.
[in]DU
          DU is COMPLEX*16 array, dimension (N-1)
          The (n-1) superdiagonal elements of A.
[in,out]DLF
          DLF is COMPLEX*16 array, dimension (N-1)
          If FACT = 'F', then DLF is an input argument and on entry
          contains the (n-1) multipliers that define the matrix L from
          the LU factorization of A as computed by ZGTTRF.

          If FACT = 'N', then DLF is an output argument and on exit
          contains the (n-1) multipliers that define the matrix L from
          the LU factorization of A.
[in,out]DF
          DF is COMPLEX*16 array, dimension (N)
          If FACT = 'F', then DF is an input argument and on entry
          contains the n diagonal elements of the upper triangular
          matrix U from the LU factorization of A.

          If FACT = 'N', then DF is an output argument and on exit
          contains the n diagonal elements of the upper triangular
          matrix U from the LU factorization of A.
[in,out]DUF
          DUF is COMPLEX*16 array, dimension (N-1)
          If FACT = 'F', then DUF is an input argument and on entry
          contains the (n-1) elements of the first superdiagonal of U.

          If FACT = 'N', then DUF is an output argument and on exit
          contains the (n-1) elements of the first superdiagonal of U.
[in,out]DU2
          DU2 is COMPLEX*16 array, dimension (N-2)
          If FACT = 'F', then DU2 is an input argument and on entry
          contains the (n-2) elements of the second superdiagonal of
          U.

          If FACT = 'N', then DU2 is an output argument and on exit
          contains the (n-2) elements of the second superdiagonal of
          U.
[in,out]IPIV
          IPIV is INTEGER array, dimension (N)
          If FACT = 'F', then IPIV is an input argument and on entry
          contains the pivot indices from the LU factorization of A as
          computed by ZGTTRF.

          If FACT = 'N', then IPIV is an output argument and on exit
          contains the pivot indices from the LU factorization of A;
          row i of the matrix was interchanged with row IPIV(i).
          IPIV(i) will always be either i or i+1; IPIV(i) = i indicates
          a row interchange was not required.
[in]B
          B is COMPLEX*16 array, dimension (LDB,NRHS)
          The N-by-NRHS right hand side matrix B.
[in]LDB
          LDB is INTEGER
          The leading dimension of the array B.  LDB >= max(1,N).
[out]X
          X is COMPLEX*16 array, dimension (LDX,NRHS)
          If INFO = 0 or INFO = N+1, the N-by-NRHS solution matrix X.
[in]LDX
          LDX is INTEGER
          The leading dimension of the array X.  LDX >= max(1,N).
[out]RCOND
          RCOND is DOUBLE PRECISION
          The estimate of the reciprocal condition number of the matrix
          A.  If RCOND is less than the machine precision (in
          particular, if RCOND = 0), the matrix is singular to working
          precision.  This condition is indicated by a return code of
          INFO > 0.
[out]FERR
          FERR is DOUBLE PRECISION array, dimension (NRHS)
          The estimated forward error bound for each solution vector
          X(j) (the j-th column of the solution matrix X).
          If XTRUE is the true solution corresponding to X(j), FERR(j)
          is an estimated upper bound for the magnitude of the largest
          element in (X(j) - XTRUE) divided by the magnitude of the
          largest element in X(j).  The estimate is as reliable as
          the estimate for RCOND, and is almost always a slight
          overestimate of the true error.
[out]BERR
          BERR is DOUBLE PRECISION array, dimension (NRHS)
          The componentwise relative backward error of each solution
          vector X(j) (i.e., the smallest relative change in
          any element of A or B that makes X(j) an exact solution).
[out]WORK
          WORK is COMPLEX*16 array, dimension (2*N)
[out]RWORK
          RWORK is DOUBLE PRECISION array, dimension (N)
[out]INFO
          INFO is INTEGER
          = 0:  successful exit
          < 0:  if INFO = -i, the i-th argument had an illegal value
          > 0:  if INFO = i, and i is
                <= N:  U(i,i) is exactly zero.  The factorization
                       has not been completed unless i = N, but the
                       factor U is exactly singular, so the solution
                       and error bounds could not be computed.
                       RCOND = 0 is returned.
                = N+1: U is nonsingular, but RCOND is less than machine
                       precision, meaning that the matrix is singular
                       to working precision.  Nevertheless, the
                       solution and error bounds are computed because
                       there are a number of situations where the
                       computed solution can be more accurate than the
                       value of RCOND would suggest.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
September 2012

Definition at line 296 of file zgtsvx.f.

296 *
297 * -- LAPACK driver routine (version 3.4.2) --
298 * -- LAPACK is a software package provided by Univ. of Tennessee, --
299 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
300 * September 2012
301 *
302 * .. Scalar Arguments ..
303  CHARACTER fact, trans
304  INTEGER info, ldb, ldx, n, nrhs
305  DOUBLE PRECISION rcond
306 * ..
307 * .. Array Arguments ..
308  INTEGER ipiv( * )
309  DOUBLE PRECISION berr( * ), ferr( * ), rwork( * )
310  COMPLEX*16 b( ldb, * ), d( * ), df( * ), dl( * ),
311  $ dlf( * ), du( * ), du2( * ), duf( * ),
312  $ work( * ), x( ldx, * )
313 * ..
314 *
315 * =====================================================================
316 *
317 * .. Parameters ..
318  DOUBLE PRECISION zero
319  parameter ( zero = 0.0d+0 )
320 * ..
321 * .. Local Scalars ..
322  LOGICAL nofact, notran
323  CHARACTER norm
324  DOUBLE PRECISION anorm
325 * ..
326 * .. External Functions ..
327  LOGICAL lsame
328  DOUBLE PRECISION dlamch, zlangt
329  EXTERNAL lsame, dlamch, zlangt
330 * ..
331 * .. External Subroutines ..
332  EXTERNAL xerbla, zcopy, zgtcon, zgtrfs, zgttrf, zgttrs,
333  $ zlacpy
334 * ..
335 * .. Intrinsic Functions ..
336  INTRINSIC max
337 * ..
338 * .. Executable Statements ..
339 *
340  info = 0
341  nofact = lsame( fact, 'N' )
342  notran = lsame( trans, 'N' )
343  IF( .NOT.nofact .AND. .NOT.lsame( fact, 'F' ) ) THEN
344  info = -1
345  ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'T' ) .AND. .NOT.
346  $ lsame( trans, 'C' ) ) THEN
347  info = -2
348  ELSE IF( n.LT.0 ) THEN
349  info = -3
350  ELSE IF( nrhs.LT.0 ) THEN
351  info = -4
352  ELSE IF( ldb.LT.max( 1, n ) ) THEN
353  info = -14
354  ELSE IF( ldx.LT.max( 1, n ) ) THEN
355  info = -16
356  END IF
357  IF( info.NE.0 ) THEN
358  CALL xerbla( 'ZGTSVX', -info )
359  RETURN
360  END IF
361 *
362  IF( nofact ) THEN
363 *
364 * Compute the LU factorization of A.
365 *
366  CALL zcopy( n, d, 1, df, 1 )
367  IF( n.GT.1 ) THEN
368  CALL zcopy( n-1, dl, 1, dlf, 1 )
369  CALL zcopy( n-1, du, 1, duf, 1 )
370  END IF
371  CALL zgttrf( n, dlf, df, duf, du2, ipiv, info )
372 *
373 * Return if INFO is non-zero.
374 *
375  IF( info.GT.0 )THEN
376  rcond = zero
377  RETURN
378  END IF
379  END IF
380 *
381 * Compute the norm of the matrix A.
382 *
383  IF( notran ) THEN
384  norm = '1'
385  ELSE
386  norm = 'I'
387  END IF
388  anorm = zlangt( norm, n, dl, d, du )
389 *
390 * Compute the reciprocal of the condition number of A.
391 *
392  CALL zgtcon( norm, n, dlf, df, duf, du2, ipiv, anorm, rcond, work,
393  $ info )
394 *
395 * Compute the solution vectors X.
396 *
397  CALL zlacpy( 'Full', n, nrhs, b, ldb, x, ldx )
398  CALL zgttrs( trans, n, nrhs, dlf, df, duf, du2, ipiv, x, ldx,
399  $ info )
400 *
401 * Use iterative refinement to improve the computed solutions and
402 * compute error bounds and backward error estimates for them.
403 *
404  CALL zgtrfs( trans, n, nrhs, dl, d, du, dlf, df, duf, du2, ipiv,
405  $ b, ldb, x, ldx, ferr, berr, work, rwork, info )
406 *
407 * Set INFO = N+1 if the matrix is singular to working precision.
408 *
409  IF( rcond.LT.dlamch( 'Epsilon' ) )
410  $ info = n + 1
411 *
412  RETURN
413 *
414 * End of ZGTSVX
415 *
subroutine zgttrs(TRANS, N, NRHS, DL, D, DU, DU2, IPIV, B, LDB, INFO)
ZGTTRS
Definition: zgttrs.f:140
subroutine zlacpy(UPLO, M, N, A, LDA, B, LDB)
ZLACPY copies all or part of one two-dimensional array to another.
Definition: zlacpy.f:105
subroutine zcopy(N, ZX, INCX, ZY, INCY)
ZCOPY
Definition: zcopy.f:52
double precision function dlamch(CMACH)
DLAMCH
Definition: dlamch.f:65
subroutine zgtcon(NORM, N, DL, D, DU, DU2, IPIV, ANORM, RCOND, WORK, INFO)
ZGTCON
Definition: zgtcon.f:143
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine zgttrf(N, DL, D, DU, DU2, IPIV, INFO)
ZGTTRF
Definition: zgttrf.f:126
double precision function zlangt(NORM, N, DL, D, DU)
ZLANGT returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: zlangt.f:108
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
subroutine zgtrfs(TRANS, N, NRHS, DL, D, DU, DLF, DF, DUF, DU2, IPIV, B, LDB, X, LDX, FERR, BERR, WORK, RWORK, INFO)
ZGTRFS
Definition: zgtrfs.f:212

Here is the call graph for this function:

Here is the caller graph for this function: