001:       SUBROUTINE SORGTR( UPLO, N, A, LDA, TAU, WORK, LWORK, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
005: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          UPLO
010:       INTEGER            INFO, LDA, LWORK, N
011: *     ..
012: *     .. Array Arguments ..
013:       REAL               A( LDA, * ), TAU( * ), WORK( * )
014: *     ..
015: *
016: *  Purpose
017: *  =======
018: *
019: *  SORGTR generates a real orthogonal matrix Q which is defined as the
020: *  product of n-1 elementary reflectors of order N, as returned by
021: *  SSYTRD:
022: *
023: *  if UPLO = 'U', Q = H(n-1) . . . H(2) H(1),
024: *
025: *  if UPLO = 'L', Q = H(1) H(2) . . . H(n-1).
026: *
027: *  Arguments
028: *  =========
029: *
030: *  UPLO    (input) CHARACTER*1
031: *          = 'U': Upper triangle of A contains elementary reflectors
032: *                 from SSYTRD;
033: *          = 'L': Lower triangle of A contains elementary reflectors
034: *                 from SSYTRD.
035: *
036: *  N       (input) INTEGER
037: *          The order of the matrix Q. N >= 0.
038: *
039: *  A       (input/output) REAL array, dimension (LDA,N)
040: *          On entry, the vectors which define the elementary reflectors,
041: *          as returned by SSYTRD.
042: *          On exit, the N-by-N orthogonal matrix Q.
043: *
044: *  LDA     (input) INTEGER
045: *          The leading dimension of the array A. LDA >= max(1,N).
046: *
047: *  TAU     (input) REAL array, dimension (N-1)
048: *          TAU(i) must contain the scalar factor of the elementary
049: *          reflector H(i), as returned by SSYTRD.
050: *
051: *  WORK    (workspace/output) REAL array, dimension (MAX(1,LWORK))
052: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
053: *
054: *  LWORK   (input) INTEGER
055: *          The dimension of the array WORK. LWORK >= max(1,N-1).
056: *          For optimum performance LWORK >= (N-1)*NB, where NB is
057: *          the optimal blocksize.
058: *
059: *          If LWORK = -1, then a workspace query is assumed; the routine
060: *          only calculates the optimal size of the WORK array, returns
061: *          this value as the first entry of the WORK array, and no error
062: *          message related to LWORK is issued by XERBLA.
063: *
064: *  INFO    (output) INTEGER
065: *          = 0:  successful exit
066: *          < 0:  if INFO = -i, the i-th argument had an illegal value
067: *
068: *  =====================================================================
069: *
070: *     .. Parameters ..
071:       REAL               ZERO, ONE
072:       PARAMETER          ( ZERO = 0.0E+0, ONE = 1.0E+0 )
073: *     ..
074: *     .. Local Scalars ..
075:       LOGICAL            LQUERY, UPPER
076:       INTEGER            I, IINFO, J, LWKOPT, NB
077: *     ..
078: *     .. External Functions ..
079:       LOGICAL            LSAME
080:       INTEGER            ILAENV
081:       EXTERNAL           ILAENV, LSAME
082: *     ..
083: *     .. External Subroutines ..
084:       EXTERNAL           SORGQL, SORGQR, XERBLA
085: *     ..
086: *     .. Intrinsic Functions ..
087:       INTRINSIC          MAX
088: *     ..
089: *     .. Executable Statements ..
090: *
091: *     Test the input arguments
092: *
093:       INFO = 0
094:       LQUERY = ( LWORK.EQ.-1 )
095:       UPPER = LSAME( UPLO, 'U' )
096:       IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
097:          INFO = -1
098:       ELSE IF( N.LT.0 ) THEN
099:          INFO = -2
100:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
101:          INFO = -4
102:       ELSE IF( LWORK.LT.MAX( 1, N-1 ) .AND. .NOT.LQUERY ) THEN
103:          INFO = -7
104:       END IF
105: *
106:       IF( INFO.EQ.0 ) THEN
107:          IF ( UPPER ) THEN
108:            NB = ILAENV( 1, 'SORGQL', ' ', N-1, N-1, N-1, -1 )
109:          ELSE
110:            NB = ILAENV( 1, 'SORGQR', ' ', N-1, N-1, N-1, -1 )
111:          END IF
112:          LWKOPT = MAX( 1, N-1 )*NB
113:          WORK( 1 ) = LWKOPT
114:       END IF
115: *    
116:       IF( INFO.NE.0 ) THEN
117:          CALL XERBLA( 'SORGTR', -INFO )
118:          RETURN
119:       ELSE IF( LQUERY ) THEN
120:          RETURN
121:       END IF
122: *
123: *     Quick return if possible
124: *
125:       IF( N.EQ.0 ) THEN
126:          WORK( 1 ) = 1
127:          RETURN
128:       END IF
129: *
130:       IF( UPPER ) THEN
131: *
132: *        Q was determined by a call to SSYTRD with UPLO = 'U'
133: *
134: *        Shift the vectors which define the elementary reflectors one
135: *        column to the left, and set the last row and column of Q to
136: *        those of the unit matrix
137: *
138:          DO 20 J = 1, N - 1
139:             DO 10 I = 1, J - 1
140:                A( I, J ) = A( I, J+1 )
141:    10       CONTINUE
142:             A( N, J ) = ZERO
143:    20    CONTINUE
144:          DO 30 I = 1, N - 1
145:             A( I, N ) = ZERO
146:    30    CONTINUE
147:          A( N, N ) = ONE
148: *
149: *        Generate Q(1:n-1,1:n-1)
150: *
151:          CALL SORGQL( N-1, N-1, N-1, A, LDA, TAU, WORK, LWORK, IINFO )
152: *
153:       ELSE
154: *
155: *        Q was determined by a call to SSYTRD with UPLO = 'L'.
156: *
157: *        Shift the vectors which define the elementary reflectors one
158: *        column to the right, and set the first row and column of Q to
159: *        those of the unit matrix
160: *
161:          DO 50 J = N, 2, -1
162:             A( 1, J ) = ZERO
163:             DO 40 I = J + 1, N
164:                A( I, J ) = A( I, J-1 )
165:    40       CONTINUE
166:    50    CONTINUE
167:          A( 1, 1 ) = ONE
168:          DO 60 I = 2, N
169:             A( I, 1 ) = ZERO
170:    60    CONTINUE
171:          IF( N.GT.1 ) THEN
172: *
173: *           Generate Q(2:n,2:n)
174: *
175:             CALL SORGQR( N-1, N-1, N-1, A( 2, 2 ), LDA, TAU, WORK,
176:      $                   LWORK, IINFO )
177:          END IF
178:       END IF
179:       WORK( 1 ) = LWKOPT
180:       RETURN
181: *
182: *     End of SORGTR
183: *
184:       END
185: