001:       SUBROUTINE STRMV(UPLO,TRANS,DIAG,N,A,LDA,X,INCX)
002: *     .. Scalar Arguments ..
003:       INTEGER INCX,LDA,N
004:       CHARACTER DIAG,TRANS,UPLO
005: *     ..
006: *     .. Array Arguments ..
007:       REAL A(LDA,*),X(*)
008: *     ..
009: *
010: *  Purpose
011: *  =======
012: *
013: *  STRMV  performs one of the matrix-vector operations
014: *
015: *     x := A*x,   or   x := A'*x,
016: *
017: *  where x is an n element vector and  A is an n by n unit, or non-unit,
018: *  upper or lower triangular matrix.
019: *
020: *  Arguments
021: *  ==========
022: *
023: *  UPLO   - CHARACTER*1.
024: *           On entry, UPLO specifies whether the matrix is an upper or
025: *           lower triangular matrix as follows:
026: *
027: *              UPLO = 'U' or 'u'   A is an upper triangular matrix.
028: *
029: *              UPLO = 'L' or 'l'   A is a lower triangular matrix.
030: *
031: *           Unchanged on exit.
032: *
033: *  TRANS  - CHARACTER*1.
034: *           On entry, TRANS specifies the operation to be performed as
035: *           follows:
036: *
037: *              TRANS = 'N' or 'n'   x := A*x.
038: *
039: *              TRANS = 'T' or 't'   x := A'*x.
040: *
041: *              TRANS = 'C' or 'c'   x := A'*x.
042: *
043: *           Unchanged on exit.
044: *
045: *  DIAG   - CHARACTER*1.
046: *           On entry, DIAG specifies whether or not A is unit
047: *           triangular as follows:
048: *
049: *              DIAG = 'U' or 'u'   A is assumed to be unit triangular.
050: *
051: *              DIAG = 'N' or 'n'   A is not assumed to be unit
052: *                                  triangular.
053: *
054: *           Unchanged on exit.
055: *
056: *  N      - INTEGER.
057: *           On entry, N specifies the order of the matrix A.
058: *           N must be at least zero.
059: *           Unchanged on exit.
060: *
061: *  A      - REAL             array of DIMENSION ( LDA, n ).
062: *           Before entry with  UPLO = 'U' or 'u', the leading n by n
063: *           upper triangular part of the array A must contain the upper
064: *           triangular matrix and the strictly lower triangular part of
065: *           A is not referenced.
066: *           Before entry with UPLO = 'L' or 'l', the leading n by n
067: *           lower triangular part of the array A must contain the lower
068: *           triangular matrix and the strictly upper triangular part of
069: *           A is not referenced.
070: *           Note that when  DIAG = 'U' or 'u', the diagonal elements of
071: *           A are not referenced either, but are assumed to be unity.
072: *           Unchanged on exit.
073: *
074: *  LDA    - INTEGER.
075: *           On entry, LDA specifies the first dimension of A as declared
076: *           in the calling (sub) program. LDA must be at least
077: *           max( 1, n ).
078: *           Unchanged on exit.
079: *
080: *  X      - REAL             array of dimension at least
081: *           ( 1 + ( n - 1 )*abs( INCX ) ).
082: *           Before entry, the incremented array X must contain the n
083: *           element vector x. On exit, X is overwritten with the
084: *           tranformed vector x.
085: *
086: *  INCX   - INTEGER.
087: *           On entry, INCX specifies the increment for the elements of
088: *           X. INCX must not be zero.
089: *           Unchanged on exit.
090: *
091: *  Further Details
092: *  ===============
093: *
094: *  Level 2 Blas routine.
095: *
096: *  -- Written on 22-October-1986.
097: *     Jack Dongarra, Argonne National Lab.
098: *     Jeremy Du Croz, Nag Central Office.
099: *     Sven Hammarling, Nag Central Office.
100: *     Richard Hanson, Sandia National Labs.
101: *
102: *  =====================================================================
103: *
104: *     .. Parameters ..
105:       REAL ZERO
106:       PARAMETER (ZERO=0.0E+0)
107: *     ..
108: *     .. Local Scalars ..
109:       REAL TEMP
110:       INTEGER I,INFO,IX,J,JX,KX
111:       LOGICAL NOUNIT
112: *     ..
113: *     .. External Functions ..
114:       LOGICAL LSAME
115:       EXTERNAL LSAME
116: *     ..
117: *     .. External Subroutines ..
118:       EXTERNAL XERBLA
119: *     ..
120: *     .. Intrinsic Functions ..
121:       INTRINSIC MAX
122: *     ..
123: *
124: *     Test the input parameters.
125: *
126:       INFO = 0
127:       IF (.NOT.LSAME(UPLO,'U') .AND. .NOT.LSAME(UPLO,'L')) THEN
128:           INFO = 1
129:       ELSE IF (.NOT.LSAME(TRANS,'N') .AND. .NOT.LSAME(TRANS,'T') .AND.
130:      +         .NOT.LSAME(TRANS,'C')) THEN
131:           INFO = 2
132:       ELSE IF (.NOT.LSAME(DIAG,'U') .AND. .NOT.LSAME(DIAG,'N')) THEN
133:           INFO = 3
134:       ELSE IF (N.LT.0) THEN
135:           INFO = 4
136:       ELSE IF (LDA.LT.MAX(1,N)) THEN
137:           INFO = 6
138:       ELSE IF (INCX.EQ.0) THEN
139:           INFO = 8
140:       END IF
141:       IF (INFO.NE.0) THEN
142:           CALL XERBLA('STRMV ',INFO)
143:           RETURN
144:       END IF
145: *
146: *     Quick return if possible.
147: *
148:       IF (N.EQ.0) RETURN
149: *
150:       NOUNIT = LSAME(DIAG,'N')
151: *
152: *     Set up the start point in X if the increment is not unity. This
153: *     will be  ( N - 1 )*INCX  too small for descending loops.
154: *
155:       IF (INCX.LE.0) THEN
156:           KX = 1 - (N-1)*INCX
157:       ELSE IF (INCX.NE.1) THEN
158:           KX = 1
159:       END IF
160: *
161: *     Start the operations. In this version the elements of A are
162: *     accessed sequentially with one pass through A.
163: *
164:       IF (LSAME(TRANS,'N')) THEN
165: *
166: *        Form  x := A*x.
167: *
168:           IF (LSAME(UPLO,'U')) THEN
169:               IF (INCX.EQ.1) THEN
170:                   DO 20 J = 1,N
171:                       IF (X(J).NE.ZERO) THEN
172:                           TEMP = X(J)
173:                           DO 10 I = 1,J - 1
174:                               X(I) = X(I) + TEMP*A(I,J)
175:    10                     CONTINUE
176:                           IF (NOUNIT) X(J) = X(J)*A(J,J)
177:                       END IF
178:    20             CONTINUE
179:               ELSE
180:                   JX = KX
181:                   DO 40 J = 1,N
182:                       IF (X(JX).NE.ZERO) THEN
183:                           TEMP = X(JX)
184:                           IX = KX
185:                           DO 30 I = 1,J - 1
186:                               X(IX) = X(IX) + TEMP*A(I,J)
187:                               IX = IX + INCX
188:    30                     CONTINUE
189:                           IF (NOUNIT) X(JX) = X(JX)*A(J,J)
190:                       END IF
191:                       JX = JX + INCX
192:    40             CONTINUE
193:               END IF
194:           ELSE
195:               IF (INCX.EQ.1) THEN
196:                   DO 60 J = N,1,-1
197:                       IF (X(J).NE.ZERO) THEN
198:                           TEMP = X(J)
199:                           DO 50 I = N,J + 1,-1
200:                               X(I) = X(I) + TEMP*A(I,J)
201:    50                     CONTINUE
202:                           IF (NOUNIT) X(J) = X(J)*A(J,J)
203:                       END IF
204:    60             CONTINUE
205:               ELSE
206:                   KX = KX + (N-1)*INCX
207:                   JX = KX
208:                   DO 80 J = N,1,-1
209:                       IF (X(JX).NE.ZERO) THEN
210:                           TEMP = X(JX)
211:                           IX = KX
212:                           DO 70 I = N,J + 1,-1
213:                               X(IX) = X(IX) + TEMP*A(I,J)
214:                               IX = IX - INCX
215:    70                     CONTINUE
216:                           IF (NOUNIT) X(JX) = X(JX)*A(J,J)
217:                       END IF
218:                       JX = JX - INCX
219:    80             CONTINUE
220:               END IF
221:           END IF
222:       ELSE
223: *
224: *        Form  x := A'*x.
225: *
226:           IF (LSAME(UPLO,'U')) THEN
227:               IF (INCX.EQ.1) THEN
228:                   DO 100 J = N,1,-1
229:                       TEMP = X(J)
230:                       IF (NOUNIT) TEMP = TEMP*A(J,J)
231:                       DO 90 I = J - 1,1,-1
232:                           TEMP = TEMP + A(I,J)*X(I)
233:    90                 CONTINUE
234:                       X(J) = TEMP
235:   100             CONTINUE
236:               ELSE
237:                   JX = KX + (N-1)*INCX
238:                   DO 120 J = N,1,-1
239:                       TEMP = X(JX)
240:                       IX = JX
241:                       IF (NOUNIT) TEMP = TEMP*A(J,J)
242:                       DO 110 I = J - 1,1,-1
243:                           IX = IX - INCX
244:                           TEMP = TEMP + A(I,J)*X(IX)
245:   110                 CONTINUE
246:                       X(JX) = TEMP
247:                       JX = JX - INCX
248:   120             CONTINUE
249:               END IF
250:           ELSE
251:               IF (INCX.EQ.1) THEN
252:                   DO 140 J = 1,N
253:                       TEMP = X(J)
254:                       IF (NOUNIT) TEMP = TEMP*A(J,J)
255:                       DO 130 I = J + 1,N
256:                           TEMP = TEMP + A(I,J)*X(I)
257:   130                 CONTINUE
258:                       X(J) = TEMP
259:   140             CONTINUE
260:               ELSE
261:                   JX = KX
262:                   DO 160 J = 1,N
263:                       TEMP = X(JX)
264:                       IX = JX
265:                       IF (NOUNIT) TEMP = TEMP*A(J,J)
266:                       DO 150 I = J + 1,N
267:                           IX = IX + INCX
268:                           TEMP = TEMP + A(I,J)*X(IX)
269:   150                 CONTINUE
270:                       X(JX) = TEMP
271:                       JX = JX + INCX
272:   160             CONTINUE
273:               END IF
274:           END IF
275:       END IF
276: *
277:       RETURN
278: *
279: *     End of STRMV .
280: *
281:       END
282: