001:       SUBROUTINE STRTRI( UPLO, DIAG, N, A, LDA, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
005: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          DIAG, UPLO
010:       INTEGER            INFO, LDA, N
011: *     ..
012: *     .. Array Arguments ..
013:       REAL               A( LDA, * )
014: *     ..
015: *
016: *  Purpose
017: *  =======
018: *
019: *  STRTRI computes the inverse of a real upper or lower triangular
020: *  matrix A.
021: *
022: *  This is the Level 3 BLAS version of the algorithm.
023: *
024: *  Arguments
025: *  =========
026: *
027: *  UPLO    (input) CHARACTER*1
028: *          = 'U':  A is upper triangular;
029: *          = 'L':  A is lower triangular.
030: *
031: *  DIAG    (input) CHARACTER*1
032: *          = 'N':  A is non-unit triangular;
033: *          = 'U':  A is unit triangular.
034: *
035: *  N       (input) INTEGER
036: *          The order of the matrix A.  N >= 0.
037: *
038: *  A       (input/output) REAL array, dimension (LDA,N)
039: *          On entry, the triangular matrix A.  If UPLO = 'U', the
040: *          leading N-by-N upper triangular part of the array A contains
041: *          the upper triangular matrix, and the strictly lower
042: *          triangular part of A is not referenced.  If UPLO = 'L', the
043: *          leading N-by-N lower triangular part of the array A contains
044: *          the lower triangular matrix, and the strictly upper
045: *          triangular part of A is not referenced.  If DIAG = 'U', the
046: *          diagonal elements of A are also not referenced and are
047: *          assumed to be 1.
048: *          On exit, the (triangular) inverse of the original matrix, in
049: *          the same storage format.
050: *
051: *  LDA     (input) INTEGER
052: *          The leading dimension of the array A.  LDA >= max(1,N).
053: *
054: *  INFO    (output) INTEGER
055: *          = 0: successful exit
056: *          < 0: if INFO = -i, the i-th argument had an illegal value
057: *          > 0: if INFO = i, A(i,i) is exactly zero.  The triangular
058: *               matrix is singular and its inverse can not be computed.
059: *
060: *  =====================================================================
061: *
062: *     .. Parameters ..
063:       REAL               ONE, ZERO
064:       PARAMETER          ( ONE = 1.0E+0, ZERO = 0.0E+0 )
065: *     ..
066: *     .. Local Scalars ..
067:       LOGICAL            NOUNIT, UPPER
068:       INTEGER            J, JB, NB, NN
069: *     ..
070: *     .. External Functions ..
071:       LOGICAL            LSAME
072:       INTEGER            ILAENV
073:       EXTERNAL           LSAME, ILAENV
074: *     ..
075: *     .. External Subroutines ..
076:       EXTERNAL           STRMM, STRSM, STRTI2, XERBLA
077: *     ..
078: *     .. Intrinsic Functions ..
079:       INTRINSIC          MAX, MIN
080: *     ..
081: *     .. Executable Statements ..
082: *
083: *     Test the input parameters.
084: *
085:       INFO = 0
086:       UPPER = LSAME( UPLO, 'U' )
087:       NOUNIT = LSAME( DIAG, 'N' )
088:       IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
089:          INFO = -1
090:       ELSE IF( .NOT.NOUNIT .AND. .NOT.LSAME( DIAG, 'U' ) ) THEN
091:          INFO = -2
092:       ELSE IF( N.LT.0 ) THEN
093:          INFO = -3
094:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
095:          INFO = -5
096:       END IF
097:       IF( INFO.NE.0 ) THEN
098:          CALL XERBLA( 'STRTRI', -INFO )
099:          RETURN
100:       END IF
101: *
102: *     Quick return if possible
103: *
104:       IF( N.EQ.0 )
105:      $   RETURN
106: *
107: *     Check for singularity if non-unit.
108: *
109:       IF( NOUNIT ) THEN
110:          DO 10 INFO = 1, N
111:             IF( A( INFO, INFO ).EQ.ZERO )
112:      $         RETURN
113:    10    CONTINUE
114:          INFO = 0
115:       END IF
116: *
117: *     Determine the block size for this environment.
118: *
119:       NB = ILAENV( 1, 'STRTRI', UPLO // DIAG, N, -1, -1, -1 )
120:       IF( NB.LE.1 .OR. NB.GE.N ) THEN
121: *
122: *        Use unblocked code
123: *
124:          CALL STRTI2( UPLO, DIAG, N, A, LDA, INFO )
125:       ELSE
126: *
127: *        Use blocked code
128: *
129:          IF( UPPER ) THEN
130: *
131: *           Compute inverse of upper triangular matrix
132: *
133:             DO 20 J = 1, N, NB
134:                JB = MIN( NB, N-J+1 )
135: *
136: *              Compute rows 1:j-1 of current block column
137: *
138:                CALL STRMM( 'Left', 'Upper', 'No transpose', DIAG, J-1,
139:      $                     JB, ONE, A, LDA, A( 1, J ), LDA )
140:                CALL STRSM( 'Right', 'Upper', 'No transpose', DIAG, J-1,
141:      $                     JB, -ONE, A( J, J ), LDA, A( 1, J ), LDA )
142: *
143: *              Compute inverse of current diagonal block
144: *
145:                CALL STRTI2( 'Upper', DIAG, JB, A( J, J ), LDA, INFO )
146:    20       CONTINUE
147:          ELSE
148: *
149: *           Compute inverse of lower triangular matrix
150: *
151:             NN = ( ( N-1 ) / NB )*NB + 1
152:             DO 30 J = NN, 1, -NB
153:                JB = MIN( NB, N-J+1 )
154:                IF( J+JB.LE.N ) THEN
155: *
156: *                 Compute rows j+jb:n of current block column
157: *
158:                   CALL STRMM( 'Left', 'Lower', 'No transpose', DIAG,
159:      $                        N-J-JB+1, JB, ONE, A( J+JB, J+JB ), LDA,
160:      $                        A( J+JB, J ), LDA )
161:                   CALL STRSM( 'Right', 'Lower', 'No transpose', DIAG,
162:      $                        N-J-JB+1, JB, -ONE, A( J, J ), LDA,
163:      $                        A( J+JB, J ), LDA )
164:                END IF
165: *
166: *              Compute inverse of current diagonal block
167: *
168:                CALL STRTI2( 'Lower', DIAG, JB, A( J, J ), LDA, INFO )
169:    30       CONTINUE
170:          END IF
171:       END IF
172: *
173:       RETURN
174: *
175: *     End of STRTRI
176: *
177:       END
178: