001:       SUBROUTINE SPPCON( UPLO, N, AP, ANORM, RCOND, WORK, IWORK, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
005: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
006: *     November 2006
007: *
008: *     Modified to call SLACN2 in place of SLACON, 7 Feb 03, SJH.
009: *
010: *     .. Scalar Arguments ..
011:       CHARACTER          UPLO
012:       INTEGER            INFO, N
013:       REAL               ANORM, RCOND
014: *     ..
015: *     .. Array Arguments ..
016:       INTEGER            IWORK( * )
017:       REAL               AP( * ), WORK( * )
018: *     ..
019: *
020: *  Purpose
021: *  =======
022: *
023: *  SPPCON estimates the reciprocal of the condition number (in the
024: *  1-norm) of a real symmetric positive definite packed matrix using
025: *  the Cholesky factorization A = U**T*U or A = L*L**T computed by
026: *  SPPTRF.
027: *
028: *  An estimate is obtained for norm(inv(A)), and the reciprocal of the
029: *  condition number is computed as RCOND = 1 / (ANORM * norm(inv(A))).
030: *
031: *  Arguments
032: *  =========
033: *
034: *  UPLO    (input) CHARACTER*1
035: *          = 'U':  Upper triangle of A is stored;
036: *          = 'L':  Lower triangle of A is stored.
037: *
038: *  N       (input) INTEGER
039: *          The order of the matrix A.  N >= 0.
040: *
041: *  AP      (input) REAL array, dimension (N*(N+1)/2)
042: *          The triangular factor U or L from the Cholesky factorization
043: *          A = U**T*U or A = L*L**T, packed columnwise in a linear
044: *          array.  The j-th column of U or L is stored in the array AP
045: *          as follows:
046: *          if UPLO = 'U', AP(i + (j-1)*j/2) = U(i,j) for 1<=i<=j;
047: *          if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = L(i,j) for j<=i<=n.
048: *
049: *  ANORM   (input) REAL
050: *          The 1-norm (or infinity-norm) of the symmetric matrix A.
051: *
052: *  RCOND   (output) REAL
053: *          The reciprocal of the condition number of the matrix A,
054: *          computed as RCOND = 1/(ANORM * AINVNM), where AINVNM is an
055: *          estimate of the 1-norm of inv(A) computed in this routine.
056: *
057: *  WORK    (workspace) REAL array, dimension (3*N)
058: *
059: *  IWORK   (workspace) INTEGER array, dimension (N)
060: *
061: *  INFO    (output) INTEGER
062: *          = 0:  successful exit
063: *          < 0:  if INFO = -i, the i-th argument had an illegal value
064: *
065: *  =====================================================================
066: *
067: *     .. Parameters ..
068:       REAL               ONE, ZERO
069:       PARAMETER          ( ONE = 1.0E+0, ZERO = 0.0E+0 )
070: *     ..
071: *     .. Local Scalars ..
072:       LOGICAL            UPPER
073:       CHARACTER          NORMIN
074:       INTEGER            IX, KASE
075:       REAL               AINVNM, SCALE, SCALEL, SCALEU, SMLNUM
076: *     ..
077: *     .. Local Arrays ..
078:       INTEGER            ISAVE( 3 )
079: *     ..
080: *     .. External Functions ..
081:       LOGICAL            LSAME
082:       INTEGER            ISAMAX
083:       REAL               SLAMCH
084:       EXTERNAL           LSAME, ISAMAX, SLAMCH
085: *     ..
086: *     .. External Subroutines ..
087:       EXTERNAL           SLACN2, SLATPS, SRSCL, XERBLA
088: *     ..
089: *     .. Intrinsic Functions ..
090:       INTRINSIC          ABS
091: *     ..
092: *     .. Executable Statements ..
093: *
094: *     Test the input parameters.
095: *
096:       INFO = 0
097:       UPPER = LSAME( UPLO, 'U' )
098:       IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
099:          INFO = -1
100:       ELSE IF( N.LT.0 ) THEN
101:          INFO = -2
102:       ELSE IF( ANORM.LT.ZERO ) THEN
103:          INFO = -4
104:       END IF
105:       IF( INFO.NE.0 ) THEN
106:          CALL XERBLA( 'SPPCON', -INFO )
107:          RETURN
108:       END IF
109: *
110: *     Quick return if possible
111: *
112:       RCOND = ZERO
113:       IF( N.EQ.0 ) THEN
114:          RCOND = ONE
115:          RETURN
116:       ELSE IF( ANORM.EQ.ZERO ) THEN
117:          RETURN
118:       END IF
119: *
120:       SMLNUM = SLAMCH( 'Safe minimum' )
121: *
122: *     Estimate the 1-norm of the inverse.
123: *
124:       KASE = 0
125:       NORMIN = 'N'
126:    10 CONTINUE
127:       CALL SLACN2( N, WORK( N+1 ), WORK, IWORK, AINVNM, KASE, ISAVE )
128:       IF( KASE.NE.0 ) THEN
129:          IF( UPPER ) THEN
130: *
131: *           Multiply by inv(U').
132: *
133:             CALL SLATPS( 'Upper', 'Transpose', 'Non-unit', NORMIN, N,
134:      $                   AP, WORK, SCALEL, WORK( 2*N+1 ), INFO )
135:             NORMIN = 'Y'
136: *
137: *           Multiply by inv(U).
138: *
139:             CALL SLATPS( 'Upper', 'No transpose', 'Non-unit', NORMIN, N,
140:      $                   AP, WORK, SCALEU, WORK( 2*N+1 ), INFO )
141:          ELSE
142: *
143: *           Multiply by inv(L).
144: *
145:             CALL SLATPS( 'Lower', 'No transpose', 'Non-unit', NORMIN, N,
146:      $                   AP, WORK, SCALEL, WORK( 2*N+1 ), INFO )
147:             NORMIN = 'Y'
148: *
149: *           Multiply by inv(L').
150: *
151:             CALL SLATPS( 'Lower', 'Transpose', 'Non-unit', NORMIN, N,
152:      $                   AP, WORK, SCALEU, WORK( 2*N+1 ), INFO )
153:          END IF
154: *
155: *        Multiply by 1/SCALE if doing so will not cause overflow.
156: *
157:          SCALE = SCALEL*SCALEU
158:          IF( SCALE.NE.ONE ) THEN
159:             IX = ISAMAX( N, WORK, 1 )
160:             IF( SCALE.LT.ABS( WORK( IX ) )*SMLNUM .OR. SCALE.EQ.ZERO )
161:      $         GO TO 20
162:             CALL SRSCL( N, SCALE, WORK, 1 )
163:          END IF
164:          GO TO 10
165:       END IF
166: *
167: *     Compute the estimate of the reciprocal condition number.
168: *
169:       IF( AINVNM.NE.ZERO )
170:      $   RCOND = ( ONE / AINVNM ) / ANORM
171: *
172:    20 CONTINUE
173:       RETURN
174: *
175: *     End of SPPCON
176: *
177:       END
178: