LAPACK  3.6.1
LAPACK: Linear Algebra PACKage
subroutine chesvxx ( character  FACT,
character  UPLO,
integer  N,
integer  NRHS,
complex, dimension( lda, * )  A,
integer  LDA,
complex, dimension( ldaf, * )  AF,
integer  LDAF,
integer, dimension( * )  IPIV,
character  EQUED,
real, dimension( * )  S,
complex, dimension( ldb, * )  B,
integer  LDB,
complex, dimension( ldx, * )  X,
integer  LDX,
real  RCOND,
real  RPVGRW,
real, dimension( * )  BERR,
integer  N_ERR_BNDS,
real, dimension( nrhs, * )  ERR_BNDS_NORM,
real, dimension( nrhs, * )  ERR_BNDS_COMP,
integer  NPARAMS,
real, dimension( * )  PARAMS,
complex, dimension( * )  WORK,
real, dimension( * )  RWORK,
integer  INFO 
)

CHESVXX computes the solution to system of linear equations A * X = B for HE matrices

Download CHESVXX + dependencies [TGZ] [ZIP] [TXT]

Purpose:
    CHESVXX uses the diagonal pivoting factorization to compute the
    solution to a complex system of linear equations A * X = B, where
    A is an N-by-N symmetric matrix and X and B are N-by-NRHS
    matrices.

    If requested, both normwise and maximum componentwise error bounds
    are returned. CHESVXX will return a solution with a tiny
    guaranteed error (O(eps) where eps is the working machine
    precision) unless the matrix is very ill-conditioned, in which
    case a warning is returned. Relevant condition numbers also are
    calculated and returned.

    CHESVXX accepts user-provided factorizations and equilibration
    factors; see the definitions of the FACT and EQUED options.
    Solving with refinement and using a factorization from a previous
    CHESVXX call will also produce a solution with either O(eps)
    errors or warnings, but we cannot make that claim for general
    user-provided factorizations and equilibration factors if they
    differ from what CHESVXX would itself produce.
Description:
    The following steps are performed:

    1. If FACT = 'E', real scaling factors are computed to equilibrate
    the system:

      diag(S)*A*diag(S)     *inv(diag(S))*X = diag(S)*B

    Whether or not the system will be equilibrated depends on the
    scaling of the matrix A, but if equilibration is used, A is
    overwritten by diag(S)*A*diag(S) and B by diag(S)*B.

    2. If FACT = 'N' or 'E', the LU decomposition is used to factor
    the matrix A (after equilibration if FACT = 'E') as

       A = U * D * U**T,  if UPLO = 'U', or
       A = L * D * L**T,  if UPLO = 'L',

    where U (or L) is a product of permutation and unit upper (lower)
    triangular matrices, and D is symmetric and block diagonal with
    1-by-1 and 2-by-2 diagonal blocks.

    3. If some D(i,i)=0, so that D is exactly singular, then the
    routine returns with INFO = i. Otherwise, the factored form of A
    is used to estimate the condition number of the matrix A (see
    argument RCOND).  If the reciprocal of the condition number is
    less than machine precision, the routine still goes on to solve
    for X and compute error bounds as described below.

    4. The system of equations is solved for X using the factored form
    of A.

    5. By default (unless PARAMS(LA_LINRX_ITREF_I) is set to zero),
    the routine will use iterative refinement to try to get a small
    error and error bounds.  Refinement calculates the residual to at
    least twice the working precision.

    6. If equilibration was used, the matrix X is premultiplied by
    diag(R) so that it solves the original system before
    equilibration.
     Some optional parameters are bundled in the PARAMS array.  These
     settings determine how refinement is performed, but often the
     defaults are acceptable.  If the defaults are acceptable, users
     can pass NPARAMS = 0 which prevents the source code from accessing
     the PARAMS argument.
Parameters
[in]FACT
          FACT is CHARACTER*1
     Specifies whether or not the factored form of the matrix A is
     supplied on entry, and if not, whether the matrix A should be
     equilibrated before it is factored.
       = 'F':  On entry, AF and IPIV contain the factored form of A.
               If EQUED is not 'N', the matrix A has been
               equilibrated with scaling factors given by S.
               A, AF, and IPIV are not modified.
       = 'N':  The matrix A will be copied to AF and factored.
       = 'E':  The matrix A will be equilibrated if necessary, then
               copied to AF and factored.
[in]UPLO
          UPLO is CHARACTER*1
       = 'U':  Upper triangle of A is stored;
       = 'L':  Lower triangle of A is stored.
[in]N
          N is INTEGER
     The number of linear equations, i.e., the order of the
     matrix A.  N >= 0.
[in]NRHS
          NRHS is INTEGER
     The number of right hand sides, i.e., the number of columns
     of the matrices B and X.  NRHS >= 0.
[in,out]A
          A is COMPLEX array, dimension (LDA,N)
     The symmetric matrix A.  If UPLO = 'U', the leading N-by-N
     upper triangular part of A contains the upper triangular
     part of the matrix A, and the strictly lower triangular
     part of A is not referenced.  If UPLO = 'L', the leading
     N-by-N lower triangular part of A contains the lower
     triangular part of the matrix A, and the strictly upper
     triangular part of A is not referenced.

     On exit, if FACT = 'E' and EQUED = 'Y', A is overwritten by
     diag(S)*A*diag(S).
[in]LDA
          LDA is INTEGER
     The leading dimension of the array A.  LDA >= max(1,N).
[in,out]AF
          AF is COMPLEX array, dimension (LDAF,N)
     If FACT = 'F', then AF is an input argument and on entry
     contains the block diagonal matrix D and the multipliers
     used to obtain the factor U or L from the factorization A =
     U*D*U**T or A = L*D*L**T as computed by SSYTRF.

     If FACT = 'N', then AF is an output argument and on exit
     returns the block diagonal matrix D and the multipliers
     used to obtain the factor U or L from the factorization A =
     U*D*U**T or A = L*D*L**T.
[in]LDAF
          LDAF is INTEGER
     The leading dimension of the array AF.  LDAF >= max(1,N).
[in,out]IPIV
          IPIV is INTEGER array, dimension (N)
     If FACT = 'F', then IPIV is an input argument and on entry
     contains details of the interchanges and the block
     structure of D, as determined by CHETRF.  If IPIV(k) > 0,
     then rows and columns k and IPIV(k) were interchanged and
     D(k,k) is a 1-by-1 diagonal block.  If UPLO = 'U' and
     IPIV(k) = IPIV(k-1) < 0, then rows and columns k-1 and
     -IPIV(k) were interchanged and D(k-1:k,k-1:k) is a 2-by-2
     diagonal block.  If UPLO = 'L' and IPIV(k) = IPIV(k+1) < 0,
     then rows and columns k+1 and -IPIV(k) were interchanged
     and D(k:k+1,k:k+1) is a 2-by-2 diagonal block.

     If FACT = 'N', then IPIV is an output argument and on exit
     contains details of the interchanges and the block
     structure of D, as determined by CHETRF.
[in,out]EQUED
          EQUED is CHARACTER*1
     Specifies the form of equilibration that was done.
       = 'N':  No equilibration (always true if FACT = 'N').
       = 'Y':  Both row and column equilibration, i.e., A has been
               replaced by diag(S) * A * diag(S).
     EQUED is an input argument if FACT = 'F'; otherwise, it is an
     output argument.
[in,out]S
          S is REAL array, dimension (N)
     The scale factors for A.  If EQUED = 'Y', A is multiplied on
     the left and right by diag(S).  S is an input argument if FACT =
     'F'; otherwise, S is an output argument.  If FACT = 'F' and EQUED
     = 'Y', each element of S must be positive.  If S is output, each
     element of S is a power of the radix. If S is input, each element
     of S should be a power of the radix to ensure a reliable solution
     and error estimates. Scaling by powers of the radix does not cause
     rounding errors unless the result underflows or overflows.
     Rounding errors during scaling lead to refining with a matrix that
     is not equivalent to the input matrix, producing error estimates
     that may not be reliable.
[in,out]B
          B is COMPLEX array, dimension (LDB,NRHS)
     On entry, the N-by-NRHS right hand side matrix B.
     On exit,
     if EQUED = 'N', B is not modified;
     if EQUED = 'Y', B is overwritten by diag(S)*B;
[in]LDB
          LDB is INTEGER
     The leading dimension of the array B.  LDB >= max(1,N).
[out]X
          X is COMPLEX array, dimension (LDX,NRHS)
     If INFO = 0, the N-by-NRHS solution matrix X to the original
     system of equations.  Note that A and B are modified on exit if
     EQUED .ne. 'N', and the solution to the equilibrated system is
     inv(diag(S))*X.
[in]LDX
          LDX is INTEGER
     The leading dimension of the array X.  LDX >= max(1,N).
[out]RCOND
          RCOND is REAL
     Reciprocal scaled condition number.  This is an estimate of the
     reciprocal Skeel condition number of the matrix A after
     equilibration (if done).  If this is less than the machine
     precision (in particular, if it is zero), the matrix is singular
     to working precision.  Note that the error may still be small even
     if this number is very small and the matrix appears ill-
     conditioned.
[out]RPVGRW
          RPVGRW is REAL
     Reciprocal pivot growth.  On exit, this contains the reciprocal
     pivot growth factor norm(A)/norm(U). The "max absolute element"
     norm is used.  If this is much less than 1, then the stability of
     the LU factorization of the (equilibrated) matrix A could be poor.
     This also means that the solution X, estimated condition numbers,
     and error bounds could be unreliable. If factorization fails with
     0<INFO<=N, then this contains the reciprocal pivot growth factor
     for the leading INFO columns of A.
[out]BERR
          BERR is REAL array, dimension (NRHS)
     Componentwise relative backward error.  This is the
     componentwise relative backward error of each solution vector X(j)
     (i.e., the smallest relative change in any element of A or B that
     makes X(j) an exact solution).
[in]N_ERR_BNDS
          N_ERR_BNDS is INTEGER
     Number of error bounds to return for each right hand side
     and each type (normwise or componentwise).  See ERR_BNDS_NORM and
     ERR_BNDS_COMP below.
[out]ERR_BNDS_NORM
          ERR_BNDS_NORM is REAL array, dimension (NRHS, N_ERR_BNDS)
     For each right-hand side, this array contains information about
     various error bounds and condition numbers corresponding to the
     normwise relative error, which is defined as follows:

     Normwise relative error in the ith solution vector:
             max_j (abs(XTRUE(j,i) - X(j,i)))
            ------------------------------
                  max_j abs(X(j,i))

     The array is indexed by the type of error information as described
     below. There currently are up to three pieces of information
     returned.

     The first index in ERR_BNDS_NORM(i,:) corresponds to the ith
     right-hand side.

     The second index in ERR_BNDS_NORM(:,err) contains the following
     three fields:
     err = 1 "Trust/don't trust" boolean. Trust the answer if the
              reciprocal condition number is less than the threshold
              sqrt(n) * slamch('Epsilon').

     err = 2 "Guaranteed" error bound: The estimated forward error,
              almost certainly within a factor of 10 of the true error
              so long as the next entry is greater than the threshold
              sqrt(n) * slamch('Epsilon'). This error bound should only
              be trusted if the previous boolean is true.

     err = 3  Reciprocal condition number: Estimated normwise
              reciprocal condition number.  Compared with the threshold
              sqrt(n) * slamch('Epsilon') to determine if the error
              estimate is "guaranteed". These reciprocal condition
              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
              appropriately scaled matrix Z.
              Let Z = S*A, where S scales each row by a power of the
              radix so all absolute row sums of Z are approximately 1.

     See Lapack Working Note 165 for further details and extra
     cautions.
[out]ERR_BNDS_COMP
          ERR_BNDS_COMP is REAL array, dimension (NRHS, N_ERR_BNDS)
     For each right-hand side, this array contains information about
     various error bounds and condition numbers corresponding to the
     componentwise relative error, which is defined as follows:

     Componentwise relative error in the ith solution vector:
                    abs(XTRUE(j,i) - X(j,i))
             max_j ----------------------
                         abs(X(j,i))

     The array is indexed by the right-hand side i (on which the
     componentwise relative error depends), and the type of error
     information as described below. There currently are up to three
     pieces of information returned for each right-hand side. If
     componentwise accuracy is not requested (PARAMS(3) = 0.0), then
     ERR_BNDS_COMP is not accessed.  If N_ERR_BNDS .LT. 3, then at most
     the first (:,N_ERR_BNDS) entries are returned.

     The first index in ERR_BNDS_COMP(i,:) corresponds to the ith
     right-hand side.

     The second index in ERR_BNDS_COMP(:,err) contains the following
     three fields:
     err = 1 "Trust/don't trust" boolean. Trust the answer if the
              reciprocal condition number is less than the threshold
              sqrt(n) * slamch('Epsilon').

     err = 2 "Guaranteed" error bound: The estimated forward error,
              almost certainly within a factor of 10 of the true error
              so long as the next entry is greater than the threshold
              sqrt(n) * slamch('Epsilon'). This error bound should only
              be trusted if the previous boolean is true.

     err = 3  Reciprocal condition number: Estimated componentwise
              reciprocal condition number.  Compared with the threshold
              sqrt(n) * slamch('Epsilon') to determine if the error
              estimate is "guaranteed". These reciprocal condition
              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
              appropriately scaled matrix Z.
              Let Z = S*(A*diag(x)), where x is the solution for the
              current right-hand side and S scales each row of
              A*diag(x) by a power of the radix so all absolute row
              sums of Z are approximately 1.

     See Lapack Working Note 165 for further details and extra
     cautions.
[in]NPARAMS
          NPARAMS is INTEGER
     Specifies the number of parameters set in PARAMS.  If .LE. 0, the
     PARAMS array is never referenced and default values are used.
[in,out]PARAMS
          PARAMS is REAL array, dimension NPARAMS
     Specifies algorithm parameters.  If an entry is .LT. 0.0, then
     that entry will be filled with default value used for that
     parameter.  Only positions up to NPARAMS are accessed; defaults
     are used for higher-numbered parameters.

       PARAMS(LA_LINRX_ITREF_I = 1) : Whether to perform iterative
            refinement or not.
         Default: 1.0
            = 0.0 : No refinement is performed, and no error bounds are
                    computed.
            = 1.0 : Use the double-precision refinement algorithm,
                    possibly with doubled-single computations if the
                    compilation environment does not support DOUBLE
                    PRECISION.
              (other values are reserved for future use)

       PARAMS(LA_LINRX_ITHRESH_I = 2) : Maximum number of residual
            computations allowed for refinement.
         Default: 10
         Aggressive: Set to 100 to permit convergence using approximate
                     factorizations or factorizations other than LU. If
                     the factorization uses a technique other than
                     Gaussian elimination, the guarantees in
                     err_bnds_norm and err_bnds_comp may no longer be
                     trustworthy.

       PARAMS(LA_LINRX_CWISE_I = 3) : Flag determining if the code
            will attempt to find a solution with small componentwise
            relative error in the double-precision algorithm.  Positive
            is true, 0.0 is false.
         Default: 1.0 (attempt componentwise convergence)
[out]WORK
          WORK is COMPLEX array, dimension (5*N)
[out]RWORK
          RWORK is REAL array, dimension (2*N)
[out]INFO
          INFO is INTEGER
       = 0:  Successful exit. The solution to every right-hand side is
         guaranteed.
       < 0:  If INFO = -i, the i-th argument had an illegal value
       > 0 and <= N:  U(INFO,INFO) is exactly zero.  The factorization
         has been completed, but the factor U is exactly singular, so
         the solution and error bounds could not be computed. RCOND = 0
         is returned.
       = N+J: The solution corresponding to the Jth right-hand side is
         not guaranteed. The solutions corresponding to other right-
         hand sides K with K > J may not be guaranteed as well, but
         only the first such right-hand side is reported. If a small
         componentwise error is not requested (PARAMS(3) = 0.0) then
         the Jth right-hand side is the first with a normwise error
         bound that is not guaranteed (the smallest J such
         that ERR_BNDS_NORM(J,1) = 0.0). By default (PARAMS(3) = 1.0)
         the Jth right-hand side is the first with either a normwise or
         componentwise error bound that is not guaranteed (the smallest
         J such that either ERR_BNDS_NORM(J,1) = 0.0 or
         ERR_BNDS_COMP(J,1) = 0.0). See the definition of
         ERR_BNDS_NORM(:,1) and ERR_BNDS_COMP(:,1). To get information
         about all of the right-hand sides check ERR_BNDS_NORM or
         ERR_BNDS_COMP.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
April 2012

Definition at line 511 of file chesvxx.f.

511 *
512 * -- LAPACK driver routine (version 3.4.1) --
513 * -- LAPACK is a software package provided by Univ. of Tennessee, --
514 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
515 * April 2012
516 *
517 * .. Scalar Arguments ..
518  CHARACTER equed, fact, uplo
519  INTEGER info, lda, ldaf, ldb, ldx, n, nrhs, nparams,
520  $ n_err_bnds
521  REAL rcond, rpvgrw
522 * ..
523 * .. Array Arguments ..
524  INTEGER ipiv( * )
525  COMPLEX a( lda, * ), af( ldaf, * ), b( ldb, * ),
526  $ work( * ), x( ldx, * )
527  REAL s( * ), params( * ), berr( * ), rwork( * ),
528  $ err_bnds_norm( nrhs, * ),
529  $ err_bnds_comp( nrhs, * )
530 * ..
531 *
532 * ==================================================================
533 *
534 * .. Parameters ..
535  REAL zero, one
536  parameter ( zero = 0.0e+0, one = 1.0e+0 )
537  INTEGER final_nrm_err_i, final_cmp_err_i, berr_i
538  INTEGER rcond_i, nrm_rcond_i, nrm_err_i, cmp_rcond_i
539  INTEGER cmp_err_i, piv_growth_i
540  parameter ( final_nrm_err_i = 1, final_cmp_err_i = 2,
541  $ berr_i = 3 )
542  parameter ( rcond_i = 4, nrm_rcond_i = 5, nrm_err_i = 6 )
543  parameter ( cmp_rcond_i = 7, cmp_err_i = 8,
544  $ piv_growth_i = 9 )
545 * ..
546 * .. Local Scalars ..
547  LOGICAL equil, nofact, rcequ
548  INTEGER infequ, j
549  REAL amax, bignum, smin, smax, scond, smlnum
550 * ..
551 * .. External Functions ..
552  EXTERNAL lsame, slamch, cla_herpvgrw
553  LOGICAL lsame
554  REAL slamch, cla_herpvgrw
555 * ..
556 * .. External Subroutines ..
557  EXTERNAL checon, cheequb, chetrf, chetrs, clacpy,
559 * ..
560 * .. Intrinsic Functions ..
561  INTRINSIC max, min
562 * ..
563 * .. Executable Statements ..
564 *
565  info = 0
566  nofact = lsame( fact, 'N' )
567  equil = lsame( fact, 'E' )
568  smlnum = slamch( 'Safe minimum' )
569  bignum = one / smlnum
570  IF( nofact .OR. equil ) THEN
571  equed = 'N'
572  rcequ = .false.
573  ELSE
574  rcequ = lsame( equed, 'Y' )
575  ENDIF
576 *
577 * Default is failure. If an input parameter is wrong or
578 * factorization fails, make everything look horrible. Only the
579 * pivot growth is set here, the rest is initialized in CHERFSX.
580 *
581  rpvgrw = zero
582 *
583 * Test the input parameters. PARAMS is not tested until CHERFSX.
584 *
585  IF( .NOT.nofact .AND. .NOT.equil .AND. .NOT.
586  $ lsame( fact, 'F' ) ) THEN
587  info = -1
588  ELSE IF( .NOT.lsame( uplo, 'U' ) .AND.
589  $ .NOT.lsame( uplo, 'L' ) ) THEN
590  info = -2
591  ELSE IF( n.LT.0 ) THEN
592  info = -3
593  ELSE IF( nrhs.LT.0 ) THEN
594  info = -4
595  ELSE IF( lda.LT.max( 1, n ) ) THEN
596  info = -6
597  ELSE IF( ldaf.LT.max( 1, n ) ) THEN
598  info = -8
599  ELSE IF( lsame( fact, 'F' ) .AND. .NOT.
600  $ ( rcequ .OR. lsame( equed, 'N' ) ) ) THEN
601  info = -9
602  ELSE
603  IF ( rcequ ) THEN
604  smin = bignum
605  smax = zero
606  DO 10 j = 1, n
607  smin = min( smin, s( j ) )
608  smax = max( smax, s( j ) )
609  10 CONTINUE
610  IF( smin.LE.zero ) THEN
611  info = -10
612  ELSE IF( n.GT.0 ) THEN
613  scond = max( smin, smlnum ) / min( smax, bignum )
614  ELSE
615  scond = one
616  END IF
617  END IF
618  IF( info.EQ.0 ) THEN
619  IF( ldb.LT.max( 1, n ) ) THEN
620  info = -12
621  ELSE IF( ldx.LT.max( 1, n ) ) THEN
622  info = -14
623  END IF
624  END IF
625  END IF
626 *
627  IF( info.NE.0 ) THEN
628  CALL xerbla( 'CHESVXX', -info )
629  RETURN
630  END IF
631 *
632  IF( equil ) THEN
633 *
634 * Compute row and column scalings to equilibrate the matrix A.
635 *
636  CALL cheequb( uplo, n, a, lda, s, scond, amax, work, infequ )
637  IF( infequ.EQ.0 ) THEN
638 *
639 * Equilibrate the matrix.
640 *
641  CALL claqhe( uplo, n, a, lda, s, scond, amax, equed )
642  rcequ = lsame( equed, 'Y' )
643  END IF
644  END IF
645 *
646 * Scale the right-hand side.
647 *
648  IF( rcequ ) CALL clascl2( n, nrhs, s, b, ldb )
649 *
650  IF( nofact .OR. equil ) THEN
651 *
652 * Compute the LDL^T or UDU^T factorization of A.
653 *
654  CALL clacpy( uplo, n, n, a, lda, af, ldaf )
655  CALL chetrf( uplo, n, af, ldaf, ipiv, work, 5*max(1,n), info )
656 *
657 * Return if INFO is non-zero.
658 *
659  IF( info.GT.0 ) THEN
660 *
661 * Pivot in column INFO is exactly 0
662 * Compute the reciprocal pivot growth factor of the
663 * leading rank-deficient INFO columns of A.
664 *
665  IF( n.GT.0 )
666  $ rpvgrw = cla_herpvgrw( uplo, n, info, a, lda, af, ldaf,
667  $ ipiv, rwork )
668  RETURN
669  END IF
670  END IF
671 *
672 * Compute the reciprocal pivot growth factor RPVGRW.
673 *
674  IF( n.GT.0 )
675  $ rpvgrw = cla_herpvgrw( uplo, n, info, a, lda, af, ldaf, ipiv,
676  $ rwork )
677 *
678 * Compute the solution matrix X.
679 *
680  CALL clacpy( 'Full', n, nrhs, b, ldb, x, ldx )
681  CALL chetrs( uplo, n, nrhs, af, ldaf, ipiv, x, ldx, info )
682 *
683 * Use iterative refinement to improve the computed solution and
684 * compute error bounds and backward error estimates for it.
685 *
686  CALL cherfsx( uplo, equed, n, nrhs, a, lda, af, ldaf, ipiv,
687  $ s, b, ldb, x, ldx, rcond, berr, n_err_bnds, err_bnds_norm,
688  $ err_bnds_comp, nparams, params, work, rwork, info )
689 *
690 * Scale solutions.
691 *
692  IF ( rcequ ) THEN
693  CALL clascl2 ( n, nrhs, s, x, ldx )
694  END IF
695 *
696  RETURN
697 *
698 * End of CHESVXX
699 *
subroutine claqhe(UPLO, N, A, LDA, S, SCOND, AMAX, EQUED)
CLAQHE scales a Hermitian matrix.
Definition: claqhe.f:136
real function cla_herpvgrw(UPLO, N, INFO, A, LDA, AF, LDAF, IPIV, WORK)
CLA_HERPVGRW
Definition: cla_herpvgrw.f:125
subroutine cheequb(UPLO, N, A, LDA, S, SCOND, AMAX, WORK, INFO)
CHEEQUB
Definition: cheequb.f:128
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine clascl2(M, N, D, X, LDX)
CLASCL2 performs diagonal scaling on a vector.
Definition: clascl2.f:93
subroutine cherfsx(UPLO, EQUED, N, NRHS, A, LDA, AF, LDAF, IPIV, S, B, LDB, X, LDX, RCOND, BERR, N_ERR_BNDS, ERR_BNDS_NORM, ERR_BNDS_COMP, NPARAMS, PARAMS, WORK, RWORK, INFO)
CHERFSX
Definition: cherfsx.f:403
subroutine chetrs(UPLO, N, NRHS, A, LDA, IPIV, B, LDB, INFO)
CHETRS
Definition: chetrs.f:122
subroutine chetrf(UPLO, N, A, LDA, IPIV, WORK, LWORK, INFO)
CHETRF
Definition: chetrf.f:179
subroutine checon(UPLO, N, A, LDA, IPIV, ANORM, RCOND, WORK, INFO)
CHECON
Definition: checon.f:127
subroutine clacpy(UPLO, M, N, A, LDA, B, LDB)
CLACPY copies all or part of one two-dimensional array to another.
Definition: clacpy.f:105
real function slamch(CMACH)
SLAMCH
Definition: slamch.f:69
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55

Here is the call graph for this function:

Here is the caller graph for this function: