LAPACK 3.3.1 Linear Algebra PACKage

zrqt01.f

Go to the documentation of this file.
```00001       SUBROUTINE ZRQT01( M, N, A, AF, Q, R, LDA, TAU, WORK, LWORK,
00002      \$                   RWORK, RESULT )
00003 *
00004 *  -- LAPACK test routine (version 3.1) --
00005 *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
00006 *     November 2006
00007 *
00008 *     .. Scalar Arguments ..
00009       INTEGER            LDA, LWORK, M, N
00010 *     ..
00011 *     .. Array Arguments ..
00012       DOUBLE PRECISION   RESULT( * ), RWORK( * )
00013       COMPLEX*16         A( LDA, * ), AF( LDA, * ), Q( LDA, * ),
00014      \$                   R( LDA, * ), TAU( * ), WORK( LWORK )
00015 *     ..
00016 *
00017 *  Purpose
00018 *  =======
00019 *
00020 *  ZRQT01 tests ZGERQF, which computes the RQ factorization of an m-by-n
00021 *  matrix A, and partially tests ZUNGRQ which forms the n-by-n
00022 *  orthogonal matrix Q.
00023 *
00024 *  ZRQT01 compares R with A*Q', and checks that Q is orthogonal.
00025 *
00026 *  Arguments
00027 *  =========
00028 *
00029 *  M       (input) INTEGER
00030 *          The number of rows of the matrix A.  M >= 0.
00031 *
00032 *  N       (input) INTEGER
00033 *          The number of columns of the matrix A.  N >= 0.
00034 *
00035 *  A       (input) COMPLEX*16 array, dimension (LDA,N)
00036 *          The m-by-n matrix A.
00037 *
00038 *  AF      (output) COMPLEX*16 array, dimension (LDA,N)
00039 *          Details of the RQ factorization of A, as returned by ZGERQF.
00040 *          See ZGERQF for further details.
00041 *
00042 *  Q       (output) COMPLEX*16 array, dimension (LDA,N)
00043 *          The n-by-n orthogonal matrix Q.
00044 *
00045 *  R       (workspace) COMPLEX*16 array, dimension (LDA,max(M,N))
00046 *
00047 *  LDA     (input) INTEGER
00048 *          The leading dimension of the arrays A, AF, Q and L.
00049 *          LDA >= max(M,N).
00050 *
00051 *  TAU     (output) COMPLEX*16 array, dimension (min(M,N))
00052 *          The scalar factors of the elementary reflectors, as returned
00053 *          by ZGERQF.
00054 *
00055 *  WORK    (workspace) COMPLEX*16 array, dimension (LWORK)
00056 *
00057 *  LWORK   (input) INTEGER
00058 *          The dimension of the array WORK.
00059 *
00060 *  RWORK   (workspace) DOUBLE PRECISION array, dimension (max(M,N))
00061 *
00062 *  RESULT  (output) DOUBLE PRECISION array, dimension (2)
00063 *          The test ratios:
00064 *          RESULT(1) = norm( R - A*Q' ) / ( N * norm(A) * EPS )
00065 *          RESULT(2) = norm( I - Q*Q' ) / ( N * EPS )
00066 *
00067 *  =====================================================================
00068 *
00069 *     .. Parameters ..
00070       DOUBLE PRECISION   ZERO, ONE
00071       PARAMETER          ( ZERO = 0.0D+0, ONE = 1.0D+0 )
00072       COMPLEX*16         ROGUE
00073       PARAMETER          ( ROGUE = ( -1.0D+10, -1.0D+10 ) )
00074 *     ..
00075 *     .. Local Scalars ..
00076       INTEGER            INFO, MINMN
00077       DOUBLE PRECISION   ANORM, EPS, RESID
00078 *     ..
00079 *     .. External Functions ..
00080       DOUBLE PRECISION   DLAMCH, ZLANGE, ZLANSY
00081       EXTERNAL           DLAMCH, ZLANGE, ZLANSY
00082 *     ..
00083 *     .. External Subroutines ..
00084       EXTERNAL           ZGEMM, ZGERQF, ZHERK, ZLACPY, ZLASET, ZUNGRQ
00085 *     ..
00086 *     .. Intrinsic Functions ..
00087       INTRINSIC          DBLE, DCMPLX, MAX, MIN
00088 *     ..
00089 *     .. Scalars in Common ..
00090       CHARACTER*32       SRNAMT
00091 *     ..
00092 *     .. Common blocks ..
00093       COMMON             / SRNAMC / SRNAMT
00094 *     ..
00095 *     .. Executable Statements ..
00096 *
00097       MINMN = MIN( M, N )
00098       EPS = DLAMCH( 'Epsilon' )
00099 *
00100 *     Copy the matrix A to the array AF.
00101 *
00102       CALL ZLACPY( 'Full', M, N, A, LDA, AF, LDA )
00103 *
00104 *     Factorize the matrix A in the array AF.
00105 *
00106       SRNAMT = 'ZGERQF'
00107       CALL ZGERQF( M, N, AF, LDA, TAU, WORK, LWORK, INFO )
00108 *
00109 *     Copy details of Q
00110 *
00111       CALL ZLASET( 'Full', N, N, ROGUE, ROGUE, Q, LDA )
00112       IF( M.LE.N ) THEN
00113          IF( M.GT.0 .AND. M.LT.N )
00114      \$      CALL ZLACPY( 'Full', M, N-M, AF, LDA, Q( N-M+1, 1 ), LDA )
00115          IF( M.GT.1 )
00116      \$      CALL ZLACPY( 'Lower', M-1, M-1, AF( 2, N-M+1 ), LDA,
00117      \$                   Q( N-M+2, N-M+1 ), LDA )
00118       ELSE
00119          IF( N.GT.1 )
00120      \$      CALL ZLACPY( 'Lower', N-1, N-1, AF( M-N+2, 1 ), LDA,
00121      \$                   Q( 2, 1 ), LDA )
00122       END IF
00123 *
00124 *     Generate the n-by-n matrix Q
00125 *
00126       SRNAMT = 'ZUNGRQ'
00127       CALL ZUNGRQ( N, N, MINMN, Q, LDA, TAU, WORK, LWORK, INFO )
00128 *
00129 *     Copy R
00130 *
00131       CALL ZLASET( 'Full', M, N, DCMPLX( ZERO ), DCMPLX( ZERO ), R,
00132      \$             LDA )
00133       IF( M.LE.N ) THEN
00134          IF( M.GT.0 )
00135      \$      CALL ZLACPY( 'Upper', M, M, AF( 1, N-M+1 ), LDA,
00136      \$                   R( 1, N-M+1 ), LDA )
00137       ELSE
00138          IF( M.GT.N .AND. N.GT.0 )
00139      \$      CALL ZLACPY( 'Full', M-N, N, AF, LDA, R, LDA )
00140          IF( N.GT.0 )
00141      \$      CALL ZLACPY( 'Upper', N, N, AF( M-N+1, 1 ), LDA,
00142      \$                   R( M-N+1, 1 ), LDA )
00143       END IF
00144 *
00145 *     Compute R - A*Q'
00146 *
00147       CALL ZGEMM( 'No transpose', 'Conjugate transpose', M, N, N,
00148      \$            DCMPLX( -ONE ), A, LDA, Q, LDA, DCMPLX( ONE ), R,
00149      \$            LDA )
00150 *
00151 *     Compute norm( R - Q'*A ) / ( N * norm(A) * EPS ) .
00152 *
00153       ANORM = ZLANGE( '1', M, N, A, LDA, RWORK )
00154       RESID = ZLANGE( '1', M, N, R, LDA, RWORK )
00155       IF( ANORM.GT.ZERO ) THEN
00156          RESULT( 1 ) = ( ( RESID / DBLE( MAX( 1, N ) ) ) / ANORM ) / EPS
00157       ELSE
00158          RESULT( 1 ) = ZERO
00159       END IF
00160 *
00161 *     Compute I - Q*Q'
00162 *
00163       CALL ZLASET( 'Full', N, N, DCMPLX( ZERO ), DCMPLX( ONE ), R, LDA )
00164       CALL ZHERK( 'Upper', 'No transpose', N, N, -ONE, Q, LDA, ONE, R,
00165      \$            LDA )
00166 *
00167 *     Compute norm( I - Q*Q' ) / ( N * EPS ) .
00168 *
00169       RESID = ZLANSY( '1', 'Upper', N, R, LDA, RWORK )
00170 *
00171       RESULT( 2 ) = ( RESID / DBLE( MAX( 1, N ) ) ) / EPS
00172 *
00173       RETURN
00174 *
00175 *     End of ZRQT01
00176 *
00177       END
```