001:       SUBROUTINE SGBTRS( TRANS, N, KL, KU, NRHS, AB, LDAB, IPIV, B, LDB,
002:      $                   INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
006: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
007: *     November 2006
008: *
009: *     .. Scalar Arguments ..
010:       CHARACTER          TRANS
011:       INTEGER            INFO, KL, KU, LDAB, LDB, N, NRHS
012: *     ..
013: *     .. Array Arguments ..
014:       INTEGER            IPIV( * )
015:       REAL               AB( LDAB, * ), B( LDB, * )
016: *     ..
017: *
018: *  Purpose
019: *  =======
020: *
021: *  SGBTRS solves a system of linear equations
022: *     A * X = B  or  A' * X = B
023: *  with a general band matrix A using the LU factorization computed
024: *  by SGBTRF.
025: *
026: *  Arguments
027: *  =========
028: *
029: *  TRANS   (input) CHARACTER*1
030: *          Specifies the form of the system of equations.
031: *          = 'N':  A * X = B  (No transpose)
032: *          = 'T':  A'* X = B  (Transpose)
033: *          = 'C':  A'* X = B  (Conjugate transpose = Transpose)
034: *
035: *  N       (input) INTEGER
036: *          The order of the matrix A.  N >= 0.
037: *
038: *  KL      (input) INTEGER
039: *          The number of subdiagonals within the band of A.  KL >= 0.
040: *
041: *  KU      (input) INTEGER
042: *          The number of superdiagonals within the band of A.  KU >= 0.
043: *
044: *  NRHS    (input) INTEGER
045: *          The number of right hand sides, i.e., the number of columns
046: *          of the matrix B.  NRHS >= 0.
047: *
048: *  AB      (input) REAL array, dimension (LDAB,N)
049: *          Details of the LU factorization of the band matrix A, as
050: *          computed by SGBTRF.  U is stored as an upper triangular band
051: *          matrix with KL+KU superdiagonals in rows 1 to KL+KU+1, and
052: *          the multipliers used during the factorization are stored in
053: *          rows KL+KU+2 to 2*KL+KU+1.
054: *
055: *  LDAB    (input) INTEGER
056: *          The leading dimension of the array AB.  LDAB >= 2*KL+KU+1.
057: *
058: *  IPIV    (input) INTEGER array, dimension (N)
059: *          The pivot indices; for 1 <= i <= N, row i of the matrix was
060: *          interchanged with row IPIV(i).
061: *
062: *  B       (input/output) REAL array, dimension (LDB,NRHS)
063: *          On entry, the right hand side matrix B.
064: *          On exit, the solution matrix X.
065: *
066: *  LDB     (input) INTEGER
067: *          The leading dimension of the array B.  LDB >= max(1,N).
068: *
069: *  INFO    (output) INTEGER
070: *          = 0:  successful exit
071: *          < 0: if INFO = -i, the i-th argument had an illegal value
072: *
073: *  =====================================================================
074: *
075: *     .. Parameters ..
076:       REAL               ONE
077:       PARAMETER          ( ONE = 1.0E+0 )
078: *     ..
079: *     .. Local Scalars ..
080:       LOGICAL            LNOTI, NOTRAN
081:       INTEGER            I, J, KD, L, LM
082: *     ..
083: *     .. External Functions ..
084:       LOGICAL            LSAME
085:       EXTERNAL           LSAME
086: *     ..
087: *     .. External Subroutines ..
088:       EXTERNAL           SGEMV, SGER, SSWAP, STBSV, XERBLA
089: *     ..
090: *     .. Intrinsic Functions ..
091:       INTRINSIC          MAX, MIN
092: *     ..
093: *     .. Executable Statements ..
094: *
095: *     Test the input parameters.
096: *
097:       INFO = 0
098:       NOTRAN = LSAME( TRANS, 'N' )
099:       IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'T' ) .AND. .NOT.
100:      $    LSAME( TRANS, 'C' ) ) THEN
101:          INFO = -1
102:       ELSE IF( N.LT.0 ) THEN
103:          INFO = -2
104:       ELSE IF( KL.LT.0 ) THEN
105:          INFO = -3
106:       ELSE IF( KU.LT.0 ) THEN
107:          INFO = -4
108:       ELSE IF( NRHS.LT.0 ) THEN
109:          INFO = -5
110:       ELSE IF( LDAB.LT.( 2*KL+KU+1 ) ) THEN
111:          INFO = -7
112:       ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
113:          INFO = -10
114:       END IF
115:       IF( INFO.NE.0 ) THEN
116:          CALL XERBLA( 'SGBTRS', -INFO )
117:          RETURN
118:       END IF
119: *
120: *     Quick return if possible
121: *
122:       IF( N.EQ.0 .OR. NRHS.EQ.0 )
123:      $   RETURN
124: *
125:       KD = KU + KL + 1
126:       LNOTI = KL.GT.0
127: *
128:       IF( NOTRAN ) THEN
129: *
130: *        Solve  A*X = B.
131: *
132: *        Solve L*X = B, overwriting B with X.
133: *
134: *        L is represented as a product of permutations and unit lower
135: *        triangular matrices L = P(1) * L(1) * ... * P(n-1) * L(n-1),
136: *        where each transformation L(i) is a rank-one modification of
137: *        the identity matrix.
138: *
139:          IF( LNOTI ) THEN
140:             DO 10 J = 1, N - 1
141:                LM = MIN( KL, N-J )
142:                L = IPIV( J )
143:                IF( L.NE.J )
144:      $            CALL SSWAP( NRHS, B( L, 1 ), LDB, B( J, 1 ), LDB )
145:                CALL SGER( LM, NRHS, -ONE, AB( KD+1, J ), 1, B( J, 1 ),
146:      $                    LDB, B( J+1, 1 ), LDB )
147:    10       CONTINUE
148:          END IF
149: *
150:          DO 20 I = 1, NRHS
151: *
152: *           Solve U*X = B, overwriting B with X.
153: *
154:             CALL STBSV( 'Upper', 'No transpose', 'Non-unit', N, KL+KU,
155:      $                  AB, LDAB, B( 1, I ), 1 )
156:    20    CONTINUE
157: *
158:       ELSE
159: *
160: *        Solve A'*X = B.
161: *
162:          DO 30 I = 1, NRHS
163: *
164: *           Solve U'*X = B, overwriting B with X.
165: *
166:             CALL STBSV( 'Upper', 'Transpose', 'Non-unit', N, KL+KU, AB,
167:      $                  LDAB, B( 1, I ), 1 )
168:    30    CONTINUE
169: *
170: *        Solve L'*X = B, overwriting B with X.
171: *
172:          IF( LNOTI ) THEN
173:             DO 40 J = N - 1, 1, -1
174:                LM = MIN( KL, N-J )
175:                CALL SGEMV( 'Transpose', LM, NRHS, -ONE, B( J+1, 1 ),
176:      $                     LDB, AB( KD+1, J ), 1, ONE, B( J, 1 ), LDB )
177:                L = IPIV( J )
178:                IF( L.NE.J )
179:      $            CALL SSWAP( NRHS, B( L, 1 ), LDB, B( J, 1 ), LDB )
180:    40       CONTINUE
181:          END IF
182:       END IF
183:       RETURN
184: *
185: *     End of SGBTRS
186: *
187:       END
188: