001:       SUBROUTINE ZLACON( N, V, X, EST, KASE )
002: *
003: *  -- LAPACK auxiliary routine (version 3.2) --
004: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
005: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       INTEGER            KASE, N
010:       DOUBLE PRECISION   EST
011: *     ..
012: *     .. Array Arguments ..
013:       COMPLEX*16         V( N ), X( N )
014: *     ..
015: *
016: *  Purpose
017: *  =======
018: *
019: *  ZLACON estimates the 1-norm of a square, complex matrix A.
020: *  Reverse communication is used for evaluating matrix-vector products.
021: *
022: *  Arguments
023: *  =========
024: *
025: *  N      (input) INTEGER
026: *         The order of the matrix.  N >= 1.
027: *
028: *  V      (workspace) COMPLEX*16 array, dimension (N)
029: *         On the final return, V = A*W,  where  EST = norm(V)/norm(W)
030: *         (W is not returned).
031: *
032: *  X      (input/output) COMPLEX*16 array, dimension (N)
033: *         On an intermediate return, X should be overwritten by
034: *               A * X,   if KASE=1,
035: *               A' * X,  if KASE=2,
036: *         where A' is the conjugate transpose of A, and ZLACON must be
037: *         re-called with all the other parameters unchanged.
038: *
039: *  EST    (input/output) DOUBLE PRECISION
040: *         On entry with KASE = 1 or 2 and JUMP = 3, EST should be
041: *         unchanged from the previous call to ZLACON.
042: *         On exit, EST is an estimate (a lower bound) for norm(A). 
043: *
044: *  KASE   (input/output) INTEGER
045: *         On the initial call to ZLACON, KASE should be 0.
046: *         On an intermediate return, KASE will be 1 or 2, indicating
047: *         whether X should be overwritten by A * X  or A' * X.
048: *         On the final return from ZLACON, KASE will again be 0.
049: *
050: *  Further Details
051: *  ======= =======
052: *
053: *  Contributed by Nick Higham, University of Manchester.
054: *  Originally named CONEST, dated March 16, 1988.
055: *
056: *  Reference: N.J. Higham, "FORTRAN codes for estimating the one-norm of
057: *  a real or complex matrix, with applications to condition estimation",
058: *  ACM Trans. Math. Soft., vol. 14, no. 4, pp. 381-396, December 1988.
059: *
060: *  Last modified:  April, 1999
061: *
062: *  =====================================================================
063: *
064: *     .. Parameters ..
065:       INTEGER            ITMAX
066:       PARAMETER          ( ITMAX = 5 )
067:       DOUBLE PRECISION   ONE, TWO
068:       PARAMETER          ( ONE = 1.0D0, TWO = 2.0D0 )
069:       COMPLEX*16         CZERO, CONE
070:       PARAMETER          ( CZERO = ( 0.0D0, 0.0D0 ),
071:      $                   CONE = ( 1.0D0, 0.0D0 ) )
072: *     ..
073: *     .. Local Scalars ..
074:       INTEGER            I, ITER, J, JLAST, JUMP
075:       DOUBLE PRECISION   ABSXI, ALTSGN, ESTOLD, SAFMIN, TEMP
076: *     ..
077: *     .. External Functions ..
078:       INTEGER            IZMAX1
079:       DOUBLE PRECISION   DLAMCH, DZSUM1
080:       EXTERNAL           IZMAX1, DLAMCH, DZSUM1
081: *     ..
082: *     .. External Subroutines ..
083:       EXTERNAL           ZCOPY
084: *     ..
085: *     .. Intrinsic Functions ..
086:       INTRINSIC          ABS, DBLE, DCMPLX, DIMAG
087: *     ..
088: *     .. Save statement ..
089:       SAVE
090: *     ..
091: *     .. Executable Statements ..
092: *
093:       SAFMIN = DLAMCH( 'Safe minimum' )
094:       IF( KASE.EQ.0 ) THEN
095:          DO 10 I = 1, N
096:             X( I ) = DCMPLX( ONE / DBLE( N ) )
097:    10    CONTINUE
098:          KASE = 1
099:          JUMP = 1
100:          RETURN
101:       END IF
102: *
103:       GO TO ( 20, 40, 70, 90, 120 )JUMP
104: *
105: *     ................ ENTRY   (JUMP = 1)
106: *     FIRST ITERATION.  X HAS BEEN OVERWRITTEN BY A*X.
107: *
108:    20 CONTINUE
109:       IF( N.EQ.1 ) THEN
110:          V( 1 ) = X( 1 )
111:          EST = ABS( V( 1 ) )
112: *        ... QUIT
113:          GO TO 130
114:       END IF
115:       EST = DZSUM1( N, X, 1 )
116: *
117:       DO 30 I = 1, N
118:          ABSXI = ABS( X( I ) )
119:          IF( ABSXI.GT.SAFMIN ) THEN
120:             X( I ) = DCMPLX( DBLE( X( I ) ) / ABSXI,
121:      $               DIMAG( X( I ) ) / ABSXI )
122:          ELSE
123:             X( I ) = CONE
124:          END IF
125:    30 CONTINUE
126:       KASE = 2
127:       JUMP = 2
128:       RETURN
129: *
130: *     ................ ENTRY   (JUMP = 2)
131: *     FIRST ITERATION.  X HAS BEEN OVERWRITTEN BY CTRANS(A)*X.
132: *
133:    40 CONTINUE
134:       J = IZMAX1( N, X, 1 )
135:       ITER = 2
136: *
137: *     MAIN LOOP - ITERATIONS 2,3,...,ITMAX.
138: *
139:    50 CONTINUE
140:       DO 60 I = 1, N
141:          X( I ) = CZERO
142:    60 CONTINUE
143:       X( J ) = CONE
144:       KASE = 1
145:       JUMP = 3
146:       RETURN
147: *
148: *     ................ ENTRY   (JUMP = 3)
149: *     X HAS BEEN OVERWRITTEN BY A*X.
150: *
151:    70 CONTINUE
152:       CALL ZCOPY( N, X, 1, V, 1 )
153:       ESTOLD = EST
154:       EST = DZSUM1( N, V, 1 )
155: *
156: *     TEST FOR CYCLING.
157:       IF( EST.LE.ESTOLD )
158:      $   GO TO 100
159: *
160:       DO 80 I = 1, N
161:          ABSXI = ABS( X( I ) )
162:          IF( ABSXI.GT.SAFMIN ) THEN
163:             X( I ) = DCMPLX( DBLE( X( I ) ) / ABSXI,
164:      $               DIMAG( X( I ) ) / ABSXI )
165:          ELSE
166:             X( I ) = CONE
167:          END IF
168:    80 CONTINUE
169:       KASE = 2
170:       JUMP = 4
171:       RETURN
172: *
173: *     ................ ENTRY   (JUMP = 4)
174: *     X HAS BEEN OVERWRITTEN BY CTRANS(A)*X.
175: *
176:    90 CONTINUE
177:       JLAST = J
178:       J = IZMAX1( N, X, 1 )
179:       IF( ( ABS( X( JLAST ) ).NE.ABS( X( J ) ) ) .AND.
180:      $    ( ITER.LT.ITMAX ) ) THEN
181:          ITER = ITER + 1
182:          GO TO 50
183:       END IF
184: *
185: *     ITERATION COMPLETE.  FINAL STAGE.
186: *
187:   100 CONTINUE
188:       ALTSGN = ONE
189:       DO 110 I = 1, N
190:          X( I ) = DCMPLX( ALTSGN*( ONE+DBLE( I-1 ) / DBLE( N-1 ) ) )
191:          ALTSGN = -ALTSGN
192:   110 CONTINUE
193:       KASE = 1
194:       JUMP = 5
195:       RETURN
196: *
197: *     ................ ENTRY   (JUMP = 5)
198: *     X HAS BEEN OVERWRITTEN BY A*X.
199: *
200:   120 CONTINUE
201:       TEMP = TWO*( DZSUM1( N, X, 1 ) / DBLE( 3*N ) )
202:       IF( TEMP.GT.EST ) THEN
203:          CALL ZCOPY( N, X, 1, V, 1 )
204:          EST = TEMP
205:       END IF
206: *
207:   130 CONTINUE
208:       KASE = 0
209:       RETURN
210: *
211: *     End of ZLACON
212: *
213:       END
214: