001:       SUBROUTINE SLACON( N, V, X, ISGN, EST, KASE )
002: *
003: *  -- LAPACK auxiliary routine (version 3.2) --
004: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
005: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       INTEGER            KASE, N
010:       REAL               EST
011: *     ..
012: *     .. Array Arguments ..
013:       INTEGER            ISGN( * )
014:       REAL               V( * ), X( * )
015: *     ..
016: *
017: *  Purpose
018: *  =======
019: *
020: *  SLACON estimates the 1-norm of a square, real matrix A.
021: *  Reverse communication is used for evaluating matrix-vector products.
022: *
023: *  Arguments
024: *  =========
025: *
026: *  N      (input) INTEGER
027: *         The order of the matrix.  N >= 1.
028: *
029: *  V      (workspace) REAL array, dimension (N)
030: *         On the final return, V = A*W,  where  EST = norm(V)/norm(W)
031: *         (W is not returned).
032: *
033: *  X      (input/output) REAL array, dimension (N)
034: *         On an intermediate return, X should be overwritten by
035: *               A * X,   if KASE=1,
036: *               A' * X,  if KASE=2,
037: *         and SLACON must be re-called with all the other parameters
038: *         unchanged.
039: *
040: *  ISGN   (workspace) INTEGER array, dimension (N)
041: *
042: *  EST    (input/output) REAL
043: *         On entry with KASE = 1 or 2 and JUMP = 3, EST should be
044: *         unchanged from the previous call to SLACON.
045: *         On exit, EST is an estimate (a lower bound) for norm(A). 
046: *
047: *  KASE   (input/output) INTEGER
048: *         On the initial call to SLACON, KASE should be 0.
049: *         On an intermediate return, KASE will be 1 or 2, indicating
050: *         whether X should be overwritten by A * X  or A' * X.
051: *         On the final return from SLACON, KASE will again be 0.
052: *
053: *  Further Details
054: *  ======= =======
055: *
056: *  Contributed by Nick Higham, University of Manchester.
057: *  Originally named SONEST, dated March 16, 1988.
058: *
059: *  Reference: N.J. Higham, "FORTRAN codes for estimating the one-norm of
060: *  a real or complex matrix, with applications to condition estimation",
061: *  ACM Trans. Math. Soft., vol. 14, no. 4, pp. 381-396, December 1988.
062: *
063: *  =====================================================================
064: *
065: *     .. Parameters ..
066:       INTEGER            ITMAX
067:       PARAMETER          ( ITMAX = 5 )
068:       REAL               ZERO, ONE, TWO
069:       PARAMETER          ( ZERO = 0.0E+0, ONE = 1.0E+0, TWO = 2.0E+0 )
070: *     ..
071: *     .. Local Scalars ..
072:       INTEGER            I, ITER, J, JLAST, JUMP
073:       REAL               ALTSGN, ESTOLD, TEMP
074: *     ..
075: *     .. External Functions ..
076:       INTEGER            ISAMAX
077:       REAL               SASUM
078:       EXTERNAL           ISAMAX, SASUM
079: *     ..
080: *     .. External Subroutines ..
081:       EXTERNAL           SCOPY
082: *     ..
083: *     .. Intrinsic Functions ..
084:       INTRINSIC          ABS, NINT, REAL, SIGN
085: *     ..
086: *     .. Save statement ..
087:       SAVE
088: *     ..
089: *     .. Executable Statements ..
090: *
091:       IF( KASE.EQ.0 ) THEN
092:          DO 10 I = 1, N
093:             X( I ) = ONE / REAL( N )
094:    10    CONTINUE
095:          KASE = 1
096:          JUMP = 1
097:          RETURN
098:       END IF
099: *
100:       GO TO ( 20, 40, 70, 110, 140 )JUMP
101: *
102: *     ................ ENTRY   (JUMP = 1)
103: *     FIRST ITERATION.  X HAS BEEN OVERWRITTEN BY A*X.
104: *
105:    20 CONTINUE
106:       IF( N.EQ.1 ) THEN
107:          V( 1 ) = X( 1 )
108:          EST = ABS( V( 1 ) )
109: *        ... QUIT
110:          GO TO 150
111:       END IF
112:       EST = SASUM( N, X, 1 )
113: *
114:       DO 30 I = 1, N
115:          X( I ) = SIGN( ONE, X( I ) )
116:          ISGN( I ) = NINT( X( I ) )
117:    30 CONTINUE
118:       KASE = 2
119:       JUMP = 2
120:       RETURN
121: *
122: *     ................ ENTRY   (JUMP = 2)
123: *     FIRST ITERATION.  X HAS BEEN OVERWRITTEN BY TRANSPOSE(A)*X.
124: *
125:    40 CONTINUE
126:       J = ISAMAX( N, X, 1 )
127:       ITER = 2
128: *
129: *     MAIN LOOP - ITERATIONS 2,3,...,ITMAX.
130: *
131:    50 CONTINUE
132:       DO 60 I = 1, N
133:          X( I ) = ZERO
134:    60 CONTINUE
135:       X( J ) = ONE
136:       KASE = 1
137:       JUMP = 3
138:       RETURN
139: *
140: *     ................ ENTRY   (JUMP = 3)
141: *     X HAS BEEN OVERWRITTEN BY A*X.
142: *
143:    70 CONTINUE
144:       CALL SCOPY( N, X, 1, V, 1 )
145:       ESTOLD = EST
146:       EST = SASUM( N, V, 1 )
147:       DO 80 I = 1, N
148:          IF( NINT( SIGN( ONE, X( I ) ) ).NE.ISGN( I ) )
149:      $      GO TO 90
150:    80 CONTINUE
151: *     REPEATED SIGN VECTOR DETECTED, HENCE ALGORITHM HAS CONVERGED.
152:       GO TO 120
153: *
154:    90 CONTINUE
155: *     TEST FOR CYCLING.
156:       IF( EST.LE.ESTOLD )
157:      $   GO TO 120
158: *
159:       DO 100 I = 1, N
160:          X( I ) = SIGN( ONE, X( I ) )
161:          ISGN( I ) = NINT( X( I ) )
162:   100 CONTINUE
163:       KASE = 2
164:       JUMP = 4
165:       RETURN
166: *
167: *     ................ ENTRY   (JUMP = 4)
168: *     X HAS BEEN OVERWRITTEN BY TRANSPOSE(A)*X.
169: *
170:   110 CONTINUE
171:       JLAST = J
172:       J = ISAMAX( N, X, 1 )
173:       IF( ( X( JLAST ).NE.ABS( X( J ) ) ) .AND. ( ITER.LT.ITMAX ) ) THEN
174:          ITER = ITER + 1
175:          GO TO 50
176:       END IF
177: *
178: *     ITERATION COMPLETE.  FINAL STAGE.
179: *
180:   120 CONTINUE
181:       ALTSGN = ONE
182:       DO 130 I = 1, N
183:          X( I ) = ALTSGN*( ONE+REAL( I-1 ) / REAL( N-1 ) )
184:          ALTSGN = -ALTSGN
185:   130 CONTINUE
186:       KASE = 1
187:       JUMP = 5
188:       RETURN
189: *
190: *     ................ ENTRY   (JUMP = 5)
191: *     X HAS BEEN OVERWRITTEN BY A*X.
192: *
193:   140 CONTINUE
194:       TEMP = TWO*( SASUM( N, X, 1 ) / REAL( 3*N ) )
195:       IF( TEMP.GT.EST ) THEN
196:          CALL SCOPY( N, X, 1, V, 1 )
197:          EST = TEMP
198:       END IF
199: *
200:   150 CONTINUE
201:       KASE = 0
202:       RETURN
203: *
204: *     End of SLACON
205: *
206:       END
207: