001:       SUBROUTINE SGELSD( M, N, NRHS, A, LDA, B, LDB, S, RCOND,
002:      $                   RANK, WORK, LWORK, IWORK, INFO )
003: *
004: *  -- LAPACK driver routine (version 3.2) --
005: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
006: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
007: *     November 2006
008: *
009: *     .. Scalar Arguments ..
010:       INTEGER            INFO, LDA, LDB, LWORK, M, N, NRHS, RANK
011:       REAL               RCOND
012: *     ..
013: *     .. Array Arguments ..
014:       INTEGER            IWORK( * )
015:       REAL               A( LDA, * ), B( LDB, * ), S( * ), WORK( * )
016: *     ..
017: *
018: *  Purpose
019: *  =======
020: *
021: *  SGELSD computes the minimum-norm solution to a real linear least
022: *  squares problem:
023: *      minimize 2-norm(| b - A*x |)
024: *  using the singular value decomposition (SVD) of A. A is an M-by-N
025: *  matrix which may be rank-deficient.
026: *
027: *  Several right hand side vectors b and solution vectors x can be
028: *  handled in a single call; they are stored as the columns of the
029: *  M-by-NRHS right hand side matrix B and the N-by-NRHS solution
030: *  matrix X.
031: *
032: *  The problem is solved in three steps:
033: *  (1) Reduce the coefficient matrix A to bidiagonal form with
034: *      Householder transformations, reducing the original problem
035: *      into a "bidiagonal least squares problem" (BLS)
036: *  (2) Solve the BLS using a divide and conquer approach.
037: *  (3) Apply back all the Householder tranformations to solve
038: *      the original least squares problem.
039: *
040: *  The effective rank of A is determined by treating as zero those
041: *  singular values which are less than RCOND times the largest singular
042: *  value.
043: *
044: *  The divide and conquer algorithm makes very mild assumptions about
045: *  floating point arithmetic. It will work on machines with a guard
046: *  digit in add/subtract, or on those binary machines without guard
047: *  digits which subtract like the Cray X-MP, Cray Y-MP, Cray C-90, or
048: *  Cray-2. It could conceivably fail on hexadecimal or decimal machines
049: *  without guard digits, but we know of none.
050: *
051: *  Arguments
052: *  =========
053: *
054: *  M       (input) INTEGER
055: *          The number of rows of A. M >= 0.
056: *
057: *  N       (input) INTEGER
058: *          The number of columns of A. N >= 0.
059: *
060: *  NRHS    (input) INTEGER
061: *          The number of right hand sides, i.e., the number of columns
062: *          of the matrices B and X. NRHS >= 0.
063: *
064: *  A       (input) REAL array, dimension (LDA,N)
065: *          On entry, the M-by-N matrix A.
066: *          On exit, A has been destroyed.
067: *
068: *  LDA     (input) INTEGER
069: *          The leading dimension of the array A.  LDA >= max(1,M).
070: *
071: *  B       (input/output) REAL array, dimension (LDB,NRHS)
072: *          On entry, the M-by-NRHS right hand side matrix B.
073: *          On exit, B is overwritten by the N-by-NRHS solution
074: *          matrix X.  If m >= n and RANK = n, the residual
075: *          sum-of-squares for the solution in the i-th column is given
076: *          by the sum of squares of elements n+1:m in that column.
077: *
078: *  LDB     (input) INTEGER
079: *          The leading dimension of the array B. LDB >= max(1,max(M,N)).
080: *
081: *  S       (output) REAL array, dimension (min(M,N))
082: *          The singular values of A in decreasing order.
083: *          The condition number of A in the 2-norm = S(1)/S(min(m,n)).
084: *
085: *  RCOND   (input) REAL
086: *          RCOND is used to determine the effective rank of A.
087: *          Singular values S(i) <= RCOND*S(1) are treated as zero.
088: *          If RCOND < 0, machine precision is used instead.
089: *
090: *  RANK    (output) INTEGER
091: *          The effective rank of A, i.e., the number of singular values
092: *          which are greater than RCOND*S(1).
093: *
094: *  WORK    (workspace/output) REAL array, dimension (MAX(1,LWORK))
095: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
096: *
097: *  LWORK   (input) INTEGER
098: *          The dimension of the array WORK. LWORK must be at least 1.
099: *          The exact minimum amount of workspace needed depends on M,
100: *          N and NRHS. As long as LWORK is at least
101: *              12*N + 2*N*SMLSIZ + 8*N*NLVL + N*NRHS + (SMLSIZ+1)**2,
102: *          if M is greater than or equal to N or
103: *              12*M + 2*M*SMLSIZ + 8*M*NLVL + M*NRHS + (SMLSIZ+1)**2,
104: *          if M is less than N, the code will execute correctly.
105: *          SMLSIZ is returned by ILAENV and is equal to the maximum
106: *          size of the subproblems at the bottom of the computation
107: *          tree (usually about 25), and
108: *             NLVL = MAX( 0, INT( LOG_2( MIN( M,N )/(SMLSIZ+1) ) ) + 1 )
109: *          For good performance, LWORK should generally be larger.
110: *
111: *          If LWORK = -1, then a workspace query is assumed; the routine
112: *          only calculates the optimal size of the array WORK and the
113: *          minimum size of the array IWORK, and returns these values as
114: *          the first entries of the WORK and IWORK arrays, and no error
115: *          message related to LWORK is issued by XERBLA.
116: *
117: *  IWORK   (workspace) INTEGER array, dimension (MAX(1,LIWORK))
118: *          LIWORK >= max(1, 3*MINMN*NLVL + 11*MINMN),
119: *          where MINMN = MIN( M,N ).
120: *          On exit, if INFO = 0, IWORK(1) returns the minimum LIWORK.
121: *
122: *  INFO    (output) INTEGER
123: *          = 0:  successful exit
124: *          < 0:  if INFO = -i, the i-th argument had an illegal value.
125: *          > 0:  the algorithm for computing the SVD failed to converge;
126: *                if INFO = i, i off-diagonal elements of an intermediate
127: *                bidiagonal form did not converge to zero.
128: *
129: *  Further Details
130: *  ===============
131: *
132: *  Based on contributions by
133: *     Ming Gu and Ren-Cang Li, Computer Science Division, University of
134: *       California at Berkeley, USA
135: *     Osni Marques, LBNL/NERSC, USA
136: *
137: *  =====================================================================
138: *
139: *     .. Parameters ..
140:       REAL               ZERO, ONE, TWO
141:       PARAMETER          ( ZERO = 0.0E0, ONE = 1.0E0, TWO = 2.0E0 )
142: *     ..
143: *     .. Local Scalars ..
144:       LOGICAL            LQUERY
145:       INTEGER            IASCL, IBSCL, IE, IL, ITAU, ITAUP, ITAUQ,
146:      $                   LDWORK, LIWORK, MAXMN, MAXWRK, MINMN, MINWRK,
147:      $                   MM, MNTHR, NLVL, NWORK, SMLSIZ, WLALSD
148:       REAL               ANRM, BIGNUM, BNRM, EPS, SFMIN, SMLNUM
149: *     ..
150: *     .. External Subroutines ..
151:       EXTERNAL           SGEBRD, SGELQF, SGEQRF, SLABAD, SLACPY, SLALSD,
152:      $                   SLASCL, SLASET, SORMBR, SORMLQ, SORMQR, XERBLA
153: *     ..
154: *     .. External Functions ..
155:       INTEGER            ILAENV
156:       REAL               SLAMCH, SLANGE
157:       EXTERNAL           SLAMCH, SLANGE, ILAENV
158: *     ..
159: *     .. Intrinsic Functions ..
160:       INTRINSIC          INT, LOG, MAX, MIN, REAL
161: *     ..
162: *     .. Executable Statements ..
163: *
164: *     Test the input arguments.
165: *
166:       INFO = 0
167:       MINMN = MIN( M, N )
168:       MAXMN = MAX( M, N )
169:       LQUERY = ( LWORK.EQ.-1 )
170:       IF( M.LT.0 ) THEN
171:          INFO = -1
172:       ELSE IF( N.LT.0 ) THEN
173:          INFO = -2
174:       ELSE IF( NRHS.LT.0 ) THEN
175:          INFO = -3
176:       ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
177:          INFO = -5
178:       ELSE IF( LDB.LT.MAX( 1, MAXMN ) ) THEN
179:          INFO = -7
180:       END IF
181: *
182: *     Compute workspace.
183: *     (Note: Comments in the code beginning "Workspace:" describe the
184: *     minimal amount of workspace needed at that point in the code,
185: *     as well as the preferred amount for good performance.
186: *     NB refers to the optimal block size for the immediately
187: *     following subroutine, as returned by ILAENV.)
188: *
189:       IF( INFO.EQ.0 ) THEN
190:          MINWRK = 1
191:          MAXWRK = 1
192:          LIWORK = 1
193:          IF( MINMN.GT.0 ) THEN
194:             SMLSIZ = ILAENV( 9, 'SGELSD', ' ', 0, 0, 0, 0 )
195:             MNTHR = ILAENV( 6, 'SGELSD', ' ', M, N, NRHS, -1 )
196:             NLVL = MAX( INT( LOG( REAL( MINMN ) / REAL( SMLSIZ + 1 ) ) /
197:      $                  LOG( TWO ) ) + 1, 0 )
198:             LIWORK = 3*MINMN*NLVL + 11*MINMN
199:             MM = M
200:             IF( M.GE.N .AND. M.GE.MNTHR ) THEN
201: *
202: *              Path 1a - overdetermined, with many more rows than
203: *                        columns.
204: *
205:                MM = N
206:                MAXWRK = MAX( MAXWRK, N + N*ILAENV( 1, 'SGEQRF', ' ', M,
207:      $                       N, -1, -1 ) )
208:                MAXWRK = MAX( MAXWRK, N + NRHS*ILAENV( 1, 'SORMQR', 'LT',
209:      $                       M, NRHS, N, -1 ) )
210:             END IF
211:             IF( M.GE.N ) THEN
212: *
213: *              Path 1 - overdetermined or exactly determined.
214: *
215:                MAXWRK = MAX( MAXWRK, 3*N + ( MM + N )*ILAENV( 1,
216:      $                       'SGEBRD', ' ', MM, N, -1, -1 ) )
217:                MAXWRK = MAX( MAXWRK, 3*N + NRHS*ILAENV( 1, 'SORMBR',
218:      $                       'QLT', MM, NRHS, N, -1 ) )
219:                MAXWRK = MAX( MAXWRK, 3*N + ( N - 1 )*ILAENV( 1,
220:      $                       'SORMBR', 'PLN', N, NRHS, N, -1 ) )
221:                WLALSD = 9*N + 2*N*SMLSIZ + 8*N*NLVL + N*NRHS +
222:      $                  ( SMLSIZ + 1 )**2
223:                MAXWRK = MAX( MAXWRK, 3*N + WLALSD )
224:                MINWRK = MAX( 3*N + MM, 3*N + NRHS, 3*N + WLALSD )
225:             END IF
226:             IF( N.GT.M ) THEN
227:                WLALSD = 9*M + 2*M*SMLSIZ + 8*M*NLVL + M*NRHS +
228:      $                  ( SMLSIZ + 1 )**2
229:                IF( N.GE.MNTHR ) THEN
230: *
231: *                 Path 2a - underdetermined, with many more columns
232: *                           than rows.
233: *
234:                   MAXWRK = M + M*ILAENV( 1, 'SGELQF', ' ', M, N, -1,
235:      $                                  -1 )
236:                   MAXWRK = MAX( MAXWRK, M*M + 4*M + 2*M*ILAENV( 1,
237:      $                          'SGEBRD', ' ', M, M, -1, -1 ) )
238:                   MAXWRK = MAX( MAXWRK, M*M + 4*M + NRHS*ILAENV( 1,
239:      $                          'SORMBR', 'QLT', M, NRHS, M, -1 ) )
240:                   MAXWRK = MAX( MAXWRK, M*M + 4*M + ( M - 1 )*ILAENV( 1,
241:      $                          'SORMBR', 'PLN', M, NRHS, M, -1 ) )
242:                   IF( NRHS.GT.1 ) THEN
243:                      MAXWRK = MAX( MAXWRK, M*M + M + M*NRHS )
244:                   ELSE
245:                      MAXWRK = MAX( MAXWRK, M*M + 2*M )
246:                   END IF
247:                   MAXWRK = MAX( MAXWRK, M + NRHS*ILAENV( 1, 'SORMLQ',
248:      $                          'LT', N, NRHS, M, -1 ) )
249:                   MAXWRK = MAX( MAXWRK, M*M + 4*M + WLALSD )
250: !     XXX: Ensure the Path 2a case below is triggered.  The workspace
251: !     calculation should use queries for all routines eventually.
252:                   MAXWRK = MAX( MAXWRK,
253:      $                 4*M+M*M+MAX( M, 2*M-4, NRHS, N-3*M ) )
254:                ELSE
255: *
256: *                 Path 2 - remaining underdetermined cases.
257: *
258:                   MAXWRK = 3*M + ( N + M )*ILAENV( 1, 'SGEBRD', ' ', M,
259:      $                     N, -1, -1 )
260:                   MAXWRK = MAX( MAXWRK, 3*M + NRHS*ILAENV( 1, 'SORMBR',
261:      $                          'QLT', M, NRHS, N, -1 ) )
262:                   MAXWRK = MAX( MAXWRK, 3*M + M*ILAENV( 1, 'SORMBR',
263:      $                          'PLN', N, NRHS, M, -1 ) )
264:                   MAXWRK = MAX( MAXWRK, 3*M + WLALSD )
265:                END IF
266:                MINWRK = MAX( 3*M + NRHS, 3*M + M, 3*M + WLALSD )
267:             END IF
268:          END IF
269:          MINWRK = MIN( MINWRK, MAXWRK )
270:          WORK( 1 ) = MAXWRK
271:          IWORK( 1 ) = LIWORK
272: *
273:          IF( LWORK.LT.MINWRK .AND. .NOT.LQUERY ) THEN
274:             INFO = -12
275:          END IF
276:       END IF
277: *
278:       IF( INFO.NE.0 ) THEN
279:          CALL XERBLA( 'SGELSD', -INFO )
280:          RETURN
281:       ELSE IF( LQUERY ) THEN
282:          RETURN
283:       END IF
284: *
285: *     Quick return if possible.
286: *
287:       IF( M.EQ.0 .OR. N.EQ.0 ) THEN
288:          RANK = 0
289:          RETURN
290:       END IF
291: *
292: *     Get machine parameters.
293: *
294:       EPS = SLAMCH( 'P' )
295:       SFMIN = SLAMCH( 'S' )
296:       SMLNUM = SFMIN / EPS
297:       BIGNUM = ONE / SMLNUM
298:       CALL SLABAD( SMLNUM, BIGNUM )
299: *
300: *     Scale A if max entry outside range [SMLNUM,BIGNUM].
301: *
302:       ANRM = SLANGE( 'M', M, N, A, LDA, WORK )
303:       IASCL = 0
304:       IF( ANRM.GT.ZERO .AND. ANRM.LT.SMLNUM ) THEN
305: *
306: *        Scale matrix norm up to SMLNUM.
307: *
308:          CALL SLASCL( 'G', 0, 0, ANRM, SMLNUM, M, N, A, LDA, INFO )
309:          IASCL = 1
310:       ELSE IF( ANRM.GT.BIGNUM ) THEN
311: *
312: *        Scale matrix norm down to BIGNUM.
313: *
314:          CALL SLASCL( 'G', 0, 0, ANRM, BIGNUM, M, N, A, LDA, INFO )
315:          IASCL = 2
316:       ELSE IF( ANRM.EQ.ZERO ) THEN
317: *
318: *        Matrix all zero. Return zero solution.
319: *
320:          CALL SLASET( 'F', MAX( M, N ), NRHS, ZERO, ZERO, B, LDB )
321:          CALL SLASET( 'F', MINMN, 1, ZERO, ZERO, S, 1 )
322:          RANK = 0
323:          GO TO 10
324:       END IF
325: *
326: *     Scale B if max entry outside range [SMLNUM,BIGNUM].
327: *
328:       BNRM = SLANGE( 'M', M, NRHS, B, LDB, WORK )
329:       IBSCL = 0
330:       IF( BNRM.GT.ZERO .AND. BNRM.LT.SMLNUM ) THEN
331: *
332: *        Scale matrix norm up to SMLNUM.
333: *
334:          CALL SLASCL( 'G', 0, 0, BNRM, SMLNUM, M, NRHS, B, LDB, INFO )
335:          IBSCL = 1
336:       ELSE IF( BNRM.GT.BIGNUM ) THEN
337: *
338: *        Scale matrix norm down to BIGNUM.
339: *
340:          CALL SLASCL( 'G', 0, 0, BNRM, BIGNUM, M, NRHS, B, LDB, INFO )
341:          IBSCL = 2
342:       END IF
343: *
344: *     If M < N make sure certain entries of B are zero.
345: *
346:       IF( M.LT.N )
347:      $   CALL SLASET( 'F', N-M, NRHS, ZERO, ZERO, B( M+1, 1 ), LDB )
348: *
349: *     Overdetermined case.
350: *
351:       IF( M.GE.N ) THEN
352: *
353: *        Path 1 - overdetermined or exactly determined.
354: *
355:          MM = M
356:          IF( M.GE.MNTHR ) THEN
357: *
358: *           Path 1a - overdetermined, with many more rows than columns.
359: *
360:             MM = N
361:             ITAU = 1
362:             NWORK = ITAU + N
363: *
364: *           Compute A=Q*R.
365: *           (Workspace: need 2*N, prefer N+N*NB)
366: *
367:             CALL SGEQRF( M, N, A, LDA, WORK( ITAU ), WORK( NWORK ),
368:      $                   LWORK-NWORK+1, INFO )
369: *
370: *           Multiply B by transpose(Q).
371: *           (Workspace: need N+NRHS, prefer N+NRHS*NB)
372: *
373:             CALL SORMQR( 'L', 'T', M, NRHS, N, A, LDA, WORK( ITAU ), B,
374:      $                   LDB, WORK( NWORK ), LWORK-NWORK+1, INFO )
375: *
376: *           Zero out below R.
377: *
378:             IF( N.GT.1 ) THEN
379:                CALL SLASET( 'L', N-1, N-1, ZERO, ZERO, A( 2, 1 ), LDA )
380:             END IF
381:          END IF
382: *
383:          IE = 1
384:          ITAUQ = IE + N
385:          ITAUP = ITAUQ + N
386:          NWORK = ITAUP + N
387: *
388: *        Bidiagonalize R in A.
389: *        (Workspace: need 3*N+MM, prefer 3*N+(MM+N)*NB)
390: *
391:          CALL SGEBRD( MM, N, A, LDA, S, WORK( IE ), WORK( ITAUQ ),
392:      $                WORK( ITAUP ), WORK( NWORK ), LWORK-NWORK+1,
393:      $                INFO )
394: *
395: *        Multiply B by transpose of left bidiagonalizing vectors of R.
396: *        (Workspace: need 3*N+NRHS, prefer 3*N+NRHS*NB)
397: *
398:          CALL SORMBR( 'Q', 'L', 'T', MM, NRHS, N, A, LDA, WORK( ITAUQ ),
399:      $                B, LDB, WORK( NWORK ), LWORK-NWORK+1, INFO )
400: *
401: *        Solve the bidiagonal least squares problem.
402: *
403:          CALL SLALSD( 'U', SMLSIZ, N, NRHS, S, WORK( IE ), B, LDB,
404:      $                RCOND, RANK, WORK( NWORK ), IWORK, INFO )
405:          IF( INFO.NE.0 ) THEN
406:             GO TO 10
407:          END IF
408: *
409: *        Multiply B by right bidiagonalizing vectors of R.
410: *
411:          CALL SORMBR( 'P', 'L', 'N', N, NRHS, N, A, LDA, WORK( ITAUP ),
412:      $                B, LDB, WORK( NWORK ), LWORK-NWORK+1, INFO )
413: *
414:       ELSE IF( N.GE.MNTHR .AND. LWORK.GE.4*M+M*M+
415:      $         MAX( M, 2*M-4, NRHS, N-3*M, WLALSD ) ) THEN
416: *
417: *        Path 2a - underdetermined, with many more columns than rows
418: *        and sufficient workspace for an efficient algorithm.
419: *
420:          LDWORK = M
421:          IF( LWORK.GE.MAX( 4*M+M*LDA+MAX( M, 2*M-4, NRHS, N-3*M ),
422:      $       M*LDA+M+M*NRHS, 4*M+M*LDA+WLALSD ) )LDWORK = LDA
423:          ITAU = 1
424:          NWORK = M + 1
425: *
426: *        Compute A=L*Q.
427: *        (Workspace: need 2*M, prefer M+M*NB)
428: *
429:          CALL SGELQF( M, N, A, LDA, WORK( ITAU ), WORK( NWORK ),
430:      $                LWORK-NWORK+1, INFO )
431:          IL = NWORK
432: *
433: *        Copy L to WORK(IL), zeroing out above its diagonal.
434: *
435:          CALL SLACPY( 'L', M, M, A, LDA, WORK( IL ), LDWORK )
436:          CALL SLASET( 'U', M-1, M-1, ZERO, ZERO, WORK( IL+LDWORK ),
437:      $                LDWORK )
438:          IE = IL + LDWORK*M
439:          ITAUQ = IE + M
440:          ITAUP = ITAUQ + M
441:          NWORK = ITAUP + M
442: *
443: *        Bidiagonalize L in WORK(IL).
444: *        (Workspace: need M*M+5*M, prefer M*M+4*M+2*M*NB)
445: *
446:          CALL SGEBRD( M, M, WORK( IL ), LDWORK, S, WORK( IE ),
447:      $                WORK( ITAUQ ), WORK( ITAUP ), WORK( NWORK ),
448:      $                LWORK-NWORK+1, INFO )
449: *
450: *        Multiply B by transpose of left bidiagonalizing vectors of L.
451: *        (Workspace: need M*M+4*M+NRHS, prefer M*M+4*M+NRHS*NB)
452: *
453:          CALL SORMBR( 'Q', 'L', 'T', M, NRHS, M, WORK( IL ), LDWORK,
454:      $                WORK( ITAUQ ), B, LDB, WORK( NWORK ),
455:      $                LWORK-NWORK+1, INFO )
456: *
457: *        Solve the bidiagonal least squares problem.
458: *
459:          CALL SLALSD( 'U', SMLSIZ, M, NRHS, S, WORK( IE ), B, LDB,
460:      $                RCOND, RANK, WORK( NWORK ), IWORK, INFO )
461:          IF( INFO.NE.0 ) THEN
462:             GO TO 10
463:          END IF
464: *
465: *        Multiply B by right bidiagonalizing vectors of L.
466: *
467:          CALL SORMBR( 'P', 'L', 'N', M, NRHS, M, WORK( IL ), LDWORK,
468:      $                WORK( ITAUP ), B, LDB, WORK( NWORK ),
469:      $                LWORK-NWORK+1, INFO )
470: *
471: *        Zero out below first M rows of B.
472: *
473:          CALL SLASET( 'F', N-M, NRHS, ZERO, ZERO, B( M+1, 1 ), LDB )
474:          NWORK = ITAU + M
475: *
476: *        Multiply transpose(Q) by B.
477: *        (Workspace: need M+NRHS, prefer M+NRHS*NB)
478: *
479:          CALL SORMLQ( 'L', 'T', N, NRHS, M, A, LDA, WORK( ITAU ), B,
480:      $                LDB, WORK( NWORK ), LWORK-NWORK+1, INFO )
481: *
482:       ELSE
483: *
484: *        Path 2 - remaining underdetermined cases.
485: *
486:          IE = 1
487:          ITAUQ = IE + M
488:          ITAUP = ITAUQ + M
489:          NWORK = ITAUP + M
490: *
491: *        Bidiagonalize A.
492: *        (Workspace: need 3*M+N, prefer 3*M+(M+N)*NB)
493: *
494:          CALL SGEBRD( M, N, A, LDA, S, WORK( IE ), WORK( ITAUQ ),
495:      $                WORK( ITAUP ), WORK( NWORK ), LWORK-NWORK+1,
496:      $                INFO )
497: *
498: *        Multiply B by transpose of left bidiagonalizing vectors.
499: *        (Workspace: need 3*M+NRHS, prefer 3*M+NRHS*NB)
500: *
501:          CALL SORMBR( 'Q', 'L', 'T', M, NRHS, N, A, LDA, WORK( ITAUQ ),
502:      $                B, LDB, WORK( NWORK ), LWORK-NWORK+1, INFO )
503: *
504: *        Solve the bidiagonal least squares problem.
505: *
506:          CALL SLALSD( 'L', SMLSIZ, M, NRHS, S, WORK( IE ), B, LDB,
507:      $                RCOND, RANK, WORK( NWORK ), IWORK, INFO )
508:          IF( INFO.NE.0 ) THEN
509:             GO TO 10
510:          END IF
511: *
512: *        Multiply B by right bidiagonalizing vectors of A.
513: *
514:          CALL SORMBR( 'P', 'L', 'N', N, NRHS, M, A, LDA, WORK( ITAUP ),
515:      $                B, LDB, WORK( NWORK ), LWORK-NWORK+1, INFO )
516: *
517:       END IF
518: *
519: *     Undo scaling.
520: *
521:       IF( IASCL.EQ.1 ) THEN
522:          CALL SLASCL( 'G', 0, 0, ANRM, SMLNUM, N, NRHS, B, LDB, INFO )
523:          CALL SLASCL( 'G', 0, 0, SMLNUM, ANRM, MINMN, 1, S, MINMN,
524:      $                INFO )
525:       ELSE IF( IASCL.EQ.2 ) THEN
526:          CALL SLASCL( 'G', 0, 0, ANRM, BIGNUM, N, NRHS, B, LDB, INFO )
527:          CALL SLASCL( 'G', 0, 0, BIGNUM, ANRM, MINMN, 1, S, MINMN,
528:      $                INFO )
529:       END IF
530:       IF( IBSCL.EQ.1 ) THEN
531:          CALL SLASCL( 'G', 0, 0, SMLNUM, BNRM, N, NRHS, B, LDB, INFO )
532:       ELSE IF( IBSCL.EQ.2 ) THEN
533:          CALL SLASCL( 'G', 0, 0, BIGNUM, BNRM, N, NRHS, B, LDB, INFO )
534:       END IF
535: *
536:    10 CONTINUE
537:       WORK( 1 ) = MAXWRK
538:       IWORK( 1 ) = LIWORK
539:       RETURN
540: *
541: *     End of SGELSD
542: *
543:       END
544: