LAPACK  3.4.2 LAPACK: Linear Algebra PACKage
cpoequb.f
Go to the documentation of this file.
1 *> \brief \b CPOEQUB
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cpoequb.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cpoequb.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cpoequb.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE CPOEQUB( N, A, LDA, S, SCOND, AMAX, INFO )
22 *
23 * .. Scalar Arguments ..
24 * INTEGER INFO, LDA, N
25 * REAL AMAX, SCOND
26 * ..
27 * .. Array Arguments ..
28 * COMPLEX A( LDA, * )
29 * REAL S( * )
30 * ..
31 *
32 *
33 *> \par Purpose:
34 * =============
35 *>
36 *> \verbatim
37 *>
38 *> CPOEQUB computes row and column scalings intended to equilibrate a
39 *> symmetric positive definite matrix A and reduce its condition number
40 *> (with respect to the two-norm). S contains the scale factors,
41 *> S(i) = 1/sqrt(A(i,i)), chosen so that the scaled matrix B with
42 *> elements B(i,j) = S(i)*A(i,j)*S(j) has ones on the diagonal. This
43 *> choice of S puts the condition number of B within a factor N of the
44 *> smallest possible condition number over all possible diagonal
45 *> scalings.
46 *> \endverbatim
47 *
48 * Arguments:
49 * ==========
50 *
51 *> \param[in] N
52 *> \verbatim
53 *> N is INTEGER
54 *> The order of the matrix A. N >= 0.
55 *> \endverbatim
56 *>
57 *> \param[in] A
58 *> \verbatim
59 *> A is COMPLEX array, dimension (LDA,N)
60 *> The N-by-N symmetric positive definite matrix whose scaling
61 *> factors are to be computed. Only the diagonal elements of A
62 *> are referenced.
63 *> \endverbatim
64 *>
65 *> \param[in] LDA
66 *> \verbatim
67 *> LDA is INTEGER
68 *> The leading dimension of the array A. LDA >= max(1,N).
69 *> \endverbatim
70 *>
71 *> \param[out] S
72 *> \verbatim
73 *> S is REAL array, dimension (N)
74 *> If INFO = 0, S contains the scale factors for A.
75 *> \endverbatim
76 *>
77 *> \param[out] SCOND
78 *> \verbatim
79 *> SCOND is REAL
80 *> If INFO = 0, S contains the ratio of the smallest S(i) to
81 *> the largest S(i). If SCOND >= 0.1 and AMAX is neither too
82 *> large nor too small, it is not worth scaling by S.
83 *> \endverbatim
84 *>
85 *> \param[out] AMAX
86 *> \verbatim
87 *> AMAX is REAL
88 *> Absolute value of largest matrix element. If AMAX is very
89 *> close to overflow or very close to underflow, the matrix
90 *> should be scaled.
91 *> \endverbatim
92 *>
93 *> \param[out] INFO
94 *> \verbatim
95 *> INFO is INTEGER
96 *> = 0: successful exit
97 *> < 0: if INFO = -i, the i-th argument had an illegal value
98 *> > 0: if INFO = i, the i-th diagonal element is nonpositive.
99 *> \endverbatim
100 *
101 * Authors:
102 * ========
103 *
104 *> \author Univ. of Tennessee
105 *> \author Univ. of California Berkeley
106 *> \author Univ. of Colorado Denver
107 *> \author NAG Ltd.
108 *
109 *> \date November 2011
110 *
111 *> \ingroup complexPOcomputational
112 *
113 * =====================================================================
114  SUBROUTINE cpoequb( N, A, LDA, S, SCOND, AMAX, INFO )
115 *
116 * -- LAPACK computational routine (version 3.4.0) --
117 * -- LAPACK is a software package provided by Univ. of Tennessee, --
118 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
119 * November 2011
120 *
121 * .. Scalar Arguments ..
122  INTEGER info, lda, n
123  REAL amax, scond
124 * ..
125 * .. Array Arguments ..
126  COMPLEX a( lda, * )
127  REAL s( * )
128 * ..
129 *
130 * =====================================================================
131 *
132 * .. Parameters ..
133  REAL zero, one
134  parameter( zero = 0.0e+0, one = 1.0e+0 )
135 * ..
136 * .. Local Scalars ..
137  INTEGER i
138  REAL smin, base, tmp
139 * ..
140 * .. External Functions ..
141  REAL slamch
142  EXTERNAL slamch
143 * ..
144 * .. External Subroutines ..
145  EXTERNAL xerbla
146 * ..
147 * .. Intrinsic Functions ..
148  INTRINSIC max, min, sqrt, log, int
149 * ..
150 * .. Executable Statements ..
151 *
152 * Test the input parameters.
153 *
154 * Positive definite only performs 1 pass of equilibration.
155 *
156  info = 0
157  IF( n.LT.0 ) THEN
158  info = -1
159  ELSE IF( lda.LT.max( 1, n ) ) THEN
160  info = -3
161  END IF
162  IF( info.NE.0 ) THEN
163  CALL xerbla( 'CPOEQUB', -info )
164  return
165  END IF
166 *
167 * Quick return if possible.
168 *
169  IF( n.EQ.0 ) THEN
170  scond = one
171  amax = zero
172  return
173  END IF
174
175  base = slamch( 'B' )
176  tmp = -0.5 / log( base )
177 *
178 * Find the minimum and maximum diagonal elements.
179 *
180  s( 1 ) = a( 1, 1 )
181  smin = s( 1 )
182  amax = s( 1 )
183  DO 10 i = 2, n
184  s( i ) = a( i, i )
185  smin = min( smin, s( i ) )
186  amax = max( amax, s( i ) )
187  10 continue
188 *
189  IF( smin.LE.zero ) THEN
190 *
191 * Find the first non-positive diagonal element and return.
192 *
193  DO 20 i = 1, n
194  IF( s( i ).LE.zero ) THEN
195  info = i
196  return
197  END IF
198  20 continue
199  ELSE
200 *
201 * Set the scale factors to the reciprocals
202 * of the diagonal elements.
203 *
204  DO 30 i = 1, n
205  s( i ) = base ** int( tmp * log( s( i ) ) )
206  30 continue
207 *
208 * Compute SCOND = min(S(I)) / max(S(I)).
209 *
210  scond = sqrt( smin ) / sqrt( amax )
211  END IF
212 *
213  return
214 *
215 * End of CPOEQUB
216 *
217  END