LAPACK 3.3.1 Linear Algebra PACKage

# sorgr2.f

Go to the documentation of this file.
```00001       SUBROUTINE SORGR2( M, N, K, A, LDA, TAU, WORK, INFO )
00002 *
00003 *  -- LAPACK routine (version 3.2) --
00004 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
00005 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
00006 *     November 2006
00007 *
00008 *     .. Scalar Arguments ..
00009       INTEGER            INFO, K, LDA, M, N
00010 *     ..
00011 *     .. Array Arguments ..
00012       REAL               A( LDA, * ), TAU( * ), WORK( * )
00013 *     ..
00014 *
00015 *  Purpose
00016 *  =======
00017 *
00018 *  SORGR2 generates an m by n real matrix Q with orthonormal rows,
00019 *  which is defined as the last m rows of a product of k elementary
00020 *  reflectors of order n
00021 *
00022 *        Q  =  H(1) H(2) . . . H(k)
00023 *
00024 *  as returned by SGERQF.
00025 *
00026 *  Arguments
00027 *  =========
00028 *
00029 *  M       (input) INTEGER
00030 *          The number of rows of the matrix Q. M >= 0.
00031 *
00032 *  N       (input) INTEGER
00033 *          The number of columns of the matrix Q. N >= M.
00034 *
00035 *  K       (input) INTEGER
00036 *          The number of elementary reflectors whose product defines the
00037 *          matrix Q. M >= K >= 0.
00038 *
00039 *  A       (input/output) REAL array, dimension (LDA,N)
00040 *          On entry, the (m-k+i)-th row must contain the vector which
00041 *          defines the elementary reflector H(i), for i = 1,2,...,k, as
00042 *          returned by SGERQF in the last k rows of its array argument
00043 *          A.
00044 *          On exit, the m by n matrix Q.
00045 *
00046 *  LDA     (input) INTEGER
00047 *          The first dimension of the array A. LDA >= max(1,M).
00048 *
00049 *  TAU     (input) REAL array, dimension (K)
00050 *          TAU(i) must contain the scalar factor of the elementary
00051 *          reflector H(i), as returned by SGERQF.
00052 *
00053 *  WORK    (workspace) REAL array, dimension (M)
00054 *
00055 *  INFO    (output) INTEGER
00056 *          = 0: successful exit
00057 *          < 0: if INFO = -i, the i-th argument has an illegal value
00058 *
00059 *  =====================================================================
00060 *
00061 *     .. Parameters ..
00062       REAL               ONE, ZERO
00063       PARAMETER          ( ONE = 1.0E+0, ZERO = 0.0E+0 )
00064 *     ..
00065 *     .. Local Scalars ..
00066       INTEGER            I, II, J, L
00067 *     ..
00068 *     .. External Subroutines ..
00069       EXTERNAL           SLARF, SSCAL, XERBLA
00070 *     ..
00071 *     .. Intrinsic Functions ..
00072       INTRINSIC          MAX
00073 *     ..
00074 *     .. Executable Statements ..
00075 *
00076 *     Test the input arguments
00077 *
00078       INFO = 0
00079       IF( M.LT.0 ) THEN
00080          INFO = -1
00081       ELSE IF( N.LT.M ) THEN
00082          INFO = -2
00083       ELSE IF( K.LT.0 .OR. K.GT.M ) THEN
00084          INFO = -3
00085       ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
00086          INFO = -5
00087       END IF
00088       IF( INFO.NE.0 ) THEN
00089          CALL XERBLA( 'SORGR2', -INFO )
00090          RETURN
00091       END IF
00092 *
00093 *     Quick return if possible
00094 *
00095       IF( M.LE.0 )
00096      \$   RETURN
00097 *
00098       IF( K.LT.M ) THEN
00099 *
00100 *        Initialise rows 1:m-k to rows of the unit matrix
00101 *
00102          DO 20 J = 1, N
00103             DO 10 L = 1, M - K
00104                A( L, J ) = ZERO
00105    10       CONTINUE
00106             IF( J.GT.N-M .AND. J.LE.N-K )
00107      \$         A( M-N+J, J ) = ONE
00108    20    CONTINUE
00109       END IF
00110 *
00111       DO 40 I = 1, K
00112          II = M - K + I
00113 *
00114 *        Apply H(i) to A(1:m-k+i,1:n-k+i) from the right
00115 *
00116          A( II, N-M+II ) = ONE
00117          CALL SLARF( 'Right', II-1, N-M+II, A( II, 1 ), LDA, TAU( I ),
00118      \$               A, LDA, WORK )
00119          CALL SSCAL( N-M+II-1, -TAU( I ), A( II, 1 ), LDA )
00120          A( II, N-M+II ) = ONE - TAU( I )
00121 *
00122 *        Set A(m-k+i,n-k+i+1:n) to zero
00123 *
00124          DO 30 L = N - M + II + 1, N
00125             A( II, L ) = ZERO
00126    30    CONTINUE
00127    40 CONTINUE
00128       RETURN
00129 *
00130 *     End of SORGR2
00131 *
00132       END
```