001:       SUBROUTINE ZHEEQUB( UPLO, N, A, LDA, S, SCOND, AMAX, WORK, INFO )
002: *
003: *     -- LAPACK routine (version 3.2)                                 --
004: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
005: *     -- Jason Riedy of Univ. of California Berkeley.                 --
006: *     -- November 2008                                                --
007: *
008: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
009: *     -- Univ. of California Berkeley and NAG Ltd.                    --
010: *
011:       IMPLICIT NONE
012: *     ..
013: *     .. Scalar Arguments ..
014:       INTEGER            INFO, LDA, N
015:       DOUBLE PRECISION   AMAX, SCOND
016:       CHARACTER          UPLO
017: *     ..
018: *     .. Array Arguments ..
019:       COMPLEX*16         A( LDA, * ), WORK( * )
020:       DOUBLE PRECISION   S( * )
021: *     ..
022: *
023: *  Purpose
024: *  =======
025: *
026: *  ZSYEQUB computes row and column scalings intended to equilibrate a
027: *  symmetric matrix A and reduce its condition number
028: *  (with respect to the two-norm).  S contains the scale factors,
029: *  S(i) = 1/sqrt(A(i,i)), chosen so that the scaled matrix B with
030: *  elements B(i,j) = S(i)*A(i,j)*S(j) has ones on the diagonal.  This
031: *  choice of S puts the condition number of B within a factor N of the
032: *  smallest possible condition number over all possible diagonal
033: *  scalings.
034: *
035: *  Arguments
036: *  =========
037: *
038: *  N       (input) INTEGER
039: *          The order of the matrix A.  N >= 0.
040: *
041: *  A       (input) COMPLEX*16 array, dimension (LDA,N)
042: *          The N-by-N symmetric matrix whose scaling
043: *          factors are to be computed.  Only the diagonal elements of A
044: *          are referenced.
045: *
046: *  LDA     (input) INTEGER
047: *          The leading dimension of the array A.  LDA >= max(1,N).
048: *
049: *  S       (output) DOUBLE PRECISION array, dimension (N)
050: *          If INFO = 0, S contains the scale factors for A.
051: *
052: *  SCOND   (output) DOUBLE PRECISION
053: *          If INFO = 0, S contains the ratio of the smallest S(i) to
054: *          the largest S(i).  If SCOND >= 0.1 and AMAX is neither too
055: *          large nor too small, it is not worth scaling by S.
056: *
057: *  AMAX    (output) DOUBLE PRECISION
058: *          Absolute value of largest matrix element.  If AMAX is very
059: *          close to overflow or very close to underflow, the matrix
060: *          should be scaled.
061: *  INFO    (output) INTEGER
062: *          = 0:  successful exit
063: *          < 0:  if INFO = -i, the i-th argument had an illegal value
064: *          > 0:  if INFO = i, the i-th diagonal element is nonpositive.
065: *
066: *  =====================================================================
067: *
068: *     .. Parameters ..
069:       DOUBLE PRECISION   ONE, ZERO
070:       PARAMETER          ( ONE = 1.0D+0, ZERO = 0.0D+0 )
071:       INTEGER            MAX_ITER
072:       PARAMETER          ( MAX_ITER = 100 )
073: *     ..
074: *     .. Local Scalars ..
075:       INTEGER            I, J, ITER
076:       DOUBLE PRECISION   AVG, STD, TOL, C0, C1, C2, T, U, SI, D,
077:      $                   BASE, SMIN, SMAX, SMLNUM, BIGNUM, SCALE, SUMSQ
078:       LOGICAL            UP
079:       COMPLEX*16         ZDUM
080: *     ..
081: *     .. External Functions ..
082:       DOUBLE PRECISION   DLAMCH
083:       LOGICAL            LSAME
084: *     ..
085: *     .. External Subroutines ..
086:       EXTERNAL           ZLASSQ
087: *     ..
088: *     .. Statement Functions ..
089:       DOUBLE PRECISION   CABS1
090: *     ..
091: *     .. Statement Function Definitions ..
092:       CABS1( ZDUM ) = ABS( DBLE( ZDUM ) ) + ABS( DIMAG( ZDUM ) )
093: *
094: *     Test input parameters.
095: *
096:       INFO = 0
097:       IF (.NOT. ( LSAME( UPLO, 'U' ) .OR. LSAME( UPLO, 'L' ) ) ) THEN
098:         INFO = -1
099:       ELSE IF ( N .LT. 0 ) THEN
100:         INFO = -2
101:       ELSE IF ( LDA .LT. MAX( 1, N ) ) THEN
102:         INFO = -4
103:       END IF
104:       IF ( INFO .NE. 0 ) THEN
105:         CALL XERBLA( 'ZHEEQUB', -INFO )
106:         RETURN
107:       END IF
108: 
109:       UP = LSAME( UPLO, 'U' )
110:       AMAX = ZERO
111: *
112: *     Quick return if possible.
113: *
114:       IF ( N .EQ. 0 ) THEN
115:         SCOND = ONE
116:         RETURN
117:       END IF
118: 
119:       DO I = 1, N
120:         S( I ) = ZERO
121:       END DO
122: 
123:       AMAX = ZERO
124:       IF ( UP ) THEN
125:          DO J = 1, N
126:             DO I = 1, J-1
127:                S( I ) = MAX( S( I ), CABS1( A( I, J ) ) )
128:                S( J ) = MAX( S( J ), CABS1( A( I, J ) ) )
129:                AMAX = MAX( AMAX, CABS1( A( I, J ) ) )
130:             END DO
131:             S( J ) = MAX( S( J ), CABS1( A( J, J ) ) )
132:             AMAX = MAX( AMAX, CABS1( A( J, J ) ) )
133:          END DO
134:       ELSE
135:          DO J = 1, N
136:             S( J ) = MAX( S( J ), CABS1( A( J, J ) ) )
137:             AMAX = MAX( AMAX, CABS1( A( J, J ) ) )
138:             DO I = J+1, N
139:                S( I ) = MAX( S( I ), CABS1( A( I, J ) ) )
140:                S( J ) = MAX( S( J ), CABS1( A( I, J ) ) )
141:                AMAX = MAX( AMAX, CABS1( A(I, J ) ) )
142:             END DO
143:          END DO
144:       END IF
145:       DO J = 1, N
146:          S( J ) = 1.0D+0 / S( J )
147:       END DO
148: 
149:       TOL = ONE / SQRT( 2.0D0 * N )
150: 
151:       DO ITER = 1, MAX_ITER
152:          SCALE = 0.0D+0
153:          SUMSQ = 0.0D+0
154: *       beta = |A|s
155:         DO I = 1, N
156:            WORK( I ) = ZERO
157:         END DO
158:         IF ( UP ) THEN
159:            DO J = 1, N
160:               DO I = 1, J-1
161:                  T = CABS1( A( I, J ) )
162:                  WORK( I ) = WORK( I ) + CABS1( A( I, J ) ) * S( J )
163:                  WORK( J ) = WORK( J ) + CABS1( A( I, J ) ) * S( I )
164:               END DO
165:               WORK( J ) = WORK( J ) + CABS1( A( J, J ) ) * S( J )
166:            END DO
167:         ELSE
168:            DO J = 1, N
169:               WORK( J ) = WORK( J ) + CABS1( A( J, J ) ) * S( J )
170:               DO I = J+1, N
171:                  T = CABS1( A( I, J ) )
172:                  WORK( I ) = WORK( I ) + CABS1( A( I, J ) ) * S( J )
173:                  WORK( J ) = WORK( J ) + CABS1( A( I, J ) ) * S( I )
174:               END DO
175:            END DO
176:         END IF
177: 
178: *       avg = s^T beta / n
179:         AVG = 0.0D+0
180:         DO I = 1, N
181:           AVG = AVG + S( I )*WORK( I )
182:         END DO
183:         AVG = AVG / N
184: 
185:         STD = 0.0D+0
186:         DO I = 2*N+1, 3*N
187:            WORK( I ) = S( I-2*N ) * WORK( I-2*N ) - AVG
188:         END DO
189:         CALL ZLASSQ( N, WORK( 2*N+1 ), 1, SCALE, SUMSQ )
190:         STD = SCALE * SQRT( SUMSQ / N )
191: 
192:         IF ( STD .LT. TOL * AVG ) GOTO 999
193: 
194:         DO I = 1, N
195:           T = CABS1( A( I, I ) )
196:           SI = S( I )
197:           C2 = ( N-1 ) * T
198:           C1 = ( N-2 ) * ( WORK( I ) - T*SI )
199:           C0 = -(T*SI)*SI + 2*WORK( I )*SI - N*AVG
200: 
201:           D = C1*C1 - 4*C0*C2
202:           IF ( D .LE. 0 ) THEN
203:             INFO = -1
204:             RETURN
205:           END IF
206:           SI = -2*C0 / ( C1 + SQRT( D ) )
207: 
208:           D = SI - S(I)
209:           U = ZERO
210:           IF ( UP ) THEN
211:             DO J = 1, I
212:               T = CABS1( A( J, I ) )
213:               U = U + S( J )*T
214:               WORK( J ) = WORK( J ) + D*T
215:             END DO
216:             DO J = I+1,N
217:               T = CABS1( A( I, J ) )
218:               U = U + S( J )*T
219:               WORK( J ) = WORK( J ) + D*T
220:             END DO
221:           ELSE
222:             DO J = 1, I
223:               T = CABS1( A( I, J ) )
224:               U = U + S( J )*T
225:               WORK( J ) = WORK( J ) + D*T
226:             END DO
227:             DO J = I+1,N
228:               T = CABS1( A( J, I ) )
229:               U = U + S( J )*T
230:               WORK( J ) = WORK( J ) + D*T
231:             END DO
232:           END IF
233:           AVG = AVG + ( U + WORK( I ) ) * D / N
234:           S( I ) = SI
235:         END DO
236: 
237:       END DO
238: 
239:  999  CONTINUE
240: 
241:       SMLNUM = DLAMCH( 'SAFEMIN' )
242:       BIGNUM = ONE / SMLNUM
243:       SMIN = BIGNUM
244:       SMAX = ZERO
245:       T = ONE / SQRT( AVG )
246:       BASE = DLAMCH( 'B' )
247:       U = ONE / LOG( BASE )
248:       DO I = 1, N
249:         S( I ) = BASE ** INT( U * LOG( S( I ) * T ) )
250:         SMIN = MIN( SMIN, S( I ) )
251:         SMAX = MAX( SMAX, S( I ) )
252:       END DO
253:       SCOND = MAX( SMIN, SMLNUM ) / MIN( SMAX, BIGNUM )
254: 
255:       END
256: