001:       REAL FUNCTION SLA_GERCOND ( TRANS, N, A, LDA, AF, LDAF, IPIV,
002:      $                            CMODE, C, INFO, WORK, IWORK )
003: *
004: *     -- LAPACK routine (version 3.2.1)                                 --
005: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
006: *     -- Jason Riedy of Univ. of California Berkeley.                 --
007: *     -- April 2009                                                   --
008: *
009: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
010: *     -- Univ. of California Berkeley and NAG Ltd.                    --
011: *
012:       IMPLICIT NONE
013: *     ..
014: *     .. Scalar Arguments ..
015:       CHARACTER          TRANS
016:       INTEGER            N, LDA, LDAF, INFO, CMODE
017: *     ..
018: *     .. Array Arguments ..
019:       INTEGER            IPIV( * ), IWORK( * )
020:       REAL               A( LDA, * ), AF( LDAF, * ), WORK( * ),
021:      $                   C( * )
022: *    ..
023: *
024: *  Purpose
025: *  =======
026: *
027: *     SLA_GERCOND estimates the Skeel condition number of op(A) * op2(C)
028: *     where op2 is determined by CMODE as follows
029: *     CMODE =  1    op2(C) = C
030: *     CMODE =  0    op2(C) = I
031: *     CMODE = -1    op2(C) = inv(C)
032: *     The Skeel condition number cond(A) = norminf( |inv(A)||A| )
033: *     is computed by computing scaling factors R such that
034: *     diag(R)*A*op2(C) is row equilibrated and computing the standard
035: *     infinity-norm condition number.
036: *
037: *  Arguments
038: *  ==========
039: *
040: *     TRANS   (input) CHARACTER*1
041: *     Specifies the form of the system of equations:
042: *       = 'N':  A * X = B     (No transpose)
043: *       = 'T':  A**T * X = B  (Transpose)
044: *       = 'C':  A**H * X = B  (Conjugate Transpose = Transpose)
045: *
046: *     N       (input) INTEGER
047: *     The number of linear equations, i.e., the order of the
048: *     matrix A.  N >= 0.
049: *
050: *     A       (input) REAL array, dimension (LDA,N)
051: *     On entry, the N-by-N matrix A.
052: *
053: *     LDA     (input) INTEGER
054: *     The leading dimension of the array A.  LDA >= max(1,N).
055: *
056: *     AF      (input) REAL array, dimension (LDAF,N)
057: *     The factors L and U from the factorization
058: *     A = P*L*U as computed by SGETRF.
059: *
060: *     LDAF    (input) INTEGER
061: *     The leading dimension of the array AF.  LDAF >= max(1,N).
062: *
063: *     IPIV    (input) INTEGER array, dimension (N)
064: *     The pivot indices from the factorization A = P*L*U
065: *     as computed by SGETRF; row i of the matrix was interchanged
066: *     with row IPIV(i).
067: *
068: *     CMODE   (input) INTEGER
069: *     Determines op2(C) in the formula op(A) * op2(C) as follows:
070: *     CMODE =  1    op2(C) = C
071: *     CMODE =  0    op2(C) = I
072: *     CMODE = -1    op2(C) = inv(C)
073: *
074: *     C       (input) REAL array, dimension (N)
075: *     The vector C in the formula op(A) * op2(C).
076: *
077: *     INFO    (output) INTEGER
078: *       = 0:  Successful exit.
079: *     i > 0:  The ith argument is invalid.
080: *
081: *     WORK    (input) REAL array, dimension (3*N).
082: *     Workspace.
083: *
084: *     IWORK   (input) INTEGER array, dimension (N).
085: *     Workspace.2
086: *
087: *  =====================================================================
088: *
089: *     .. Local Scalars ..
090:       LOGICAL            NOTRANS
091:       INTEGER            KASE, I, J
092:       REAL               AINVNM, TMP
093: *     ..
094: *     .. Local Arrays ..
095:       INTEGER            ISAVE( 3 )
096: *     ..
097: *     .. External Functions ..
098:       LOGICAL            LSAME
099:       EXTERNAL           LSAME
100: *     ..
101: *     .. External Subroutines ..
102:       EXTERNAL           SLACN2, SGETRS, XERBLA
103: *     ..
104: *     .. Intrinsic Functions ..
105:       INTRINSIC          ABS, MAX
106: *     ..
107: *     .. Executable Statements ..
108: *
109:       SLA_GERCOND = 0.0
110: *
111:       INFO = 0
112:       NOTRANS = LSAME( TRANS, 'N' )
113:       IF ( .NOT. NOTRANS .AND. .NOT. LSAME(TRANS, 'T')
114:      $     .AND. .NOT. LSAME(TRANS, 'C') ) THEN
115:          INFO = -1
116:       ELSE IF( N.LT.0 ) THEN
117:          INFO = -2
118:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
119:          INFO = -4
120:       ELSE IF( LDAF.LT.MAX( 1, N ) ) THEN
121:          INFO = -6
122:       END IF
123:       IF( INFO.NE.0 ) THEN
124:          CALL XERBLA( 'SLA_GERCOND', -INFO )
125:          RETURN
126:       END IF
127:       IF( N.EQ.0 ) THEN
128:          SLA_GERCOND = 1.0
129:          RETURN
130:       END IF
131: *
132: *     Compute the equilibration matrix R such that
133: *     inv(R)*A*C has unit 1-norm.
134: *
135:       IF (NOTRANS) THEN
136:          DO I = 1, N
137:             TMP = 0.0
138:             IF ( CMODE .EQ. 1 ) THEN
139:                DO J = 1, N
140:                   TMP = TMP + ABS( A( I, J ) * C( J ) )
141:                END DO
142:             ELSE IF ( CMODE .EQ. 0 ) THEN
143:                DO J = 1, N
144:                   TMP = TMP + ABS( A( I, J ) )
145:                END DO
146:             ELSE
147:                DO J = 1, N
148:                   TMP = TMP + ABS( A( I, J ) / C( J ) )
149:                END DO
150:             END IF
151:             WORK( 2*N+I ) = TMP
152:          END DO
153:       ELSE
154:          DO I = 1, N
155:             TMP = 0.0
156:             IF ( CMODE .EQ. 1 ) THEN
157:                DO J = 1, N
158:                   TMP = TMP + ABS( A( J, I ) * C( J ) )
159:                END DO
160:             ELSE IF ( CMODE .EQ. 0 ) THEN
161:                DO J = 1, N
162:                   TMP = TMP + ABS( A( J, I ) )
163:                END DO
164:             ELSE
165:                DO J = 1, N
166:                   TMP = TMP + ABS( A( J, I ) / C( J ) )
167:                END DO
168:             END IF
169:             WORK( 2*N+I ) = TMP
170:          END DO
171:       END IF
172: *
173: *     Estimate the norm of inv(op(A)).
174: *
175:       AINVNM = 0.0
176: 
177:       KASE = 0
178:    10 CONTINUE
179:       CALL SLACN2( N, WORK( N+1 ), WORK, IWORK, AINVNM, KASE, ISAVE )
180:       IF( KASE.NE.0 ) THEN
181:          IF( KASE.EQ.2 ) THEN
182: *
183: *           Multiply by R.
184: *
185:             DO I = 1, N
186:                WORK(I) = WORK(I) * WORK(2*N+I)
187:             END DO
188: 
189:             IF (NOTRANS) THEN
190:                CALL SGETRS( 'No transpose', N, 1, AF, LDAF, IPIV,
191:      $            WORK, N, INFO )
192:             ELSE
193:                CALL SGETRS( 'Transpose', N, 1, AF, LDAF, IPIV,
194:      $            WORK, N, INFO )
195:             END IF
196: *
197: *           Multiply by inv(C).
198: *
199:             IF ( CMODE .EQ. 1 ) THEN
200:                DO I = 1, N
201:                   WORK( I ) = WORK( I ) / C( I )
202:                END DO
203:             ELSE IF ( CMODE .EQ. -1 ) THEN
204:                DO I = 1, N
205:                   WORK( I ) = WORK( I ) * C( I )
206:                END DO
207:             END IF
208:          ELSE
209: *
210: *           Multiply by inv(C').
211: *
212:             IF ( CMODE .EQ. 1 ) THEN
213:                DO I = 1, N
214:                   WORK( I ) = WORK( I ) / C( I )
215:                END DO
216:             ELSE IF ( CMODE .EQ. -1 ) THEN
217:                DO I = 1, N
218:                   WORK( I ) = WORK( I ) * C( I )
219:                END DO
220:             END IF
221: 
222:             IF (NOTRANS) THEN
223:                CALL SGETRS( 'Transpose', N, 1, AF, LDAF, IPIV,
224:      $            WORK, N, INFO )
225:             ELSE
226:                CALL SGETRS( 'No transpose', N, 1, AF, LDAF, IPIV,
227:      $            WORK, N, INFO )
228:             END IF
229: *
230: *           Multiply by R.
231: *
232:             DO I = 1, N
233:                WORK( I ) = WORK( I ) * WORK( 2*N+I )
234:             END DO
235:          END IF
236:          GO TO 10
237:       END IF
238: *
239: *     Compute the estimate of the reciprocal condition number.
240: *
241:       IF( AINVNM .NE. 0.0 )
242:      $   SLA_GERCOND = ( 1.0 / AINVNM )
243: *
244:       RETURN
245: *
246:       END
247: