001:       SUBROUTINE ZSYEQUB( UPLO, N, A, LDA, S, SCOND, AMAX, WORK, INFO )
002: *
003: *     -- LAPACK routine (version 3.2)                                 --
004: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
005: *     -- Jason Riedy of Univ. of California Berkeley.                 --
006: *     -- November 2008                                                --
007: *
008: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
009: *     -- Univ. of California Berkeley and NAG Ltd.                    --
010: *
011:       IMPLICIT NONE
012: *     ..
013: *     .. Scalar Arguments ..
014:       INTEGER            INFO, LDA, N
015:       DOUBLE PRECISION   AMAX, SCOND
016:       CHARACTER          UPLO
017: *     ..
018: *     .. Array Arguments ..
019:       COMPLEX*16         A( LDA, * ), WORK( * )
020:       DOUBLE PRECISION   S( * )
021: *     ..
022: *
023: *  Purpose
024: *  =======
025: *
026: *  ZSYEQUB computes row and column scalings intended to equilibrate a
027: *  symmetric matrix A and reduce its condition number
028: *  (with respect to the two-norm).  S contains the scale factors,
029: *  S(i) = 1/sqrt(A(i,i)), chosen so that the scaled matrix B with
030: *  elements B(i,j) = S(i)*A(i,j)*S(j) has ones on the diagonal.  This
031: *  choice of S puts the condition number of B within a factor N of the
032: *  smallest possible condition number over all possible diagonal
033: *  scalings.
034: *
035: *  Arguments
036: *  =========
037: *
038: *  N       (input) INTEGER
039: *          The order of the matrix A.  N >= 0.
040: *
041: *  A       (input) COMPLEX*16 array, dimension (LDA,N)
042: *          The N-by-N symmetric matrix whose scaling
043: *          factors are to be computed.  Only the diagonal elements of A
044: *          are referenced.
045: *
046: *  LDA     (input) INTEGER
047: *          The leading dimension of the array A.  LDA >= max(1,N).
048: *
049: *  S       (output) DOUBLE PRECISION array, dimension (N)
050: *          If INFO = 0, S contains the scale factors for A.
051: *
052: *  SCOND   (output) DOUBLE PRECISION
053: *          If INFO = 0, S contains the ratio of the smallest S(i) to
054: *          the largest S(i).  If SCOND >= 0.1 and AMAX is neither too
055: *          large nor too small, it is not worth scaling by S.
056: *
057: *  AMAX    (output) DOUBLE PRECISION
058: *          Absolute value of largest matrix element.  If AMAX is very
059: *          close to overflow or very close to underflow, the matrix
060: *          should be scaled.
061: *  INFO    (output) INTEGER
062: *          = 0:  successful exit
063: *          < 0:  if INFO = -i, the i-th argument had an illegal value
064: *          > 0:  if INFO = i, the i-th diagonal element is nonpositive.
065: *
066: *  Further Details
067: *  ======= =======
068: *
069: *  Reference: Livne, O.E. and Golub, G.H., "Scaling by Binormalization",
070: *  Numerical Algorithms, vol. 35, no. 1, pp. 97-120, January 2004.
071: *  DOI 10.1023/B:NUMA.0000016606.32820.69
072: *  Tech report version: http://ruready.utah.edu/archive/papers/bin.pdf
073: *
074: *  =====================================================================
075: *
076: *     .. Parameters ..
077:       DOUBLE PRECISION   ONE, ZERO
078:       PARAMETER          ( ONE = 1.0D0, ZERO = 0.0D0 )
079:       INTEGER            MAX_ITER
080:       PARAMETER          ( MAX_ITER = 100 )
081: *     ..
082: *     .. Local Scalars ..
083:       INTEGER            I, J, ITER
084:       DOUBLE PRECISION   AVG, STD, TOL, C0, C1, C2, T, U, SI, D, BASE,
085:      $                   SMIN, SMAX, SMLNUM, BIGNUM, SCALE, SUMSQ
086:       LOGICAL            UP
087:       COMPLEX*16         ZDUM
088: *     ..
089: *     .. External Functions ..
090:       DOUBLE PRECISION   DLAMCH
091:       LOGICAL            LSAME
092: *     ..
093: *     .. External Subroutines ..
094:       EXTERNAL           ZLASSQ
095: *     ..
096: *     .. Statement Functions ..
097:       DOUBLE PRECISION   CABS1
098: *     ..
099: *     Statement Function Definitions
100:       CABS1( ZDUM ) = ABS( DBLE( ZDUM ) ) + ABS( DIMAG( ZDUM ) )
101: *     ..
102: *     .. Executable Statements ..
103: *
104: *     Test the input parameters.
105: *
106:       INFO = 0
107:       IF ( .NOT. ( LSAME( UPLO, 'U' ) .OR. LSAME( UPLO, 'L' ) ) ) THEN
108:         INFO = -1
109:       ELSE IF ( N .LT. 0 ) THEN
110:         INFO = -2
111:       ELSE IF ( LDA .LT. MAX( 1, N ) ) THEN
112:         INFO = -4
113:       END IF
114:       IF ( INFO .NE. 0 ) THEN
115:         CALL XERBLA( 'ZSYEQUB', -INFO )
116:         RETURN
117:       END IF
118: 
119:       UP = LSAME( UPLO, 'U' )
120:       AMAX = ZERO
121: *
122: *     Quick return if possible.
123: *
124:       IF ( N .EQ. 0 ) THEN
125:         SCOND = ONE
126:         RETURN
127:       END IF
128: 
129:       DO I = 1, N
130:         S( I ) = ZERO
131:       END DO
132: 
133:       AMAX = ZERO
134:       IF ( UP ) THEN
135:          DO J = 1, N
136:             DO I = 1, J-1
137:                S( I ) = MAX( S( I ), CABS1( A( I, J ) ) )
138:                S( J ) = MAX( S( J ), CABS1( A( I, J ) ) )
139:                AMAX = MAX( AMAX, CABS1( A( I, J ) ) )
140:             END DO
141:             S( J ) = MAX( S( J ), CABS1( A( J, J) ) )
142:             AMAX = MAX( AMAX, CABS1( A( J, J ) ) )
143:          END DO
144:       ELSE
145:          DO J = 1, N
146:             S( J ) = MAX( S( J ), CABS1( A( J, J ) ) )
147:             AMAX = MAX( AMAX, CABS1( A( J, J ) ) )
148:             DO I = J+1, N
149:                S( I ) = MAX( S( I ), CABS1( A( I, J ) ) )
150:                S( J ) = MAX( S( J ), CABS1 (A( I, J ) ) )
151:                AMAX = MAX( AMAX, CABS1( A( I, J ) ) )
152:             END DO
153:          END DO
154:       END IF
155:       DO J = 1, N
156:          S( J ) = 1.0D+0 / S( J )
157:       END DO
158: 
159:       TOL = ONE / SQRT( 2.0D0 * N )
160: 
161:       DO ITER = 1, MAX_ITER
162:          SCALE = 0.0D+0
163:          SUMSQ = 0.0D+0
164: *       beta = |A|s
165:         DO I = 1, N
166:            WORK( I ) = ZERO
167:         END DO
168:         IF ( UP ) THEN
169:            DO J = 1, N
170:               DO I = 1, J-1
171:                  T = CABS1( A( I, J ) )
172:                  WORK( I ) = WORK( I ) + CABS1( A( I, J ) ) * S( J )
173:                  WORK( J ) = WORK( J ) + CABS1( A( I, J ) ) * S( I )
174:               END DO
175:               WORK( J ) = WORK( J ) + CABS1( A( J, J ) ) * S( J )
176:            END DO
177:         ELSE
178:            DO J = 1, N
179:               WORK( J ) = WORK( J ) + CABS1( A( J, J ) ) * S( J )
180:               DO I = J+1, N
181:                  T = CABS1( A( I, J ) )
182:                  WORK( I ) = WORK( I ) + CABS1( A( I, J ) ) * S( J )
183:                  WORK( J ) = WORK( J ) + CABS1( A( I, J ) ) * S( I )
184:               END DO
185:            END DO
186:         END IF
187: 
188: *       avg = s^T beta / n
189:         AVG = 0.0D+0
190:         DO I = 1, N
191:           AVG = AVG + S( I )*WORK( I )
192:         END DO
193:         AVG = AVG / N
194: 
195:         STD = 0.0D+0
196:         DO I = N+1, 2*N
197:            WORK( I ) = S( I-N ) * WORK( I-N ) - AVG
198:         END DO
199:         CALL ZLASSQ( N, WORK( N+1 ), 1, SCALE, SUMSQ )
200:         STD = SCALE * SQRT( SUMSQ / N )
201: 
202:         IF ( STD .LT. TOL * AVG ) GOTO 999
203: 
204:         DO I = 1, N
205:           T = CABS1( A( I, I ) )
206:           SI = S( I )
207:           C2 = ( N-1 ) * T
208:           C1 = ( N-2 ) * ( WORK( I ) - T*SI )
209:           C0 = -(T*SI)*SI + 2*WORK( I )*SI - N*AVG
210:           D = C1*C1 - 4*C0*C2
211: 
212:           IF ( D .LE. 0 ) THEN
213:             INFO = -1
214:             RETURN
215:           END IF
216:           SI = -2*C0 / ( C1 + SQRT( D ) )
217: 
218:           D = SI - S( I )
219:           U = ZERO
220:           IF ( UP ) THEN
221:             DO J = 1, I
222:               T = CABS1( A( J, I ) )
223:               U = U + S( J )*T
224:               WORK( J ) = WORK( J ) + D*T
225:             END DO
226:             DO J = I+1,N
227:               T = CABS1( A( I, J ) )
228:               U = U + S( J )*T
229:               WORK( J ) = WORK( J ) + D*T
230:             END DO
231:           ELSE
232:             DO J = 1, I
233:               T = CABS1( A( I, J ) )
234:               U = U + S( J )*T
235:               WORK( J ) = WORK( J ) + D*T
236:             END DO
237:             DO J = I+1,N
238:               T = CABS1( A( J, I ) )
239:               U = U + S( J )*T
240:               WORK( J ) = WORK( J ) + D*T
241:             END DO
242:           END IF
243:           AVG = AVG + ( U + WORK( I ) ) * D / N
244:           S( I ) = SI
245:         END DO
246:       END DO
247: 
248:  999  CONTINUE
249: 
250:       SMLNUM = DLAMCH( 'SAFEMIN' )
251:       BIGNUM = ONE / SMLNUM
252:       SMIN = BIGNUM
253:       SMAX = ZERO
254:       T = ONE / SQRT( AVG )
255:       BASE = DLAMCH( 'B' )
256:       U = ONE / LOG( BASE )
257:       DO I = 1, N
258:         S( I ) = BASE ** INT( U * LOG( S( I ) * T ) )
259:         SMIN = MIN( SMIN, S( I ) )
260:         SMAX = MAX( SMAX, S( I ) )
261:       END DO
262:       SCOND = MAX( SMIN, SMLNUM ) / MIN( SMAX, BIGNUM )
263: *
264:       END
265: