001:       DOUBLE PRECISION FUNCTION ZLA_PORCOND_C( UPLO, N, A, LDA, AF, 
002:      $                                         LDAF, C, CAPPLY, INFO,
003:      $                                         WORK, RWORK )
004: *
005: *     -- LAPACK routine (version 3.2.1)                                 --
006: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
007: *     -- Jason Riedy of Univ. of California Berkeley.                 --
008: *     -- April 2009                                                   --
009: *
010: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
011: *     -- Univ. of California Berkeley and NAG Ltd.                    --
012: *
013:       IMPLICIT NONE
014: *     ..
015: *     .. Scalar Arguments ..
016:       CHARACTER          UPLO
017:       LOGICAL            CAPPLY
018:       INTEGER            N, LDA, LDAF, INFO
019: *     ..
020: *     .. Array Arguments ..
021:       COMPLEX*16         A( LDA, * ), AF( LDAF, * ), WORK( * )
022:       DOUBLE PRECISION   C( * ), RWORK( * )
023: *     ..
024: *
025: *  Purpose
026: *  =======
027: *
028: *     ZLA_PORCOND_C Computes the infinity norm condition number of
029: *     op(A) * inv(diag(C)) where C is a DOUBLE PRECISION vector
030: *
031: *  Arguments
032: *  =========
033: *
034: *     UPLO    (input) CHARACTER*1
035: *       = 'U':  Upper triangle of A is stored;
036: *       = 'L':  Lower triangle of A is stored.
037: *
038: *     N       (input) INTEGER
039: *     The number of linear equations, i.e., the order of the
040: *     matrix A.  N >= 0.
041: *
042: *     A       (input) COMPLEX*16 array, dimension (LDA,N)
043: *     On entry, the N-by-N matrix A
044: *
045: *     LDA     (input) INTEGER
046: *     The leading dimension of the array A.  LDA >= max(1,N).
047: *
048: *     AF      (input) COMPLEX*16 array, dimension (LDAF,N)
049: *     The triangular factor U or L from the Cholesky factorization
050: *     A = U**T*U or A = L*L**T, as computed by ZPOTRF.
051: *
052: *     LDAF    (input) INTEGER
053: *     The leading dimension of the array AF.  LDAF >= max(1,N).
054: *
055: *     C       (input) DOUBLE PRECISION array, dimension (N)
056: *     The vector C in the formula op(A) * inv(diag(C)).
057: *
058: *     CAPPLY  (input) LOGICAL
059: *     If .TRUE. then access the vector C in the formula above.
060: *
061: *     INFO    (output) INTEGER
062: *       = 0:  Successful exit.
063: *     i > 0:  The ith argument is invalid.
064: *
065: *     WORK    (input) COMPLEX*16 array, dimension (2*N).
066: *     Workspace.
067: *
068: *     RWORK   (input) DOUBLE PRECISION array, dimension (N).
069: *     Workspace.
070: *
071: *  =====================================================================
072: *
073: *     .. Local Scalars ..
074:       INTEGER            KASE
075:       DOUBLE PRECISION   AINVNM, ANORM, TMP
076:       INTEGER            I, J
077:       LOGICAL            UP
078:       COMPLEX*16         ZDUM
079: *     ..
080: *     .. Local Arrays ..
081:       INTEGER            ISAVE( 3 )
082: *     ..
083: *     .. External Functions ..
084:       LOGICAL            LSAME
085:       EXTERNAL           LSAME
086: *     ..
087: *     .. External Subroutines ..
088:       EXTERNAL           ZLACN2, ZPOTRS, XERBLA
089: *     ..
090: *     .. Intrinsic Functions ..
091:       INTRINSIC          ABS, MAX, REAL, DIMAG
092: *     ..
093: *     .. Statement Functions ..
094:       DOUBLE PRECISION CABS1
095: *     ..
096: *     .. Statement Function Definitions ..
097:       CABS1( ZDUM ) = ABS( DBLE( ZDUM ) ) + ABS( DIMAG( ZDUM ) )
098: *     ..
099: *     .. Executable Statements ..
100: *
101:       ZLA_PORCOND_C = 0.0D+0
102: *
103:       INFO = 0
104:       IF( N.LT.0 ) THEN
105:          INFO = -2
106:       END IF
107:       IF( INFO.NE.0 ) THEN
108:          CALL XERBLA( 'ZLA_PORCOND_C', -INFO )
109:          RETURN
110:       END IF
111:       UP = .FALSE.
112:       IF ( LSAME( UPLO, 'U' ) ) UP = .TRUE.
113: *
114: *     Compute norm of op(A)*op2(C).
115: *
116:       ANORM = 0.0D+0
117:       IF ( UP ) THEN
118:          DO I = 1, N
119:             TMP = 0.0D+0
120:             IF ( CAPPLY ) THEN
121:                DO J = 1, I
122:                   TMP = TMP + CABS1( A( J, I ) ) / C( J )
123:                END DO
124:                DO J = I+1, N
125:                   TMP = TMP + CABS1( A( I, J ) ) / C( J )
126:                END DO
127:             ELSE
128:                DO J = 1, I
129:                   TMP = TMP + CABS1( A( J, I ) )
130:                END DO
131:                DO J = I+1, N
132:                   TMP = TMP + CABS1( A( I, J ) )
133:                END DO
134:             END IF
135:             RWORK( I ) = TMP
136:             ANORM = MAX( ANORM, TMP )
137:          END DO
138:       ELSE
139:          DO I = 1, N
140:             TMP = 0.0D+0
141:             IF ( CAPPLY ) THEN
142:                DO J = 1, I
143:                   TMP = TMP + CABS1( A( I, J ) ) / C( J )
144:                END DO
145:                DO J = I+1, N
146:                   TMP = TMP + CABS1( A( J, I ) ) / C( J )
147:                END DO
148:             ELSE
149:                DO J = 1, I
150:                   TMP = TMP + CABS1( A( I, J ) )
151:                END DO
152:                DO J = I+1, N
153:                   TMP = TMP + CABS1( A( J, I ) )
154:                END DO
155:             END IF
156:             RWORK( I ) = TMP
157:             ANORM = MAX( ANORM, TMP )
158:          END DO
159:       END IF
160: *
161: *     Quick return if possible.
162: *
163:       IF( N.EQ.0 ) THEN
164:          ZLA_PORCOND_C = 1.0D+0
165:          RETURN
166:       ELSE IF( ANORM .EQ. 0.0D+0 ) THEN
167:          RETURN
168:       END IF
169: *
170: *     Estimate the norm of inv(op(A)).
171: *
172:       AINVNM = 0.0D+0
173: *
174:       KASE = 0
175:    10 CONTINUE
176:       CALL ZLACN2( N, WORK( N+1 ), WORK, AINVNM, KASE, ISAVE )
177:       IF( KASE.NE.0 ) THEN
178:          IF( KASE.EQ.2 ) THEN
179: *
180: *           Multiply by R.
181: *
182:             DO I = 1, N
183:                WORK( I ) = WORK( I ) * RWORK( I )
184:             END DO
185: *
186:             IF ( UP ) THEN
187:                CALL ZPOTRS( 'U', N, 1, AF, LDAF,
188:      $            WORK, N, INFO )
189:             ELSE
190:                CALL ZPOTRS( 'L', N, 1, AF, LDAF,
191:      $            WORK, N, INFO )
192:             ENDIF
193: *
194: *           Multiply by inv(C).
195: *
196:             IF ( CAPPLY ) THEN
197:                DO I = 1, N
198:                   WORK( I ) = WORK( I ) * C( I )
199:                END DO
200:             END IF
201:          ELSE
202: *
203: *           Multiply by inv(C').
204: *
205:             IF ( CAPPLY ) THEN
206:                DO I = 1, N
207:                   WORK( I ) = WORK( I ) * C( I )
208:                END DO
209:             END IF
210: *
211:             IF ( UP ) THEN
212:                CALL ZPOTRS( 'U', N, 1, AF, LDAF,
213:      $            WORK, N, INFO )
214:             ELSE
215:                CALL ZPOTRS( 'L', N, 1, AF, LDAF,
216:      $            WORK, N, INFO )
217:             END IF
218: *
219: *           Multiply by R.
220: *
221:             DO I = 1, N
222:                WORK( I ) = WORK( I ) * RWORK( I )
223:             END DO
224:          END IF
225:          GO TO 10
226:       END IF
227: *
228: *     Compute the estimate of the reciprocal condition number.
229: *
230:       IF( AINVNM .NE. 0.0D+0 )
231:      $   ZLA_PORCOND_C = 1.0D+0 / AINVNM
232: *
233:       RETURN
234: *
235:       END
236: