LAPACK  3.4.2
LAPACK: Linear Algebra PACKage
 All Files Functions Groups
zggsvp.f
Go to the documentation of this file.
1 *> \brief \b ZGGSVP
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download ZGGSVP + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zggsvp.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zggsvp.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zggsvp.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE ZGGSVP( JOBU, JOBV, JOBQ, M, P, N, A, LDA, B, LDB,
22 * TOLA, TOLB, K, L, U, LDU, V, LDV, Q, LDQ,
23 * IWORK, RWORK, TAU, WORK, INFO )
24 *
25 * .. Scalar Arguments ..
26 * CHARACTER JOBQ, JOBU, JOBV
27 * INTEGER INFO, K, L, LDA, LDB, LDQ, LDU, LDV, M, N, P
28 * DOUBLE PRECISION TOLA, TOLB
29 * ..
30 * .. Array Arguments ..
31 * INTEGER IWORK( * )
32 * DOUBLE PRECISION RWORK( * )
33 * COMPLEX*16 A( LDA, * ), B( LDB, * ), Q( LDQ, * ),
34 * $ TAU( * ), U( LDU, * ), V( LDV, * ), WORK( * )
35 * ..
36 *
37 *
38 *> \par Purpose:
39 * =============
40 *>
41 *> \verbatim
42 *>
43 *> ZGGSVP computes unitary matrices U, V and Q such that
44 *>
45 *> N-K-L K L
46 *> U**H*A*Q = K ( 0 A12 A13 ) if M-K-L >= 0;
47 *> L ( 0 0 A23 )
48 *> M-K-L ( 0 0 0 )
49 *>
50 *> N-K-L K L
51 *> = K ( 0 A12 A13 ) if M-K-L < 0;
52 *> M-K ( 0 0 A23 )
53 *>
54 *> N-K-L K L
55 *> V**H*B*Q = L ( 0 0 B13 )
56 *> P-L ( 0 0 0 )
57 *>
58 *> where the K-by-K matrix A12 and L-by-L matrix B13 are nonsingular
59 *> upper triangular; A23 is L-by-L upper triangular if M-K-L >= 0,
60 *> otherwise A23 is (M-K)-by-L upper trapezoidal. K+L = the effective
61 *> numerical rank of the (M+P)-by-N matrix (A**H,B**H)**H.
62 *>
63 *> This decomposition is the preprocessing step for computing the
64 *> Generalized Singular Value Decomposition (GSVD), see subroutine
65 *> ZGGSVD.
66 *> \endverbatim
67 *
68 * Arguments:
69 * ==========
70 *
71 *> \param[in] JOBU
72 *> \verbatim
73 *> JOBU is CHARACTER*1
74 *> = 'U': Unitary matrix U is computed;
75 *> = 'N': U is not computed.
76 *> \endverbatim
77 *>
78 *> \param[in] JOBV
79 *> \verbatim
80 *> JOBV is CHARACTER*1
81 *> = 'V': Unitary matrix V is computed;
82 *> = 'N': V is not computed.
83 *> \endverbatim
84 *>
85 *> \param[in] JOBQ
86 *> \verbatim
87 *> JOBQ is CHARACTER*1
88 *> = 'Q': Unitary matrix Q is computed;
89 *> = 'N': Q is not computed.
90 *> \endverbatim
91 *>
92 *> \param[in] M
93 *> \verbatim
94 *> M is INTEGER
95 *> The number of rows of the matrix A. M >= 0.
96 *> \endverbatim
97 *>
98 *> \param[in] P
99 *> \verbatim
100 *> P is INTEGER
101 *> The number of rows of the matrix B. P >= 0.
102 *> \endverbatim
103 *>
104 *> \param[in] N
105 *> \verbatim
106 *> N is INTEGER
107 *> The number of columns of the matrices A and B. N >= 0.
108 *> \endverbatim
109 *>
110 *> \param[in,out] A
111 *> \verbatim
112 *> A is COMPLEX*16 array, dimension (LDA,N)
113 *> On entry, the M-by-N matrix A.
114 *> On exit, A contains the triangular (or trapezoidal) matrix
115 *> described in the Purpose section.
116 *> \endverbatim
117 *>
118 *> \param[in] LDA
119 *> \verbatim
120 *> LDA is INTEGER
121 *> The leading dimension of the array A. LDA >= max(1,M).
122 *> \endverbatim
123 *>
124 *> \param[in,out] B
125 *> \verbatim
126 *> B is COMPLEX*16 array, dimension (LDB,N)
127 *> On entry, the P-by-N matrix B.
128 *> On exit, B contains the triangular matrix described in
129 *> the Purpose section.
130 *> \endverbatim
131 *>
132 *> \param[in] LDB
133 *> \verbatim
134 *> LDB is INTEGER
135 *> The leading dimension of the array B. LDB >= max(1,P).
136 *> \endverbatim
137 *>
138 *> \param[in] TOLA
139 *> \verbatim
140 *> TOLA is DOUBLE PRECISION
141 *> \endverbatim
142 *>
143 *> \param[in] TOLB
144 *> \verbatim
145 *> TOLB is DOUBLE PRECISION
146 *>
147 *> TOLA and TOLB are the thresholds to determine the effective
148 *> numerical rank of matrix B and a subblock of A. Generally,
149 *> they are set to
150 *> TOLA = MAX(M,N)*norm(A)*MAZHEPS,
151 *> TOLB = MAX(P,N)*norm(B)*MAZHEPS.
152 *> The size of TOLA and TOLB may affect the size of backward
153 *> errors of the decomposition.
154 *> \endverbatim
155 *>
156 *> \param[out] K
157 *> \verbatim
158 *> K is INTEGER
159 *> \endverbatim
160 *>
161 *> \param[out] L
162 *> \verbatim
163 *> L is INTEGER
164 *>
165 *> On exit, K and L specify the dimension of the subblocks
166 *> described in Purpose section.
167 *> K + L = effective numerical rank of (A**H,B**H)**H.
168 *> \endverbatim
169 *>
170 *> \param[out] U
171 *> \verbatim
172 *> U is COMPLEX*16 array, dimension (LDU,M)
173 *> If JOBU = 'U', U contains the unitary matrix U.
174 *> If JOBU = 'N', U is not referenced.
175 *> \endverbatim
176 *>
177 *> \param[in] LDU
178 *> \verbatim
179 *> LDU is INTEGER
180 *> The leading dimension of the array U. LDU >= max(1,M) if
181 *> JOBU = 'U'; LDU >= 1 otherwise.
182 *> \endverbatim
183 *>
184 *> \param[out] V
185 *> \verbatim
186 *> V is COMPLEX*16 array, dimension (LDV,P)
187 *> If JOBV = 'V', V contains the unitary matrix V.
188 *> If JOBV = 'N', V is not referenced.
189 *> \endverbatim
190 *>
191 *> \param[in] LDV
192 *> \verbatim
193 *> LDV is INTEGER
194 *> The leading dimension of the array V. LDV >= max(1,P) if
195 *> JOBV = 'V'; LDV >= 1 otherwise.
196 *> \endverbatim
197 *>
198 *> \param[out] Q
199 *> \verbatim
200 *> Q is COMPLEX*16 array, dimension (LDQ,N)
201 *> If JOBQ = 'Q', Q contains the unitary matrix Q.
202 *> If JOBQ = 'N', Q is not referenced.
203 *> \endverbatim
204 *>
205 *> \param[in] LDQ
206 *> \verbatim
207 *> LDQ is INTEGER
208 *> The leading dimension of the array Q. LDQ >= max(1,N) if
209 *> JOBQ = 'Q'; LDQ >= 1 otherwise.
210 *> \endverbatim
211 *>
212 *> \param[out] IWORK
213 *> \verbatim
214 *> IWORK is INTEGER array, dimension (N)
215 *> \endverbatim
216 *>
217 *> \param[out] RWORK
218 *> \verbatim
219 *> RWORK is DOUBLE PRECISION array, dimension (2*N)
220 *> \endverbatim
221 *>
222 *> \param[out] TAU
223 *> \verbatim
224 *> TAU is COMPLEX*16 array, dimension (N)
225 *> \endverbatim
226 *>
227 *> \param[out] WORK
228 *> \verbatim
229 *> WORK is COMPLEX*16 array, dimension (max(3*N,M,P))
230 *> \endverbatim
231 *>
232 *> \param[out] INFO
233 *> \verbatim
234 *> INFO is INTEGER
235 *> = 0: successful exit
236 *> < 0: if INFO = -i, the i-th argument had an illegal value.
237 *> \endverbatim
238 *
239 * Authors:
240 * ========
241 *
242 *> \author Univ. of Tennessee
243 *> \author Univ. of California Berkeley
244 *> \author Univ. of Colorado Denver
245 *> \author NAG Ltd.
246 *
247 *> \date November 2011
248 *
249 *> \ingroup complex16OTHERcomputational
250 *
251 *> \par Further Details:
252 * =====================
253 *>
254 *> \verbatim
255 *>
256 *> The subroutine uses LAPACK subroutine ZGEQPF for the QR factorization
257 *> with column pivoting to detect the effective numerical rank of the
258 *> a matrix. It may be replaced by a better rank determination strategy.
259 *> \endverbatim
260 *>
261 * =====================================================================
262  SUBROUTINE zggsvp( JOBU, JOBV, JOBQ, M, P, N, A, LDA, B, LDB,
263  $ tola, tolb, k, l, u, ldu, v, ldv, q, ldq,
264  $ iwork, rwork, tau, work, info )
265 *
266 * -- LAPACK computational routine (version 3.4.0) --
267 * -- LAPACK is a software package provided by Univ. of Tennessee, --
268 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
269 * November 2011
270 *
271 * .. Scalar Arguments ..
272  CHARACTER jobq, jobu, jobv
273  INTEGER info, k, l, lda, ldb, ldq, ldu, ldv, m, n, p
274  DOUBLE PRECISION tola, tolb
275 * ..
276 * .. Array Arguments ..
277  INTEGER iwork( * )
278  DOUBLE PRECISION rwork( * )
279  COMPLEX*16 a( lda, * ), b( ldb, * ), q( ldq, * ),
280  $ tau( * ), u( ldu, * ), v( ldv, * ), work( * )
281 * ..
282 *
283 * =====================================================================
284 *
285 * .. Parameters ..
286  COMPLEX*16 czero, cone
287  parameter( czero = ( 0.0d+0, 0.0d+0 ),
288  $ cone = ( 1.0d+0, 0.0d+0 ) )
289 * ..
290 * .. Local Scalars ..
291  LOGICAL forwrd, wantq, wantu, wantv
292  INTEGER i, j
293  COMPLEX*16 t
294 * ..
295 * .. External Functions ..
296  LOGICAL lsame
297  EXTERNAL lsame
298 * ..
299 * .. External Subroutines ..
300  EXTERNAL xerbla, zgeqpf, zgeqr2, zgerq2, zlacpy, zlapmt,
301  $ zlaset, zung2r, zunm2r, zunmr2
302 * ..
303 * .. Intrinsic Functions ..
304  INTRINSIC abs, dble, dimag, max, min
305 * ..
306 * .. Statement Functions ..
307  DOUBLE PRECISION cabs1
308 * ..
309 * .. Statement Function definitions ..
310  cabs1( t ) = abs( dble( t ) ) + abs( dimag( t ) )
311 * ..
312 * .. Executable Statements ..
313 *
314 * Test the input parameters
315 *
316  wantu = lsame( jobu, 'U' )
317  wantv = lsame( jobv, 'V' )
318  wantq = lsame( jobq, 'Q' )
319  forwrd = .true.
320 *
321  info = 0
322  IF( .NOT.( wantu .OR. lsame( jobu, 'N' ) ) ) THEN
323  info = -1
324  ELSE IF( .NOT.( wantv .OR. lsame( jobv, 'N' ) ) ) THEN
325  info = -2
326  ELSE IF( .NOT.( wantq .OR. lsame( jobq, 'N' ) ) ) THEN
327  info = -3
328  ELSE IF( m.LT.0 ) THEN
329  info = -4
330  ELSE IF( p.LT.0 ) THEN
331  info = -5
332  ELSE IF( n.LT.0 ) THEN
333  info = -6
334  ELSE IF( lda.LT.max( 1, m ) ) THEN
335  info = -8
336  ELSE IF( ldb.LT.max( 1, p ) ) THEN
337  info = -10
338  ELSE IF( ldu.LT.1 .OR. ( wantu .AND. ldu.LT.m ) ) THEN
339  info = -16
340  ELSE IF( ldv.LT.1 .OR. ( wantv .AND. ldv.LT.p ) ) THEN
341  info = -18
342  ELSE IF( ldq.LT.1 .OR. ( wantq .AND. ldq.LT.n ) ) THEN
343  info = -20
344  END IF
345  IF( info.NE.0 ) THEN
346  CALL xerbla( 'ZGGSVP', -info )
347  return
348  END IF
349 *
350 * QR with column pivoting of B: B*P = V*( S11 S12 )
351 * ( 0 0 )
352 *
353  DO 10 i = 1, n
354  iwork( i ) = 0
355  10 continue
356  CALL zgeqpf( p, n, b, ldb, iwork, tau, work, rwork, info )
357 *
358 * Update A := A*P
359 *
360  CALL zlapmt( forwrd, m, n, a, lda, iwork )
361 *
362 * Determine the effective rank of matrix B.
363 *
364  l = 0
365  DO 20 i = 1, min( p, n )
366  IF( cabs1( b( i, i ) ).GT.tolb )
367  $ l = l + 1
368  20 continue
369 *
370  IF( wantv ) THEN
371 *
372 * Copy the details of V, and form V.
373 *
374  CALL zlaset( 'Full', p, p, czero, czero, v, ldv )
375  IF( p.GT.1 )
376  $ CALL zlacpy( 'Lower', p-1, n, b( 2, 1 ), ldb, v( 2, 1 ),
377  $ ldv )
378  CALL zung2r( p, p, min( p, n ), v, ldv, tau, work, info )
379  END IF
380 *
381 * Clean up B
382 *
383  DO 40 j = 1, l - 1
384  DO 30 i = j + 1, l
385  b( i, j ) = czero
386  30 continue
387  40 continue
388  IF( p.GT.l )
389  $ CALL zlaset( 'Full', p-l, n, czero, czero, b( l+1, 1 ), ldb )
390 *
391  IF( wantq ) THEN
392 *
393 * Set Q = I and Update Q := Q*P
394 *
395  CALL zlaset( 'Full', n, n, czero, cone, q, ldq )
396  CALL zlapmt( forwrd, n, n, q, ldq, iwork )
397  END IF
398 *
399  IF( p.GE.l .AND. n.NE.l ) THEN
400 *
401 * RQ factorization of ( S11 S12 ) = ( 0 S12 )*Z
402 *
403  CALL zgerq2( l, n, b, ldb, tau, work, info )
404 *
405 * Update A := A*Z**H
406 *
407  CALL zunmr2( 'Right', 'Conjugate transpose', m, n, l, b, ldb,
408  $ tau, a, lda, work, info )
409  IF( wantq ) THEN
410 *
411 * Update Q := Q*Z**H
412 *
413  CALL zunmr2( 'Right', 'Conjugate transpose', n, n, l, b,
414  $ ldb, tau, q, ldq, work, info )
415  END IF
416 *
417 * Clean up B
418 *
419  CALL zlaset( 'Full', l, n-l, czero, czero, b, ldb )
420  DO 60 j = n - l + 1, n
421  DO 50 i = j - n + l + 1, l
422  b( i, j ) = czero
423  50 continue
424  60 continue
425 *
426  END IF
427 *
428 * Let N-L L
429 * A = ( A11 A12 ) M,
430 *
431 * then the following does the complete QR decomposition of A11:
432 *
433 * A11 = U*( 0 T12 )*P1**H
434 * ( 0 0 )
435 *
436  DO 70 i = 1, n - l
437  iwork( i ) = 0
438  70 continue
439  CALL zgeqpf( m, n-l, a, lda, iwork, tau, work, rwork, info )
440 *
441 * Determine the effective rank of A11
442 *
443  k = 0
444  DO 80 i = 1, min( m, n-l )
445  IF( cabs1( a( i, i ) ).GT.tola )
446  $ k = k + 1
447  80 continue
448 *
449 * Update A12 := U**H*A12, where A12 = A( 1:M, N-L+1:N )
450 *
451  CALL zunm2r( 'Left', 'Conjugate transpose', m, l, min( m, n-l ),
452  $ a, lda, tau, a( 1, n-l+1 ), lda, work, info )
453 *
454  IF( wantu ) THEN
455 *
456 * Copy the details of U, and form U
457 *
458  CALL zlaset( 'Full', m, m, czero, czero, u, ldu )
459  IF( m.GT.1 )
460  $ CALL zlacpy( 'Lower', m-1, n-l, a( 2, 1 ), lda, u( 2, 1 ),
461  $ ldu )
462  CALL zung2r( m, m, min( m, n-l ), u, ldu, tau, work, info )
463  END IF
464 *
465  IF( wantq ) THEN
466 *
467 * Update Q( 1:N, 1:N-L ) = Q( 1:N, 1:N-L )*P1
468 *
469  CALL zlapmt( forwrd, n, n-l, q, ldq, iwork )
470  END IF
471 *
472 * Clean up A: set the strictly lower triangular part of
473 * A(1:K, 1:K) = 0, and A( K+1:M, 1:N-L ) = 0.
474 *
475  DO 100 j = 1, k - 1
476  DO 90 i = j + 1, k
477  a( i, j ) = czero
478  90 continue
479  100 continue
480  IF( m.GT.k )
481  $ CALL zlaset( 'Full', m-k, n-l, czero, czero, a( k+1, 1 ), lda )
482 *
483  IF( n-l.GT.k ) THEN
484 *
485 * RQ factorization of ( T11 T12 ) = ( 0 T12 )*Z1
486 *
487  CALL zgerq2( k, n-l, a, lda, tau, work, info )
488 *
489  IF( wantq ) THEN
490 *
491 * Update Q( 1:N,1:N-L ) = Q( 1:N,1:N-L )*Z1**H
492 *
493  CALL zunmr2( 'Right', 'Conjugate transpose', n, n-l, k, a,
494  $ lda, tau, q, ldq, work, info )
495  END IF
496 *
497 * Clean up A
498 *
499  CALL zlaset( 'Full', k, n-l-k, czero, czero, a, lda )
500  DO 120 j = n - l - k + 1, n - l
501  DO 110 i = j - n + l + k + 1, k
502  a( i, j ) = czero
503  110 continue
504  120 continue
505 *
506  END IF
507 *
508  IF( m.GT.k ) THEN
509 *
510 * QR factorization of A( K+1:M,N-L+1:N )
511 *
512  CALL zgeqr2( m-k, l, a( k+1, n-l+1 ), lda, tau, work, info )
513 *
514  IF( wantu ) THEN
515 *
516 * Update U(:,K+1:M) := U(:,K+1:M)*U1
517 *
518  CALL zunm2r( 'Right', 'No transpose', m, m-k, min( m-k, l ),
519  $ a( k+1, n-l+1 ), lda, tau, u( 1, k+1 ), ldu,
520  $ work, info )
521  END IF
522 *
523 * Clean up
524 *
525  DO 140 j = n - l + 1, n
526  DO 130 i = j - n + k + l + 1, m
527  a( i, j ) = czero
528  130 continue
529  140 continue
530 *
531  END IF
532 *
533  return
534 *
535 * End of ZGGSVP
536 *
537  END