LAPACK  3.6.1
LAPACK: Linear Algebra PACKage
subroutine sggqrf ( integer  N,
integer  M,
integer  P,
real, dimension( lda, * )  A,
integer  LDA,
real, dimension( * )  TAUA,
real, dimension( ldb, * )  B,
integer  LDB,
real, dimension( * )  TAUB,
real, dimension( * )  WORK,
integer  LWORK,
integer  INFO 
)

SGGQRF

Download SGGQRF + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 SGGQRF computes a generalized QR factorization of an N-by-M matrix A
 and an N-by-P matrix B:

             A = Q*R,        B = Q*T*Z,

 where Q is an N-by-N orthogonal matrix, Z is a P-by-P orthogonal
 matrix, and R and T assume one of the forms:

 if N >= M,  R = ( R11 ) M  ,   or if N < M,  R = ( R11  R12 ) N,
                 (  0  ) N-M                         N   M-N
                    M

 where R11 is upper triangular, and

 if N <= P,  T = ( 0  T12 ) N,   or if N > P,  T = ( T11 ) N-P,
                  P-N  N                           ( T21 ) P
                                                      P

 where T12 or T21 is upper triangular.

 In particular, if B is square and nonsingular, the GQR factorization
 of A and B implicitly gives the QR factorization of inv(B)*A:

              inv(B)*A = Z**T*(inv(T)*R)

 where inv(B) denotes the inverse of the matrix B, and Z**T denotes the
 transpose of the matrix Z.
Parameters
[in]N
          N is INTEGER
          The number of rows of the matrices A and B. N >= 0.
[in]M
          M is INTEGER
          The number of columns of the matrix A.  M >= 0.
[in]P
          P is INTEGER
          The number of columns of the matrix B.  P >= 0.
[in,out]A
          A is REAL array, dimension (LDA,M)
          On entry, the N-by-M matrix A.
          On exit, the elements on and above the diagonal of the array
          contain the min(N,M)-by-M upper trapezoidal matrix R (R is
          upper triangular if N >= M); the elements below the diagonal,
          with the array TAUA, represent the orthogonal matrix Q as a
          product of min(N,M) elementary reflectors (see Further
          Details).
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A. LDA >= max(1,N).
[out]TAUA
          TAUA is REAL array, dimension (min(N,M))
          The scalar factors of the elementary reflectors which
          represent the orthogonal matrix Q (see Further Details).
[in,out]B
          B is REAL array, dimension (LDB,P)
          On entry, the N-by-P matrix B.
          On exit, if N <= P, the upper triangle of the subarray
          B(1:N,P-N+1:P) contains the N-by-N upper triangular matrix T;
          if N > P, the elements on and above the (N-P)-th subdiagonal
          contain the N-by-P upper trapezoidal matrix T; the remaining
          elements, with the array TAUB, represent the orthogonal
          matrix Z as a product of elementary reflectors (see Further
          Details).
[in]LDB
          LDB is INTEGER
          The leading dimension of the array B. LDB >= max(1,N).
[out]TAUB
          TAUB is REAL array, dimension (min(N,P))
          The scalar factors of the elementary reflectors which
          represent the orthogonal matrix Z (see Further Details).
[out]WORK
          WORK is REAL array, dimension (MAX(1,LWORK))
          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
[in]LWORK
          LWORK is INTEGER
          The dimension of the array WORK. LWORK >= max(1,N,M,P).
          For optimum performance LWORK >= max(N,M,P)*max(NB1,NB2,NB3),
          where NB1 is the optimal blocksize for the QR factorization
          of an N-by-M matrix, NB2 is the optimal blocksize for the
          RQ factorization of an N-by-P matrix, and NB3 is the optimal
          blocksize for a call of SORMQR.

          If LWORK = -1, then a workspace query is assumed; the routine
          only calculates the optimal size of the WORK array, returns
          this value as the first entry of the WORK array, and no error
          message related to LWORK is issued by XERBLA.
[out]INFO
          INFO is INTEGER
          = 0:  successful exit
          < 0:  if INFO = -i, the i-th argument had an illegal value.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
November 2011
Further Details:
  The matrix Q is represented as a product of elementary reflectors

     Q = H(1) H(2) . . . H(k), where k = min(n,m).

  Each H(i) has the form

     H(i) = I - taua * v * v**T

  where taua is a real scalar, and v is a real vector with
  v(1:i-1) = 0 and v(i) = 1; v(i+1:n) is stored on exit in A(i+1:n,i),
  and taua in TAUA(i).
  To form Q explicitly, use LAPACK subroutine SORGQR.
  To use Q to update another matrix, use LAPACK subroutine SORMQR.

  The matrix Z is represented as a product of elementary reflectors

     Z = H(1) H(2) . . . H(k), where k = min(n,p).

  Each H(i) has the form

     H(i) = I - taub * v * v**T

  where taub is a real scalar, and v is a real vector with
  v(p-k+i+1:p) = 0 and v(p-k+i) = 1; v(1:p-k+i-1) is stored on exit in
  B(n-k+i,1:p-k+i-1), and taub in TAUB(i).
  To form Z explicitly, use LAPACK subroutine SORGRQ.
  To use Z to update another matrix, use LAPACK subroutine SORMRQ.

Definition at line 217 of file sggqrf.f.

217 *
218 * -- LAPACK computational routine (version 3.4.0) --
219 * -- LAPACK is a software package provided by Univ. of Tennessee, --
220 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
221 * November 2011
222 *
223 * .. Scalar Arguments ..
224  INTEGER info, lda, ldb, lwork, m, n, p
225 * ..
226 * .. Array Arguments ..
227  REAL a( lda, * ), b( ldb, * ), taua( * ), taub( * ),
228  $ work( * )
229 * ..
230 *
231 * =====================================================================
232 *
233 * .. Local Scalars ..
234  LOGICAL lquery
235  INTEGER lopt, lwkopt, nb, nb1, nb2, nb3
236 * ..
237 * .. External Subroutines ..
238  EXTERNAL sgeqrf, sgerqf, sormqr, xerbla
239 * ..
240 * .. External Functions ..
241  INTEGER ilaenv
242  EXTERNAL ilaenv
243 * ..
244 * .. Intrinsic Functions ..
245  INTRINSIC int, max, min
246 * ..
247 * .. Executable Statements ..
248 *
249 * Test the input parameters
250 *
251  info = 0
252  nb1 = ilaenv( 1, 'SGEQRF', ' ', n, m, -1, -1 )
253  nb2 = ilaenv( 1, 'SGERQF', ' ', n, p, -1, -1 )
254  nb3 = ilaenv( 1, 'SORMQR', ' ', n, m, p, -1 )
255  nb = max( nb1, nb2, nb3 )
256  lwkopt = max( n, m, p )*nb
257  work( 1 ) = lwkopt
258  lquery = ( lwork.EQ.-1 )
259  IF( n.LT.0 ) THEN
260  info = -1
261  ELSE IF( m.LT.0 ) THEN
262  info = -2
263  ELSE IF( p.LT.0 ) THEN
264  info = -3
265  ELSE IF( lda.LT.max( 1, n ) ) THEN
266  info = -5
267  ELSE IF( ldb.LT.max( 1, n ) ) THEN
268  info = -8
269  ELSE IF( lwork.LT.max( 1, n, m, p ) .AND. .NOT.lquery ) THEN
270  info = -11
271  END IF
272  IF( info.NE.0 ) THEN
273  CALL xerbla( 'SGGQRF', -info )
274  RETURN
275  ELSE IF( lquery ) THEN
276  RETURN
277  END IF
278 *
279 * QR factorization of N-by-M matrix A: A = Q*R
280 *
281  CALL sgeqrf( n, m, a, lda, taua, work, lwork, info )
282  lopt = work( 1 )
283 *
284 * Update B := Q**T*B.
285 *
286  CALL sormqr( 'Left', 'Transpose', n, p, min( n, m ), a, lda, taua,
287  $ b, ldb, work, lwork, info )
288  lopt = max( lopt, int( work( 1 ) ) )
289 *
290 * RQ factorization of N-by-P matrix B: B = T*Z.
291 *
292  CALL sgerqf( n, p, b, ldb, taub, work, lwork, info )
293  work( 1 ) = max( lopt, int( work( 1 ) ) )
294 *
295  RETURN
296 *
297 * End of SGGQRF
298 *
subroutine sormqr(SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK, LWORK, INFO)
SORMQR
Definition: sormqr.f:170
subroutine sgeqrf(M, N, A, LDA, TAU, WORK, LWORK, INFO)
SGEQRF
Definition: sgeqrf.f:138
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine sgerqf(M, N, A, LDA, TAU, WORK, LWORK, INFO)
SGERQF
Definition: sgerqf.f:140
integer function ilaenv(ISPEC, NAME, OPTS, N1, N2, N3, N4)
Definition: tstiee.f:83

Here is the call graph for this function:

Here is the caller graph for this function: