cqrt04.f

Go to the documentation of this file.

*> \brief \b CQRT04
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       SUBROUTINE CQRT04(M,N,NB,RESULT)
* 
*       .. Scalar Arguments ..
*       INTEGER M, N, NB, LDT
*       .. Return values ..
*       REAL RESULT(6)
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CQRT04 tests CGEQRT and CGEMQRT.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          Number of rows in test matrix.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          Number of columns in test matrix.
*> \endverbatim
*>
*> \param[in] NB
*> \verbatim
*>          NB is INTEGER
*>          Block size of test matrix.  NB <= Min(M,N).
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*>          RESULT is REAL array, dimension (6)
*>          Results of each of the six tests below.
*>
*>          RESULT(1) = | A - Q R |
*>          RESULT(2) = | I - Q^H Q |
*>          RESULT(3) = | Q C - Q C |
*>          RESULT(4) = | Q^H C - Q^H C |
*>          RESULT(5) = | C Q - C Q | 
*>          RESULT(6) = | C Q^H - C Q^H |
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date April 2012
*
*> \ingroup complex_lin
*
*  =====================================================================
      SUBROUTINE cqrt04(M,N,NB,RESULT)
      IMPLICIT NONE
*
*  -- LAPACK test routine (version 3.4.1) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     April 2012
*
*     .. Scalar Arguments ..
      INTEGER m, n, nb, ldt
*     .. Return values ..
      REAL result(6)
*
*  =====================================================================
*
*     ..
*     .. Local allocatable arrays 
      COMPLEX, ALLOCATABLE :: af(:,:), q(:,:),
     $  r(:,:), rwork(:), work( : ), t(:,:), 
     $  cf(:,:), df(:,:), a(:,:), c(:,:), d(:,:)
*
*     .. Parameters ..
      REAL zero
      COMPLEX one, czero
      parameter( zero = 0.0, one = (1.0,0.0), czero=(0.0,0.0) )
*     ..
*     .. Local Scalars ..
      INTEGER info, j, k, l, lwork
      REAL   anorm, eps, resid, cnorm, dnorm
*     ..
*     .. Local Arrays ..
      INTEGER            iseed( 4 )
*     ..
*     .. External Functions ..
      REAL slamch 
      REAL clange, clansy
      LOGICAL  lsame
      EXTERNAL slamch, clange, clansy, lsame
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC  max, min      
*     ..
*     .. Data statements ..
      DATA iseed / 1988, 1989, 1990, 1991 /      
*      
      eps = slamch( 'Epsilon' )
      k = min(m,n)
      l = max(m,n)
      lwork = max(2,l)*max(2,l)*nb
*
*     Dynamically allocate local arrays
*
      ALLOCATE ( a(m,n), af(m,n), q(m,m), r(m,l), rwork(l), 
     $           work(lwork), t(nb,n), c(m,n), cf(m,n), 
     $           d(n,m), df(n,m) )
*
*     Put random numbers into A and copy to AF
*
      ldt=nb
      DO j=1,n
         CALL clarnv( 2, iseed, m, a( 1, j ) )
      END DO
      CALL clacpy( 'Full', m, n, a, m, af, m )
*
*     Factor the matrix A in the array AF.
*
      CALL cgeqrt( m, n, nb, af, m, t, ldt, work, info )
*
*     Generate the m-by-m matrix Q
*
      CALL claset( 'Full', m, m, czero, one, q, m )
      CALL cgemqrt( 'R', 'N', m, m, k, nb, af, m, t, ldt, q, m, 
     $              work, info )
*
*     Copy R
*
      CALL claset( 'Full', m, n, czero, czero, r, m )
      CALL clacpy( 'Upper', m, n, af, m, r, m )
*
*     Compute |R - Q'*A| / |A| and store in RESULT(1)
*
      CALL cgemm( 'C', 'N', m, n, m, -one, q, m, a, m, one, r, m )
      anorm = clange( '1', m, n, a, m, rwork )
      resid = clange( '1', m, n, r, m, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = resid / (eps*max(1,m)*anorm)
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute |I - Q'*Q| and store in RESULT(2)
*
      CALL claset( 'Full', m, m, czero, one, r, m )
      CALL cherk( 'U', 'C', m, m, REAL(-ONE), q, m, REAL(ONE), r, m )
      resid = clansy( '1', 'Upper', m, r, m, rwork )
      result( 2 ) = resid / (eps*max(1,m))
*
*     Generate random m-by-n matrix C and a copy CF
*
      DO j=1,n
         CALL clarnv( 2, iseed, m, c( 1, j ) )
      END DO
      cnorm = clange( '1', m, n, c, m, rwork)
      CALL clacpy( 'Full', m, n, c, m, cf, m )
*
*     Apply Q to C as Q*C
*
      CALL cgemqrt( 'L', 'N', m, n, k, nb, af, m, t, nb, cf, m, 
     $             work, info)
*
*     Compute |Q*C - Q*C| / |C|
*
      CALL cgemm( 'N', 'N', m, n, m, -one, q, m, c, m, one, cf, m )
      resid = clange( '1', m, n, cf, m, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 3 ) = resid / (eps*max(1,m)*cnorm)
      ELSE
         result( 3 ) = zero
      END IF
*
*     Copy C into CF again
*
      CALL clacpy( 'Full', m, n, c, m, cf, m )
*
*     Apply Q to C as QT*C
*
      CALL cgemqrt( 'L', 'C', m, n, k, nb, af, m, t, nb, cf, m, 
     $             work, info)
*
*     Compute |QT*C - QT*C| / |C|
*
      CALL cgemm( 'C', 'N', m, n, m, -one, q, m, c, m, one, cf, m )
      resid = clange( '1', m, n, cf, m, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 4 ) = resid / (eps*max(1,m)*cnorm)
      ELSE
         result( 4 ) = zero
      END IF     
*
*     Generate random n-by-m matrix D and a copy DF
*
      DO j=1,m
         CALL clarnv( 2, iseed, n, d( 1, j ) )
      END DO
      dnorm = clange( '1', n, m, d, n, rwork)
      CALL clacpy( 'Full', n, m, d, n, df, n )
*
*     Apply Q to D as D*Q
*
      CALL cgemqrt( 'R', 'N', n, m, k, nb, af, m, t, nb, df, n, 
     $             work, info)      
*
*     Compute |D*Q - D*Q| / |D|
*
      CALL cgemm( 'N', 'N', n, m, m, -one, d, n, q, m, one, df, n )
      resid = clange( '1', n, m, df, n, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 5 ) = resid / (eps*max(1,m)*dnorm)
      ELSE
         result( 5 ) = zero
      END IF
*
*     Copy D into DF again
*
      CALL clacpy( 'Full', n, m, d, n, df, n )
*
*     Apply Q to D as D*QT
*
      CALL cgemqrt( 'R', 'C', n, m, k, nb, af, m, t, nb, df, n, 
     $             work, info)      
*
*     Compute |D*QT - D*QT| / |D|
*
      CALL cgemm( 'N', 'C', n, m, m, -one, d, n, q, m, one, df, n )
      resid = clange( '1', n, m, df, n, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 6 ) = resid / (eps*max(1,m)*dnorm)
      ELSE
         result( 6 ) = zero
      END IF
*
*     Deallocate all arrays
*
      DEALLOCATE ( a, af, q, r, rwork, work, t, c, d, cf, df)
*
      return
      END