001:       SUBROUTINE DSYMV(UPLO,N,ALPHA,A,LDA,X,INCX,BETA,Y,INCY)
002: *     .. Scalar Arguments ..
003:       DOUBLE PRECISION ALPHA,BETA
004:       INTEGER INCX,INCY,LDA,N
005:       CHARACTER UPLO
006: *     ..
007: *     .. Array Arguments ..
008:       DOUBLE PRECISION A(LDA,*),X(*),Y(*)
009: *     ..
010: *
011: *  Purpose
012: *  =======
013: *
014: *  DSYMV  performs the matrix-vector  operation
015: *
016: *     y := alpha*A*x + beta*y,
017: *
018: *  where alpha and beta are scalars, x and y are n element vectors and
019: *  A is an n by n symmetric matrix.
020: *
021: *  Arguments
022: *  ==========
023: *
024: *  UPLO   - CHARACTER*1.
025: *           On entry, UPLO specifies whether the upper or lower
026: *           triangular part of the array A is to be referenced as
027: *           follows:
028: *
029: *              UPLO = 'U' or 'u'   Only the upper triangular part of A
030: *                                  is to be referenced.
031: *
032: *              UPLO = 'L' or 'l'   Only the lower triangular part of A
033: *                                  is to be referenced.
034: *
035: *           Unchanged on exit.
036: *
037: *  N      - INTEGER.
038: *           On entry, N specifies the order of the matrix A.
039: *           N must be at least zero.
040: *           Unchanged on exit.
041: *
042: *  ALPHA  - DOUBLE PRECISION.
043: *           On entry, ALPHA specifies the scalar alpha.
044: *           Unchanged on exit.
045: *
046: *  A      - DOUBLE PRECISION array of DIMENSION ( LDA, n ).
047: *           Before entry with  UPLO = 'U' or 'u', the leading n by n
048: *           upper triangular part of the array A must contain the upper
049: *           triangular part of the symmetric matrix and the strictly
050: *           lower triangular part of A is not referenced.
051: *           Before entry with UPLO = 'L' or 'l', the leading n by n
052: *           lower triangular part of the array A must contain the lower
053: *           triangular part of the symmetric matrix and the strictly
054: *           upper triangular part of A is not referenced.
055: *           Unchanged on exit.
056: *
057: *  LDA    - INTEGER.
058: *           On entry, LDA specifies the first dimension of A as declared
059: *           in the calling (sub) program. LDA must be at least
060: *           max( 1, n ).
061: *           Unchanged on exit.
062: *
063: *  X      - DOUBLE PRECISION array of dimension at least
064: *           ( 1 + ( n - 1 )*abs( INCX ) ).
065: *           Before entry, the incremented array X must contain the n
066: *           element vector x.
067: *           Unchanged on exit.
068: *
069: *  INCX   - INTEGER.
070: *           On entry, INCX specifies the increment for the elements of
071: *           X. INCX must not be zero.
072: *           Unchanged on exit.
073: *
074: *  BETA   - DOUBLE PRECISION.
075: *           On entry, BETA specifies the scalar beta. When BETA is
076: *           supplied as zero then Y need not be set on input.
077: *           Unchanged on exit.
078: *
079: *  Y      - DOUBLE PRECISION array of dimension at least
080: *           ( 1 + ( n - 1 )*abs( INCY ) ).
081: *           Before entry, the incremented array Y must contain the n
082: *           element vector y. On exit, Y is overwritten by the updated
083: *           vector y.
084: *
085: *  INCY   - INTEGER.
086: *           On entry, INCY specifies the increment for the elements of
087: *           Y. INCY must not be zero.
088: *           Unchanged on exit.
089: *
090: *  Further Details
091: *  ===============
092: *
093: *  Level 2 Blas routine.
094: *
095: *  -- Written on 22-October-1986.
096: *     Jack Dongarra, Argonne National Lab.
097: *     Jeremy Du Croz, Nag Central Office.
098: *     Sven Hammarling, Nag Central Office.
099: *     Richard Hanson, Sandia National Labs.
100: *
101: *  =====================================================================
102: *
103: *     .. Parameters ..
104:       DOUBLE PRECISION ONE,ZERO
105:       PARAMETER (ONE=1.0D+0,ZERO=0.0D+0)
106: *     ..
107: *     .. Local Scalars ..
108:       DOUBLE PRECISION TEMP1,TEMP2
109:       INTEGER I,INFO,IX,IY,J,JX,JY,KX,KY
110: *     ..
111: *     .. External Functions ..
112:       LOGICAL LSAME
113:       EXTERNAL LSAME
114: *     ..
115: *     .. External Subroutines ..
116:       EXTERNAL XERBLA
117: *     ..
118: *     .. Intrinsic Functions ..
119:       INTRINSIC MAX
120: *     ..
121: *
122: *     Test the input parameters.
123: *
124:       INFO = 0
125:       IF (.NOT.LSAME(UPLO,'U') .AND. .NOT.LSAME(UPLO,'L')) THEN
126:           INFO = 1
127:       ELSE IF (N.LT.0) THEN
128:           INFO = 2
129:       ELSE IF (LDA.LT.MAX(1,N)) THEN
130:           INFO = 5
131:       ELSE IF (INCX.EQ.0) THEN
132:           INFO = 7
133:       ELSE IF (INCY.EQ.0) THEN
134:           INFO = 10
135:       END IF
136:       IF (INFO.NE.0) THEN
137:           CALL XERBLA('DSYMV ',INFO)
138:           RETURN
139:       END IF
140: *
141: *     Quick return if possible.
142: *
143:       IF ((N.EQ.0) .OR. ((ALPHA.EQ.ZERO).AND. (BETA.EQ.ONE))) RETURN
144: *
145: *     Set up the start points in  X  and  Y.
146: *
147:       IF (INCX.GT.0) THEN
148:           KX = 1
149:       ELSE
150:           KX = 1 - (N-1)*INCX
151:       END IF
152:       IF (INCY.GT.0) THEN
153:           KY = 1
154:       ELSE
155:           KY = 1 - (N-1)*INCY
156:       END IF
157: *
158: *     Start the operations. In this version the elements of A are
159: *     accessed sequentially with one pass through the triangular part
160: *     of A.
161: *
162: *     First form  y := beta*y.
163: *
164:       IF (BETA.NE.ONE) THEN
165:           IF (INCY.EQ.1) THEN
166:               IF (BETA.EQ.ZERO) THEN
167:                   DO 10 I = 1,N
168:                       Y(I) = ZERO
169:    10             CONTINUE
170:               ELSE
171:                   DO 20 I = 1,N
172:                       Y(I) = BETA*Y(I)
173:    20             CONTINUE
174:               END IF
175:           ELSE
176:               IY = KY
177:               IF (BETA.EQ.ZERO) THEN
178:                   DO 30 I = 1,N
179:                       Y(IY) = ZERO
180:                       IY = IY + INCY
181:    30             CONTINUE
182:               ELSE
183:                   DO 40 I = 1,N
184:                       Y(IY) = BETA*Y(IY)
185:                       IY = IY + INCY
186:    40             CONTINUE
187:               END IF
188:           END IF
189:       END IF
190:       IF (ALPHA.EQ.ZERO) RETURN
191:       IF (LSAME(UPLO,'U')) THEN
192: *
193: *        Form  y  when A is stored in upper triangle.
194: *
195:           IF ((INCX.EQ.1) .AND. (INCY.EQ.1)) THEN
196:               DO 60 J = 1,N
197:                   TEMP1 = ALPHA*X(J)
198:                   TEMP2 = ZERO
199:                   DO 50 I = 1,J - 1
200:                       Y(I) = Y(I) + TEMP1*A(I,J)
201:                       TEMP2 = TEMP2 + A(I,J)*X(I)
202:    50             CONTINUE
203:                   Y(J) = Y(J) + TEMP1*A(J,J) + ALPHA*TEMP2
204:    60         CONTINUE
205:           ELSE
206:               JX = KX
207:               JY = KY
208:               DO 80 J = 1,N
209:                   TEMP1 = ALPHA*X(JX)
210:                   TEMP2 = ZERO
211:                   IX = KX
212:                   IY = KY
213:                   DO 70 I = 1,J - 1
214:                       Y(IY) = Y(IY) + TEMP1*A(I,J)
215:                       TEMP2 = TEMP2 + A(I,J)*X(IX)
216:                       IX = IX + INCX
217:                       IY = IY + INCY
218:    70             CONTINUE
219:                   Y(JY) = Y(JY) + TEMP1*A(J,J) + ALPHA*TEMP2
220:                   JX = JX + INCX
221:                   JY = JY + INCY
222:    80         CONTINUE
223:           END IF
224:       ELSE
225: *
226: *        Form  y  when A is stored in lower triangle.
227: *
228:           IF ((INCX.EQ.1) .AND. (INCY.EQ.1)) THEN
229:               DO 100 J = 1,N
230:                   TEMP1 = ALPHA*X(J)
231:                   TEMP2 = ZERO
232:                   Y(J) = Y(J) + TEMP1*A(J,J)
233:                   DO 90 I = J + 1,N
234:                       Y(I) = Y(I) + TEMP1*A(I,J)
235:                       TEMP2 = TEMP2 + A(I,J)*X(I)
236:    90             CONTINUE
237:                   Y(J) = Y(J) + ALPHA*TEMP2
238:   100         CONTINUE
239:           ELSE
240:               JX = KX
241:               JY = KY
242:               DO 120 J = 1,N
243:                   TEMP1 = ALPHA*X(JX)
244:                   TEMP2 = ZERO
245:                   Y(JY) = Y(JY) + TEMP1*A(J,J)
246:                   IX = JX
247:                   IY = JY
248:                   DO 110 I = J + 1,N
249:                       IX = IX + INCX
250:                       IY = IY + INCY
251:                       Y(IY) = Y(IY) + TEMP1*A(I,J)
252:                       TEMP2 = TEMP2 + A(I,J)*X(IX)
253:   110             CONTINUE
254:                   Y(JY) = Y(JY) + ALPHA*TEMP2
255:                   JX = JX + INCX
256:                   JY = JY + INCY
257:   120         CONTINUE
258:           END IF
259:       END IF
260: *
261:       RETURN
262: *
263: *     End of DSYMV .
264: *
265:       END
266: