cdrvpox.f

Go to the documentation of this file.

*> \brief \b CDRVPOX
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE CDRVPO( DOTYPE, NN, NVAL, NRHS, THRESH, TSTERR, NMAX,
*                          A, AFAC, ASAV, B, BSAV, X, XACT, S, WORK,
*                          RWORK, NOUT )
* 
*       .. Scalar Arguments ..
*       LOGICAL            TSTERR
*       INTEGER            NMAX, NN, NOUT, NRHS
*       REAL               THRESH
*       ..
*       .. Array Arguments ..
*       LOGICAL            DOTYPE( * )
*       INTEGER            NVAL( * )
*       REAL               RWORK( * ), S( * )
*       COMPLEX            A( * ), AFAC( * ), ASAV( * ), B( * ),
*      $                   BSAV( * ), WORK( * ), X( * ), XACT( * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CDRVPO tests the driver routines CPOSV, -SVX, and -SVXX.
*>
*> Note that this file is used only when the XBLAS are available,
*> otherwise cdrvpo.f defines this subroutine.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] DOTYPE
*> \verbatim
*>          DOTYPE is LOGICAL array, dimension (NTYPES)
*>          The matrix types to be used for testing.  Matrices of type j
*>          (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) =
*>          .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used.
*> \endverbatim
*>
*> \param[in] NN
*> \verbatim
*>          NN is INTEGER
*>          The number of values of N contained in the vector NVAL.
*> \endverbatim
*>
*> \param[in] NVAL
*> \verbatim
*>          NVAL is INTEGER array, dimension (NN)
*>          The values of the matrix dimension N.
*> \endverbatim
*>
*> \param[in] NRHS
*> \verbatim
*>          NRHS is INTEGER
*>          The number of right hand side vectors to be generated for
*>          each linear system.
*> \endverbatim
*>
*> \param[in] THRESH
*> \verbatim
*>          THRESH is REAL
*>          The threshold value for the test ratios.  A result is
*>          included in the output file if RESULT >= THRESH.  To have
*>          every test ratio printed, use THRESH = 0.
*> \endverbatim
*>
*> \param[in] TSTERR
*> \verbatim
*>          TSTERR is LOGICAL
*>          Flag that indicates whether error exits are to be tested.
*> \endverbatim
*>
*> \param[in] NMAX
*> \verbatim
*>          NMAX is INTEGER
*>          The maximum value permitted for N, used in dimensioning the
*>          work arrays.
*> \endverbatim
*>
*> \param[out] A
*> \verbatim
*>          A is COMPLEX array, dimension (NMAX*NMAX)
*> \endverbatim
*>
*> \param[out] AFAC
*> \verbatim
*>          AFAC is COMPLEX array, dimension (NMAX*NMAX)
*> \endverbatim
*>
*> \param[out] ASAV
*> \verbatim
*>          ASAV is COMPLEX array, dimension (NMAX*NMAX)
*> \endverbatim
*>
*> \param[out] B
*> \verbatim
*>          B is COMPLEX array, dimension (NMAX*NRHS)
*> \endverbatim
*>
*> \param[out] BSAV
*> \verbatim
*>          BSAV is COMPLEX array, dimension (NMAX*NRHS)
*> \endverbatim
*>
*> \param[out] X
*> \verbatim
*>          X is COMPLEX array, dimension (NMAX*NRHS)
*> \endverbatim
*>
*> \param[out] XACT
*> \verbatim
*>          XACT is COMPLEX array, dimension (NMAX*NRHS)
*> \endverbatim
*>
*> \param[out] S
*> \verbatim
*>          S is REAL array, dimension (NMAX)
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX array, dimension
*>                      (NMAX*max(3,NRHS))
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is REAL array, dimension (NMAX+2*NRHS)
*> \endverbatim
*>
*> \param[in] NOUT
*> \verbatim
*>          NOUT is INTEGER
*>          The unit number for output.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2013
*
*> \ingroup complex_lin
*
*  =====================================================================
      SUBROUTINE cdrvpo( DOTYPE, NN, NVAL, NRHS, THRESH, TSTERR, NMAX,
     $                   a, afac, asav, b, bsav, x, xact, s, work,
     $                   rwork, nout )
*
*  -- LAPACK test routine (version 3.5.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2013
*
*     .. Scalar Arguments ..
      LOGICAL            tsterr
      INTEGER            nmax, nn, nout, nrhs
      REAL               thresh
*     ..
*     .. Array Arguments ..
      LOGICAL            dotype( * )
      INTEGER            nval( * )
      REAL               rwork( * ), s( * )
      COMPLEX            a( * ), afac( * ), asav( * ), b( * ),
     $                   bsav( * ), work( * ), x( * ), xact( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               one, zero
      parameter                ( one = 1.0e+0, zero = 0.0e+0 )
      INTEGER            ntypes
      parameter                ( ntypes = 9 )
      INTEGER            ntests
      parameter                ( ntests = 6 )
*     ..
*     .. Local Scalars ..
      LOGICAL            equil, nofact, prefac, zerot
      CHARACTER          dist, equed, fact, TYPE, uplo, xtype
      CHARACTER*3        path
      INTEGER            i, iequed, ifact, imat, in, info, ioff, iuplo,
     $                   izero, k, k1, kl, ku, lda, mode, n, nb, nbmin,
     $                   nerrs, nfact, nfail, nimat, nrun, nt,
     $                   n_err_bnds
      REAL               ainvnm, amax, anorm, cndnum, rcond, rcondc,
     $                   roldc, scond, rpvgrw_svxx
*     ..
*     .. Local Arrays ..
      CHARACTER          equeds( 2 ), facts( 3 ), uplos( 2 )
      INTEGER            iseed( 4 ), iseedy( 4 )
      REAL               result( ntests ), berr( nrhs ),
     $                   errbnds_n( nrhs, 3 ), errbnds_c( nrhs, 3 )
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      REAL               clanhe, sget06
      EXTERNAL           lsame, clanhe, sget06
*     ..
*     .. External Subroutines ..
      EXTERNAL           aladhd, alaerh, alasvm, cerrvx, cget04, clacpy,
     $                   claipd, claqhe, clarhs, claset, clatb4, clatms,
     $                   cpoequ, cposv, cposvx, cpot01, cpot02, cpot05,
     $                   cpotrf, cpotri, xlaenv, cposvxx
*     ..
*     .. Scalars in Common ..
      LOGICAL            lerr, ok
      CHARACTER*32       srnamt
      INTEGER            infot, nunit
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, nunit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, max
*     ..
*     .. Data statements ..
      DATA               iseedy / 1988, 1989, 1990, 1991 /
      DATA               uplos / 'U', 'L' /
      DATA               facts / 'F', 'N', 'E' /
      DATA               equeds / 'N', 'Y' /
*     ..
*     .. Executable Statements ..
*
*     Initialize constants and the random number seed.
*
      path( 1: 1 ) = 'Complex precision'
      path( 2: 3 ) = 'PO'
      nrun = 0
      nfail = 0
      nerrs = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 CONTINUE
*
*     Test the error exits
*
      IF( tsterr )
     $   CALL cerrvx( path, nout )
      infot = 0
*
*     Set the block size and minimum block size for testing.
*
      nb = 1
      nbmin = 2
      CALL xlaenv( 1, nb )
      CALL xlaenv( 2, nbmin )
*
*     Do for each value of N in NVAL
*
      DO 130 in = 1, nn
         n = nval( in )
         lda = max( n, 1 )
         xtype = 'N'
         nimat = ntypes
         IF( n.LE.0 )
     $      nimat = 1
*
         DO 120 imat = 1, nimat
*
*           Do the tests only if DOTYPE( IMAT ) is true.
*
            IF( .NOT.dotype( imat ) )
     $         GO TO 120
*
*           Skip types 3, 4, or 5 if the matrix size is too small.
*
            zerot = imat.GE.3 .AND. imat.LE.5
            IF( zerot .AND. n.LT.imat-2 )
     $         GO TO 120
*
*           Do first for UPLO = 'U', then for UPLO = 'L'
*
            DO 110 iuplo = 1, 2
               uplo = uplos( iuplo )
*
*              Set up parameters with CLATB4 and generate a test matrix
*              with CLATMS.
*
               CALL clatb4( path, imat, n, n, TYPE, kl, ku, anorm, mode,
     $                      cndnum, dist )
*
               srnamt = 'CLATMS'
               CALL clatms( n, n, dist, iseed, TYPE, rwork, mode,
     $                      cndnum, anorm, kl, ku, uplo, a, lda, work,
     $                      info )
*
*              Check error code from CLATMS.
*
               IF( info.NE.0 ) THEN
                  CALL alaerh( path, 'CLATMS', info, 0, uplo, n, n, -1,
     $                         -1, -1, imat, nfail, nerrs, nout )
                  GO TO 110
               END IF
*
*              For types 3-5, zero one row and column of the matrix to
*              test that INFO is returned correctly.
*
               IF( zerot ) THEN
                  IF( imat.EQ.3 ) THEN
                     izero = 1
                  ELSE IF( imat.EQ.4 ) THEN
                     izero = n
                  ELSE
                     izero = n / 2 + 1
                  END IF
                  ioff = ( izero-1 )*lda
*
*                 Set row and column IZERO of A to 0.
*
                  IF( iuplo.EQ.1 ) THEN
                     DO 20 i = 1, izero - 1
                        a( ioff+i ) = zero
   20                CONTINUE
                     ioff = ioff + izero
                     DO 30 i = izero, n
                        a( ioff ) = zero
                        ioff = ioff + lda
   30                CONTINUE
                  ELSE
                     ioff = izero
                     DO 40 i = 1, izero - 1
                        a( ioff ) = zero
                        ioff = ioff + lda
   40                CONTINUE
                     ioff = ioff - izero
                     DO 50 i = izero, n
                        a( ioff+i ) = zero
   50                CONTINUE
                  END IF
               ELSE
                  izero = 0
               END IF
*
*              Set the imaginary part of the diagonals.
*
               CALL claipd( n, a, lda+1, 0 )
*
*              Save a copy of the matrix A in ASAV.
*
               CALL clacpy( uplo, n, n, a, lda, asav, lda )
*
               DO 100 iequed = 1, 2
                  equed = equeds( iequed )
                  IF( iequed.EQ.1 ) THEN
                     nfact = 3
                  ELSE
                     nfact = 1
                  END IF
*
                  DO 90 ifact = 1, nfact
                     fact = facts( ifact )
                     prefac = lsame( fact, 'F' )
                     nofact = lsame( fact, 'N' )
                     equil = lsame( fact, 'E' )
*
                     IF( zerot ) THEN
                        IF( prefac )
     $                     GO TO 90
                        rcondc = zero
*
                     ELSE IF( .NOT.lsame( fact, 'N' ) ) THEN
*
*                       Compute the condition number for comparison with
*                       the value returned by CPOSVX (FACT = 'N' reuses
*                       the condition number from the previous iteration
*                       with FACT = 'F').
*
                        CALL clacpy( uplo, n, n, asav, lda, afac, lda )
                        IF( equil .OR. iequed.GT.1 ) THEN
*
*                          Compute row and column scale factors to
*                          equilibrate the matrix A.
*
                           CALL cpoequ( n, afac, lda, s, scond, amax,
     $                                  info )
                           IF( info.EQ.0 .AND. n.GT.0 ) THEN
                              IF( iequed.GT.1 )
     $                           scond = zero
*
*                             Equilibrate the matrix.
*
                              CALL claqhe( uplo, n, afac, lda, s, scond,
     $                                     amax, equed )
                           END IF
                        END IF
*
*                       Save the condition number of the
*                       non-equilibrated system for use in CGET04.
*
                        IF( equil )
     $                     roldc = rcondc
*
*                       Compute the 1-norm of A.
*
                        anorm = clanhe( '1', uplo, n, afac, lda, rwork )
*
*                       Factor the matrix A.
*
                        CALL cpotrf( uplo, n, afac, lda, info )
*
*                       Form the inverse of A.
*
                        CALL clacpy( uplo, n, n, afac, lda, a, lda )
                        CALL cpotri( uplo, n, a, lda, info )
*
*                       Compute the 1-norm condition number of A.
*
                        ainvnm = clanhe( '1', uplo, n, a, lda, rwork )
                        IF( anorm.LE.zero .OR. ainvnm.LE.zero ) THEN
                           rcondc = one
                        ELSE
                           rcondc = ( one / anorm ) / ainvnm
                        END IF
                     END IF
*
*                    Restore the matrix A.
*
                     CALL clacpy( uplo, n, n, asav, lda, a, lda )
*
*                    Form an exact solution and set the right hand side.
*
                     srnamt = 'CLARHS'
                     CALL clarhs( path, xtype, uplo, ' ', n, n, kl, ku,
     $                            nrhs, a, lda, xact, lda, b, lda,
     $                            iseed, info )
                     xtype = 'C'
                     CALL clacpy( 'Full', n, nrhs, b, lda, bsav, lda )
*
                     IF( nofact ) THEN
*
*                       --- Test CPOSV  ---
*
*                       Compute the L*L' or U'*U factorization of the
*                       matrix and solve the system.
*
                        CALL clacpy( uplo, n, n, a, lda, afac, lda )
                        CALL clacpy( 'Full', n, nrhs, b, lda, x, lda )
*
                        srnamt = 'CPOSV '
                        CALL cposv( uplo, n, nrhs, afac, lda, x, lda,
     $                              info )
*
*                       Check error code from CPOSV .
*
                        IF( info.NE.izero ) THEN
                           CALL alaerh( path, 'CPOSV ', info, izero,
     $                                  uplo, n, n, -1, -1, nrhs, imat,
     $                                  nfail, nerrs, nout )
                           GO TO 70
                        ELSE IF( info.NE.0 ) THEN
                           GO TO 70
                        END IF
*
*                       Reconstruct matrix from factors and compute
*                       residual.
*
                        CALL cpot01( uplo, n, a, lda, afac, lda, rwork,
     $                               result( 1 ) )
*
*                       Compute residual of the computed solution.
*
                        CALL clacpy( 'Full', n, nrhs, b, lda, work,
     $                               lda )
                        CALL cpot02( uplo, n, nrhs, a, lda, x, lda,
     $                               work, lda, rwork, result( 2 ) )
*
*                       Check solution from generated exact solution.
*
                        CALL cget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                               result( 3 ) )
                        nt = 3
*
*                       Print information about the tests that did not
*                       pass the threshold.
*
                        DO 60 k = 1, nt
                           IF( result( k ).GE.thresh ) THEN
                              IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                           CALL aladhd( nout, path )
                              WRITE( nout, fmt = 9999 )'CPOSV ', uplo,
     $                           n, imat, k, result( k )
                              nfail = nfail + 1
                           END IF
   60                   CONTINUE
                        nrun = nrun + nt
   70                   CONTINUE
                     END IF
*
*                    --- Test CPOSVX ---
*
                     IF( .NOT.prefac )
     $                  CALL claset( uplo, n, n, cmplx( zero ),
     $                               cmplx( zero ), afac, lda )
                     CALL claset( 'Full', n, nrhs, cmplx( zero ),
     $                            cmplx( zero ), x, lda )
                     IF( iequed.GT.1 .AND. n.GT.0 ) THEN
*
*                       Equilibrate the matrix if FACT='F' and
*                       EQUED='Y'.
*
                        CALL claqhe( uplo, n, a, lda, s, scond, amax,
     $                               equed )
                     END IF
*
*                    Solve the system and compute the condition number
*                    and error bounds using CPOSVX.
*
                     srnamt = 'CPOSVX'
                     CALL cposvx( fact, uplo, n, nrhs, a, lda, afac,
     $                            lda, equed, s, b, lda, x, lda, rcond,
     $                            rwork, rwork( nrhs+1 ), work,
     $                            rwork( 2*nrhs+1 ), info )
*
*                    Check the error code from CPOSVX.
*
                     IF( info.NE.izero ) THEN
                        CALL alaerh( path, 'CPOSVX', info, izero,
     $                               fact // uplo, n, n, -1, -1, nrhs,
     $                               imat, nfail, nerrs, nout )
                        GO TO 90
                     END IF
*
                     IF( info.EQ.0 ) THEN
                        IF( .NOT.prefac ) THEN
*
*                          Reconstruct matrix from factors and compute
*                          residual.
*
                           CALL cpot01( uplo, n, a, lda, afac, lda,
     $                                  rwork( 2*nrhs+1 ), result( 1 ) )
                           k1 = 1
                        ELSE
                           k1 = 2
                        END IF
*
*                       Compute residual of the computed solution.
*
                        CALL clacpy( 'Full', n, nrhs, bsav, lda, work,
     $                               lda )
                        CALL cpot02( uplo, n, nrhs, asav, lda, x, lda,
     $                               work, lda, rwork( 2*nrhs+1 ),
     $                               result( 2 ) )
*
*                       Check solution from generated exact solution.
*
                        IF( nofact .OR. ( prefac .AND. lsame( equed,
     $                      'N' ) ) ) THEN
                           CALL cget04( n, nrhs, x, lda, xact, lda,
     $                                  rcondc, result( 3 ) )
                        ELSE
                           CALL cget04( n, nrhs, x, lda, xact, lda,
     $                                  roldc, result( 3 ) )
                        END IF
*
*                       Check the error bounds from iterative
*                       refinement.
*
                        CALL cpot05( uplo, n, nrhs, asav, lda, b, lda,
     $                               x, lda, xact, lda, rwork,
     $                               rwork( nrhs+1 ), result( 4 ) )
                     ELSE
                        k1 = 6
                     END IF
*
*                    Compare RCOND from CPOSVX with the computed value
*                    in RCONDC.
*
                     result( 6 ) = sget06( rcond, rcondc )
*
*                    Print information about the tests that did not pass
*                    the threshold.
*
                     DO 80 k = k1, 6
                        IF( result( k ).GE.thresh ) THEN
                           IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                        CALL aladhd( nout, path )
                           IF( prefac ) THEN
                              WRITE( nout, fmt = 9997 )'CPOSVX', fact,
     $                           uplo, n, equed, imat, k, result( k )
                           ELSE
                              WRITE( nout, fmt = 9998 )'CPOSVX', fact,
     $                           uplo, n, imat, k, result( k )
                           END IF
                           nfail = nfail + 1
                        END IF
   80                CONTINUE
                     nrun = nrun + 7 - k1
*
*                    --- Test CPOSVXX ---
*
*                    Restore the matrices A and B.
*
                     CALL clacpy( 'Full', n, n, asav, lda, a, lda )
                     CALL clacpy( 'Full', n, nrhs, bsav, lda, b, lda )

                     IF( .NOT.prefac )
     $                  CALL claset( uplo, n, n, cmplx( zero ),
     $                               cmplx( zero ), afac, lda )
                     CALL claset( 'Full', n, nrhs, cmplx( zero ),
     $                            cmplx( zero ), x, lda )
                     IF( iequed.GT.1 .AND. n.GT.0 ) THEN
*
*                       Equilibrate the matrix if FACT='F' and
*                       EQUED='Y'.
*
                        CALL claqhe( uplo, n, a, lda, s, scond, amax,
     $                               equed )
                     END IF
*
*                    Solve the system and compute the condition number
*                    and error bounds using CPOSVXX.
*
                     srnamt = 'CPOSVXX'
                     n_err_bnds = 3
                    CALL cposvxx( fact, uplo, n, nrhs, a, lda, afac,
     $                    lda, equed, s, b, lda, x,
     $                    lda, rcond, rpvgrw_svxx, berr, n_err_bnds,
     $                    errbnds_n, errbnds_c, 0, zero, work,
     $                    rwork( 2*nrhs+1 ), info )
*
*                    Check the error code from CPOSVXX.
*
                     IF( info.EQ.n+1 ) GOTO 90
                     IF( info.NE.izero ) THEN
                        CALL alaerh( path, 'CPOSVXX', info, izero,
     $                               fact // uplo, n, n, -1, -1, nrhs,
     $                               imat, nfail, nerrs, nout )
                        GO TO 90
                     END IF
*
                     IF( info.EQ.0 ) THEN
                        IF( .NOT.prefac ) THEN
*
*                          Reconstruct matrix from factors and compute
*                          residual.
*
                           CALL cpot01( uplo, n, a, lda, afac, lda,
     $                                  rwork( 2*nrhs+1 ), result( 1 ) )
                           k1 = 1
                        ELSE
                           k1 = 2
                        END IF
*
*                       Compute residual of the computed solution.
*
                        CALL clacpy( 'Full', n, nrhs, bsav, lda, work,
     $                               lda )
                        CALL cpot02( uplo, n, nrhs, asav, lda, x, lda,
     $                               work, lda, rwork( 2*nrhs+1 ),
     $                               result( 2 ) )
*
*                       Check solution from generated exact solution.
*
                        IF( nofact .OR. ( prefac .AND. lsame( equed,
     $                      'N' ) ) ) THEN
                           CALL cget04( n, nrhs, x, lda, xact, lda,
     $                                  rcondc, result( 3 ) )
                        ELSE
                           CALL cget04( n, nrhs, x, lda, xact, lda,
     $                                  roldc, result( 3 ) )
                        END IF
*
*                       Check the error bounds from iterative
*                       refinement.
*
                        CALL cpot05( uplo, n, nrhs, asav, lda, b, lda,
     $                               x, lda, xact, lda, rwork,
     $                               rwork( nrhs+1 ), result( 4 ) )
                     ELSE
                        k1 = 6
                     END IF
*
*                    Compare RCOND from CPOSVXX with the computed value
*                    in RCONDC.
*
                     result( 6 ) = sget06( rcond, rcondc )
*
*                    Print information about the tests that did not pass
*                    the threshold.
*
                     DO 85 k = k1, 6
                        IF( result( k ).GE.thresh ) THEN
                           IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                        CALL aladhd( nout, path )
                           IF( prefac ) THEN
                              WRITE( nout, fmt = 9997 )'CPOSVXX', fact,
     $                           uplo, n, equed, imat, k, result( k )
                           ELSE
                              WRITE( nout, fmt = 9998 )'CPOSVXX', fact,
     $                           uplo, n, imat, k, result( k )
                           END IF
                           nfail = nfail + 1
                        END IF
  85                 CONTINUE
                     nrun = nrun + 7 - k1
  90              CONTINUE
  100          CONTINUE
  110       CONTINUE
  120    CONTINUE
  130 CONTINUE
*
*     Print a summary of the results.
*
      CALL alasvm( path, nout, nfail, nrun, nerrs )
*

*     Test Error Bounds for CGESVXX

      CALL cebchvxx(thresh, path)

 9999 FORMAT( 1x, a, ', UPLO=''', a1, ''', N =', i5, ', type ', i1,
     $      ', test(', i1, ')=', g12.5 )
 9998 FORMAT( 1x, a, ', FACT=''', a1, ''', UPLO=''', a1, ''', N=', i5,
     $      ', type ', i1, ', test(', i1, ')=', g12.5 )
 9997 FORMAT( 1x, a, ', FACT=''', a1, ''', UPLO=''', a1, ''', N=', i5,
     $      ', EQUED=''', a1, ''', type ', i1, ', test(', i1, ') =',
     $      g12.5 )
      RETURN
*
*     End of CDRVPO
*
      END