001:       SUBROUTINE SORMHR( SIDE, TRANS, M, N, ILO, IHI, A, LDA, TAU, C,
002:      $                   LDC, WORK, LWORK, INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
006: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
007: *     November 2006
008: *
009: *     .. Scalar Arguments ..
010:       CHARACTER          SIDE, TRANS
011:       INTEGER            IHI, ILO, INFO, LDA, LDC, LWORK, M, N
012: *     ..
013: *     .. Array Arguments ..
014:       REAL               A( LDA, * ), C( LDC, * ), TAU( * ),
015:      $                   WORK( * )
016: *     ..
017: *
018: *  Purpose
019: *  =======
020: *
021: *  SORMHR overwrites the general real M-by-N matrix C with
022: *
023: *                  SIDE = 'L'     SIDE = 'R'
024: *  TRANS = 'N':      Q * C          C * Q
025: *  TRANS = 'T':      Q**T * C       C * Q**T
026: *
027: *  where Q is a real orthogonal matrix of order nq, with nq = m if
028: *  SIDE = 'L' and nq = n if SIDE = 'R'. Q is defined as the product of
029: *  IHI-ILO elementary reflectors, as returned by SGEHRD:
030: *
031: *  Q = H(ilo) H(ilo+1) . . . H(ihi-1).
032: *
033: *  Arguments
034: *  =========
035: *
036: *  SIDE    (input) CHARACTER*1
037: *          = 'L': apply Q or Q**T from the Left;
038: *          = 'R': apply Q or Q**T from the Right.
039: *
040: *  TRANS   (input) CHARACTER*1
041: *          = 'N':  No transpose, apply Q;
042: *          = 'T':  Transpose, apply Q**T.
043: *
044: *  M       (input) INTEGER
045: *          The number of rows of the matrix C. M >= 0.
046: *
047: *  N       (input) INTEGER
048: *          The number of columns of the matrix C. N >= 0.
049: *
050: *  ILO     (input) INTEGER
051: *  IHI     (input) INTEGER
052: *          ILO and IHI must have the same values as in the previous call
053: *          of SGEHRD. Q is equal to the unit matrix except in the
054: *          submatrix Q(ilo+1:ihi,ilo+1:ihi).
055: *          If SIDE = 'L', then 1 <= ILO <= IHI <= M, if M > 0, and
056: *          ILO = 1 and IHI = 0, if M = 0;
057: *          if SIDE = 'R', then 1 <= ILO <= IHI <= N, if N > 0, and
058: *          ILO = 1 and IHI = 0, if N = 0.
059: *
060: *  A       (input) REAL array, dimension
061: *                               (LDA,M) if SIDE = 'L'
062: *                               (LDA,N) if SIDE = 'R'
063: *          The vectors which define the elementary reflectors, as
064: *          returned by SGEHRD.
065: *
066: *  LDA     (input) INTEGER
067: *          The leading dimension of the array A.
068: *          LDA >= max(1,M) if SIDE = 'L'; LDA >= max(1,N) if SIDE = 'R'.
069: *
070: *  TAU     (input) REAL array, dimension
071: *                               (M-1) if SIDE = 'L'
072: *                               (N-1) if SIDE = 'R'
073: *          TAU(i) must contain the scalar factor of the elementary
074: *          reflector H(i), as returned by SGEHRD.
075: *
076: *  C       (input/output) REAL array, dimension (LDC,N)
077: *          On entry, the M-by-N matrix C.
078: *          On exit, C is overwritten by Q*C or Q**T*C or C*Q**T or C*Q.
079: *
080: *  LDC     (input) INTEGER
081: *          The leading dimension of the array C. LDC >= max(1,M).
082: *
083: *  WORK    (workspace/output) REAL array, dimension (MAX(1,LWORK))
084: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
085: *
086: *  LWORK   (input) INTEGER
087: *          The dimension of the array WORK.
088: *          If SIDE = 'L', LWORK >= max(1,N);
089: *          if SIDE = 'R', LWORK >= max(1,M).
090: *          For optimum performance LWORK >= N*NB if SIDE = 'L', and
091: *          LWORK >= M*NB if SIDE = 'R', where NB is the optimal
092: *          blocksize.
093: *
094: *          If LWORK = -1, then a workspace query is assumed; the routine
095: *          only calculates the optimal size of the WORK array, returns
096: *          this value as the first entry of the WORK array, and no error
097: *          message related to LWORK is issued by XERBLA.
098: *
099: *  INFO    (output) INTEGER
100: *          = 0:  successful exit
101: *          < 0:  if INFO = -i, the i-th argument had an illegal value
102: *
103: *  =====================================================================
104: *
105: *     .. Local Scalars ..
106:       LOGICAL            LEFT, LQUERY
107:       INTEGER            I1, I2, IINFO, LWKOPT, MI, NB, NH, NI, NQ, NW
108: *     ..
109: *     .. External Functions ..
110:       LOGICAL            LSAME
111:       INTEGER            ILAENV
112:       EXTERNAL           ILAENV, LSAME
113: *     ..
114: *     .. External Subroutines ..
115:       EXTERNAL           SORMQR, XERBLA
116: *     ..
117: *     .. Intrinsic Functions ..
118:       INTRINSIC          MAX, MIN
119: *     ..
120: *     .. Executable Statements ..
121: *
122: *     Test the input arguments
123: *
124:       INFO = 0
125:       NH = IHI - ILO
126:       LEFT = LSAME( SIDE, 'L' )
127:       LQUERY = ( LWORK.EQ.-1 )
128: *
129: *     NQ is the order of Q and NW is the minimum dimension of WORK
130: *
131:       IF( LEFT ) THEN
132:          NQ = M
133:          NW = N
134:       ELSE
135:          NQ = N
136:          NW = M
137:       END IF
138:       IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
139:          INFO = -1
140:       ELSE IF( .NOT.LSAME( TRANS, 'N' ) .AND. .NOT.LSAME( TRANS, 'T' ) )
141:      $          THEN
142:          INFO = -2
143:       ELSE IF( M.LT.0 ) THEN
144:          INFO = -3
145:       ELSE IF( N.LT.0 ) THEN
146:          INFO = -4
147:       ELSE IF( ILO.LT.1 .OR. ILO.GT.MAX( 1, NQ ) ) THEN
148:          INFO = -5
149:       ELSE IF( IHI.LT.MIN( ILO, NQ ) .OR. IHI.GT.NQ ) THEN
150:          INFO = -6
151:       ELSE IF( LDA.LT.MAX( 1, NQ ) ) THEN
152:          INFO = -8
153:       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
154:          INFO = -11
155:       ELSE IF( LWORK.LT.MAX( 1, NW ) .AND. .NOT.LQUERY ) THEN
156:          INFO = -13
157:       END IF
158: *
159:       IF( INFO.EQ.0 ) THEN
160:          IF( LEFT ) THEN
161:             NB = ILAENV( 1, 'SORMQR', SIDE // TRANS, NH, N, NH, -1 )
162:          ELSE
163:             NB = ILAENV( 1, 'SORMQR', SIDE // TRANS, M, NH, NH, -1 ) 
164:          END IF
165:          LWKOPT = MAX( 1, NW )*NB
166:          WORK( 1 ) = LWKOPT
167:       END IF
168: *
169:       IF( INFO.NE.0 ) THEN
170:          CALL XERBLA( 'SORMHR', -INFO )
171:          RETURN
172:       ELSE IF( LQUERY ) THEN
173:          RETURN
174:       END IF
175: *
176: *     Quick return if possible
177: *
178:       IF( M.EQ.0 .OR. N.EQ.0 .OR. NH.EQ.0 ) THEN
179:          WORK( 1 ) = 1
180:          RETURN
181:       END IF
182: *
183:       IF( LEFT ) THEN
184:          MI = NH
185:          NI = N
186:          I1 = ILO + 1
187:          I2 = 1
188:       ELSE
189:          MI = M
190:          NI = NH
191:          I1 = 1
192:          I2 = ILO + 1
193:       END IF
194: *
195:       CALL SORMQR( SIDE, TRANS, MI, NI, NH, A( ILO+1, ILO ), LDA,
196:      $             TAU( ILO ), C( I1, I2 ), LDC, WORK, LWORK, IINFO )
197: *
198:       WORK( 1 ) = LWKOPT
199:       RETURN
200: *
201: *     End of SORMHR
202: *
203:       END
204: