LAPACK  3.6.1
LAPACK: Linear Algebra PACKage
subroutine cgeqr2 ( integer  M,
integer  N,
complex, dimension( lda, * )  A,
integer  LDA,
complex, dimension( * )  TAU,
complex, dimension( * )  WORK,
integer  INFO 
)

CGEQR2 computes the QR factorization of a general rectangular matrix using an unblocked algorithm.

Download CGEQR2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 CGEQR2 computes a QR factorization of a complex m by n matrix A:
 A = Q * R.
Parameters
[in]M
          M is INTEGER
          The number of rows of the matrix A.  M >= 0.
[in]N
          N is INTEGER
          The number of columns of the matrix A.  N >= 0.
[in,out]A
          A is COMPLEX array, dimension (LDA,N)
          On entry, the m by n matrix A.
          On exit, the elements on and above the diagonal of the array
          contain the min(m,n) by n upper trapezoidal matrix R (R is
          upper triangular if m >= n); the elements below the diagonal,
          with the array TAU, represent the unitary matrix Q as a
          product of elementary reflectors (see Further Details).
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,M).
[out]TAU
          TAU is COMPLEX array, dimension (min(M,N))
          The scalar factors of the elementary reflectors (see Further
          Details).
[out]WORK
          WORK is COMPLEX array, dimension (N)
[out]INFO
          INFO is INTEGER
          = 0: successful exit
          < 0: if INFO = -i, the i-th argument had an illegal value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
September 2012
Further Details:
  The matrix Q is represented as a product of elementary reflectors

     Q = H(1) H(2) . . . H(k), where k = min(m,n).

  Each H(i) has the form

     H(i) = I - tau * v * v**H

  where tau is a complex scalar, and v is a complex vector with
  v(1:i-1) = 0 and v(i) = 1; v(i+1:m) is stored on exit in A(i+1:m,i),
  and tau in TAU(i).

Definition at line 123 of file cgeqr2.f.

123 *
124 * -- LAPACK computational routine (version 3.4.2) --
125 * -- LAPACK is a software package provided by Univ. of Tennessee, --
126 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
127 * September 2012
128 *
129 * .. Scalar Arguments ..
130  INTEGER info, lda, m, n
131 * ..
132 * .. Array Arguments ..
133  COMPLEX a( lda, * ), tau( * ), work( * )
134 * ..
135 *
136 * =====================================================================
137 *
138 * .. Parameters ..
139  COMPLEX one
140  parameter ( one = ( 1.0e+0, 0.0e+0 ) )
141 * ..
142 * .. Local Scalars ..
143  INTEGER i, k
144  COMPLEX alpha
145 * ..
146 * .. External Subroutines ..
147  EXTERNAL clarf, clarfg, xerbla
148 * ..
149 * .. Intrinsic Functions ..
150  INTRINSIC conjg, max, min
151 * ..
152 * .. Executable Statements ..
153 *
154 * Test the input arguments
155 *
156  info = 0
157  IF( m.LT.0 ) THEN
158  info = -1
159  ELSE IF( n.LT.0 ) THEN
160  info = -2
161  ELSE IF( lda.LT.max( 1, m ) ) THEN
162  info = -4
163  END IF
164  IF( info.NE.0 ) THEN
165  CALL xerbla( 'CGEQR2', -info )
166  RETURN
167  END IF
168 *
169  k = min( m, n )
170 *
171  DO 10 i = 1, k
172 *
173 * Generate elementary reflector H(i) to annihilate A(i+1:m,i)
174 *
175  CALL clarfg( m-i+1, a( i, i ), a( min( i+1, m ), i ), 1,
176  $ tau( i ) )
177  IF( i.LT.n ) THEN
178 *
179 * Apply H(i)**H to A(i:m,i+1:n) from the left
180 *
181  alpha = a( i, i )
182  a( i, i ) = one
183  CALL clarf( 'Left', m-i+1, n-i, a( i, i ), 1,
184  $ conjg( tau( i ) ), a( i, i+1 ), lda, work )
185  a( i, i ) = alpha
186  END IF
187  10 CONTINUE
188  RETURN
189 *
190 * End of CGEQR2
191 *
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine clarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
CLARF applies an elementary reflector to a general rectangular matrix.
Definition: clarf.f:130
subroutine clarfg(N, ALPHA, X, INCX, TAU)
CLARFG generates an elementary reflector (Householder matrix).
Definition: clarfg.f:108

Here is the call graph for this function:

Here is the caller graph for this function: