001:       SUBROUTINE SSYGS2( ITYPE, UPLO, N, A, LDA, B, LDB, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
005: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          UPLO
010:       INTEGER            INFO, ITYPE, LDA, LDB, N
011: *     ..
012: *     .. Array Arguments ..
013:       REAL               A( LDA, * ), B( LDB, * )
014: *     ..
015: *
016: *  Purpose
017: *  =======
018: *
019: *  SSYGS2 reduces a real symmetric-definite generalized eigenproblem
020: *  to standard form.
021: *
022: *  If ITYPE = 1, the problem is A*x = lambda*B*x,
023: *  and A is overwritten by inv(U')*A*inv(U) or inv(L)*A*inv(L')
024: *
025: *  If ITYPE = 2 or 3, the problem is A*B*x = lambda*x or
026: *  B*A*x = lambda*x, and A is overwritten by U*A*U` or L'*A*L.
027: *
028: *  B must have been previously factorized as U'*U or L*L' by SPOTRF.
029: *
030: *  Arguments
031: *  =========
032: *
033: *  ITYPE   (input) INTEGER
034: *          = 1: compute inv(U')*A*inv(U) or inv(L)*A*inv(L');
035: *          = 2 or 3: compute U*A*U' or L'*A*L.
036: *
037: *  UPLO    (input) CHARACTER*1
038: *          Specifies whether the upper or lower triangular part of the
039: *          symmetric matrix A is stored, and how B has been factorized.
040: *          = 'U':  Upper triangular
041: *          = 'L':  Lower triangular
042: *
043: *  N       (input) INTEGER
044: *          The order of the matrices A and B.  N >= 0.
045: *
046: *  A       (input/output) REAL array, dimension (LDA,N)
047: *          On entry, the symmetric matrix A.  If UPLO = 'U', the leading
048: *          n by n upper triangular part of A contains the upper
049: *          triangular part of the matrix A, and the strictly lower
050: *          triangular part of A is not referenced.  If UPLO = 'L', the
051: *          leading n by n lower triangular part of A contains the lower
052: *          triangular part of the matrix A, and the strictly upper
053: *          triangular part of A is not referenced.
054: *
055: *          On exit, if INFO = 0, the transformed matrix, stored in the
056: *          same format as A.
057: *
058: *  LDA     (input) INTEGER
059: *          The leading dimension of the array A.  LDA >= max(1,N).
060: *
061: *  B       (input) REAL array, dimension (LDB,N)
062: *          The triangular factor from the Cholesky factorization of B,
063: *          as returned by SPOTRF.
064: *
065: *  LDB     (input) INTEGER
066: *          The leading dimension of the array B.  LDB >= max(1,N).
067: *
068: *  INFO    (output) INTEGER
069: *          = 0:  successful exit.
070: *          < 0:  if INFO = -i, the i-th argument had an illegal value.
071: *
072: *  =====================================================================
073: *
074: *     .. Parameters ..
075:       REAL               ONE, HALF
076:       PARAMETER          ( ONE = 1.0, HALF = 0.5 )
077: *     ..
078: *     .. Local Scalars ..
079:       LOGICAL            UPPER
080:       INTEGER            K
081:       REAL               AKK, BKK, CT
082: *     ..
083: *     .. External Subroutines ..
084:       EXTERNAL           SAXPY, SSCAL, SSYR2, STRMV, STRSV, XERBLA
085: *     ..
086: *     .. Intrinsic Functions ..
087:       INTRINSIC          MAX
088: *     ..
089: *     .. External Functions ..
090:       LOGICAL            LSAME
091:       EXTERNAL           LSAME
092: *     ..
093: *     .. Executable Statements ..
094: *
095: *     Test the input parameters.
096: *
097:       INFO = 0
098:       UPPER = LSAME( UPLO, 'U' )
099:       IF( ITYPE.LT.1 .OR. ITYPE.GT.3 ) THEN
100:          INFO = -1
101:       ELSE IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
102:          INFO = -2
103:       ELSE IF( N.LT.0 ) THEN
104:          INFO = -3
105:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
106:          INFO = -5
107:       ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
108:          INFO = -7
109:       END IF
110:       IF( INFO.NE.0 ) THEN
111:          CALL XERBLA( 'SSYGS2', -INFO )
112:          RETURN
113:       END IF
114: *
115:       IF( ITYPE.EQ.1 ) THEN
116:          IF( UPPER ) THEN
117: *
118: *           Compute inv(U')*A*inv(U)
119: *
120:             DO 10 K = 1, N
121: *
122: *              Update the upper triangle of A(k:n,k:n)
123: *
124:                AKK = A( K, K )
125:                BKK = B( K, K )
126:                AKK = AKK / BKK**2
127:                A( K, K ) = AKK
128:                IF( K.LT.N ) THEN
129:                   CALL SSCAL( N-K, ONE / BKK, A( K, K+1 ), LDA )
130:                   CT = -HALF*AKK
131:                   CALL SAXPY( N-K, CT, B( K, K+1 ), LDB, A( K, K+1 ),
132:      $                        LDA )
133:                   CALL SSYR2( UPLO, N-K, -ONE, A( K, K+1 ), LDA,
134:      $                        B( K, K+1 ), LDB, A( K+1, K+1 ), LDA )
135:                   CALL SAXPY( N-K, CT, B( K, K+1 ), LDB, A( K, K+1 ),
136:      $                        LDA )
137:                   CALL STRSV( UPLO, 'Transpose', 'Non-unit', N-K,
138:      $                        B( K+1, K+1 ), LDB, A( K, K+1 ), LDA )
139:                END IF
140:    10       CONTINUE
141:          ELSE
142: *
143: *           Compute inv(L)*A*inv(L')
144: *
145:             DO 20 K = 1, N
146: *
147: *              Update the lower triangle of A(k:n,k:n)
148: *
149:                AKK = A( K, K )
150:                BKK = B( K, K )
151:                AKK = AKK / BKK**2
152:                A( K, K ) = AKK
153:                IF( K.LT.N ) THEN
154:                   CALL SSCAL( N-K, ONE / BKK, A( K+1, K ), 1 )
155:                   CT = -HALF*AKK
156:                   CALL SAXPY( N-K, CT, B( K+1, K ), 1, A( K+1, K ), 1 )
157:                   CALL SSYR2( UPLO, N-K, -ONE, A( K+1, K ), 1,
158:      $                        B( K+1, K ), 1, A( K+1, K+1 ), LDA )
159:                   CALL SAXPY( N-K, CT, B( K+1, K ), 1, A( K+1, K ), 1 )
160:                   CALL STRSV( UPLO, 'No transpose', 'Non-unit', N-K,
161:      $                        B( K+1, K+1 ), LDB, A( K+1, K ), 1 )
162:                END IF
163:    20       CONTINUE
164:          END IF
165:       ELSE
166:          IF( UPPER ) THEN
167: *
168: *           Compute U*A*U'
169: *
170:             DO 30 K = 1, N
171: *
172: *              Update the upper triangle of A(1:k,1:k)
173: *
174:                AKK = A( K, K )
175:                BKK = B( K, K )
176:                CALL STRMV( UPLO, 'No transpose', 'Non-unit', K-1, B,
177:      $                     LDB, A( 1, K ), 1 )
178:                CT = HALF*AKK
179:                CALL SAXPY( K-1, CT, B( 1, K ), 1, A( 1, K ), 1 )
180:                CALL SSYR2( UPLO, K-1, ONE, A( 1, K ), 1, B( 1, K ), 1,
181:      $                     A, LDA )
182:                CALL SAXPY( K-1, CT, B( 1, K ), 1, A( 1, K ), 1 )
183:                CALL SSCAL( K-1, BKK, A( 1, K ), 1 )
184:                A( K, K ) = AKK*BKK**2
185:    30       CONTINUE
186:          ELSE
187: *
188: *           Compute L'*A*L
189: *
190:             DO 40 K = 1, N
191: *
192: *              Update the lower triangle of A(1:k,1:k)
193: *
194:                AKK = A( K, K )
195:                BKK = B( K, K )
196:                CALL STRMV( UPLO, 'Transpose', 'Non-unit', K-1, B, LDB,
197:      $                     A( K, 1 ), LDA )
198:                CT = HALF*AKK
199:                CALL SAXPY( K-1, CT, B( K, 1 ), LDB, A( K, 1 ), LDA )
200:                CALL SSYR2( UPLO, K-1, ONE, A( K, 1 ), LDA, B( K, 1 ),
201:      $                     LDB, A, LDA )
202:                CALL SAXPY( K-1, CT, B( K, 1 ), LDB, A( K, 1 ), LDA )
203:                CALL SSCAL( K-1, BKK, A( K, 1 ), LDA )
204:                A( K, K ) = AKK*BKK**2
205:    40       CONTINUE
206:          END IF
207:       END IF
208:       RETURN
209: *
210: *     End of SSYGS2
211: *
212:       END
213: