001:       SUBROUTINE DGERFS( TRANS, N, NRHS, A, LDA, AF, LDAF, IPIV, B, LDB,
002:      $                   X, LDX, FERR, BERR, WORK, IWORK, INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
006: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
007: *     November 2006
008: *
009: *     Modified to call DLACN2 in place of DLACON, 5 Feb 03, SJH.
010: *
011: *     .. Scalar Arguments ..
012:       CHARACTER          TRANS
013:       INTEGER            INFO, LDA, LDAF, LDB, LDX, N, NRHS
014: *     ..
015: *     .. Array Arguments ..
016:       INTEGER            IPIV( * ), IWORK( * )
017:       DOUBLE PRECISION   A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
018:      $                   BERR( * ), FERR( * ), WORK( * ), X( LDX, * )
019: *     ..
020: *
021: *  Purpose
022: *  =======
023: *
024: *  DGERFS improves the computed solution to a system of linear
025: *  equations and provides error bounds and backward error estimates for
026: *  the solution.
027: *
028: *  Arguments
029: *  =========
030: *
031: *  TRANS   (input) CHARACTER*1
032: *          Specifies the form of the system of equations:
033: *          = 'N':  A * X = B     (No transpose)
034: *          = 'T':  A**T * X = B  (Transpose)
035: *          = 'C':  A**H * X = B  (Conjugate transpose = Transpose)
036: *
037: *  N       (input) INTEGER
038: *          The order of the matrix A.  N >= 0.
039: *
040: *  NRHS    (input) INTEGER
041: *          The number of right hand sides, i.e., the number of columns
042: *          of the matrices B and X.  NRHS >= 0.
043: *
044: *  A       (input) DOUBLE PRECISION array, dimension (LDA,N)
045: *          The original N-by-N matrix A.
046: *
047: *  LDA     (input) INTEGER
048: *          The leading dimension of the array A.  LDA >= max(1,N).
049: *
050: *  AF      (input) DOUBLE PRECISION array, dimension (LDAF,N)
051: *          The factors L and U from the factorization A = P*L*U
052: *          as computed by DGETRF.
053: *
054: *  LDAF    (input) INTEGER
055: *          The leading dimension of the array AF.  LDAF >= max(1,N).
056: *
057: *  IPIV    (input) INTEGER array, dimension (N)
058: *          The pivot indices from DGETRF; for 1<=i<=N, row i of the
059: *          matrix was interchanged with row IPIV(i).
060: *
061: *  B       (input) DOUBLE PRECISION array, dimension (LDB,NRHS)
062: *          The right hand side matrix B.
063: *
064: *  LDB     (input) INTEGER
065: *          The leading dimension of the array B.  LDB >= max(1,N).
066: *
067: *  X       (input/output) DOUBLE PRECISION array, dimension (LDX,NRHS)
068: *          On entry, the solution matrix X, as computed by DGETRS.
069: *          On exit, the improved solution matrix X.
070: *
071: *  LDX     (input) INTEGER
072: *          The leading dimension of the array X.  LDX >= max(1,N).
073: *
074: *  FERR    (output) DOUBLE PRECISION array, dimension (NRHS)
075: *          The estimated forward error bound for each solution vector
076: *          X(j) (the j-th column of the solution matrix X).
077: *          If XTRUE is the true solution corresponding to X(j), FERR(j)
078: *          is an estimated upper bound for the magnitude of the largest
079: *          element in (X(j) - XTRUE) divided by the magnitude of the
080: *          largest element in X(j).  The estimate is as reliable as
081: *          the estimate for RCOND, and is almost always a slight
082: *          overestimate of the true error.
083: *
084: *  BERR    (output) DOUBLE PRECISION array, dimension (NRHS)
085: *          The componentwise relative backward error of each solution
086: *          vector X(j) (i.e., the smallest relative change in
087: *          any element of A or B that makes X(j) an exact solution).
088: *
089: *  WORK    (workspace) DOUBLE PRECISION array, dimension (3*N)
090: *
091: *  IWORK   (workspace) INTEGER array, dimension (N)
092: *
093: *  INFO    (output) INTEGER
094: *          = 0:  successful exit
095: *          < 0:  if INFO = -i, the i-th argument had an illegal value
096: *
097: *  Internal Parameters
098: *  ===================
099: *
100: *  ITMAX is the maximum number of steps of iterative refinement.
101: *
102: *  =====================================================================
103: *
104: *     .. Parameters ..
105:       INTEGER            ITMAX
106:       PARAMETER          ( ITMAX = 5 )
107:       DOUBLE PRECISION   ZERO
108:       PARAMETER          ( ZERO = 0.0D+0 )
109:       DOUBLE PRECISION   ONE
110:       PARAMETER          ( ONE = 1.0D+0 )
111:       DOUBLE PRECISION   TWO
112:       PARAMETER          ( TWO = 2.0D+0 )
113:       DOUBLE PRECISION   THREE
114:       PARAMETER          ( THREE = 3.0D+0 )
115: *     ..
116: *     .. Local Scalars ..
117:       LOGICAL            NOTRAN
118:       CHARACTER          TRANST
119:       INTEGER            COUNT, I, J, K, KASE, NZ
120:       DOUBLE PRECISION   EPS, LSTRES, S, SAFE1, SAFE2, SAFMIN, XK
121: *     ..
122: *     .. Local Arrays ..
123:       INTEGER            ISAVE( 3 )
124: *     ..
125: *     .. External Subroutines ..
126:       EXTERNAL           DAXPY, DCOPY, DGEMV, DGETRS, DLACN2, XERBLA
127: *     ..
128: *     .. Intrinsic Functions ..
129:       INTRINSIC          ABS, MAX
130: *     ..
131: *     .. External Functions ..
132:       LOGICAL            LSAME
133:       DOUBLE PRECISION   DLAMCH
134:       EXTERNAL           LSAME, DLAMCH
135: *     ..
136: *     .. Executable Statements ..
137: *
138: *     Test the input parameters.
139: *
140:       INFO = 0
141:       NOTRAN = LSAME( TRANS, 'N' )
142:       IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'T' ) .AND. .NOT.
143:      $    LSAME( TRANS, 'C' ) ) THEN
144:          INFO = -1
145:       ELSE IF( N.LT.0 ) THEN
146:          INFO = -2
147:       ELSE IF( NRHS.LT.0 ) THEN
148:          INFO = -3
149:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
150:          INFO = -5
151:       ELSE IF( LDAF.LT.MAX( 1, N ) ) THEN
152:          INFO = -7
153:       ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
154:          INFO = -10
155:       ELSE IF( LDX.LT.MAX( 1, N ) ) THEN
156:          INFO = -12
157:       END IF
158:       IF( INFO.NE.0 ) THEN
159:          CALL XERBLA( 'DGERFS', -INFO )
160:          RETURN
161:       END IF
162: *
163: *     Quick return if possible
164: *
165:       IF( N.EQ.0 .OR. NRHS.EQ.0 ) THEN
166:          DO 10 J = 1, NRHS
167:             FERR( J ) = ZERO
168:             BERR( J ) = ZERO
169:    10    CONTINUE
170:          RETURN
171:       END IF
172: *
173:       IF( NOTRAN ) THEN
174:          TRANST = 'T'
175:       ELSE
176:          TRANST = 'N'
177:       END IF
178: *
179: *     NZ = maximum number of nonzero elements in each row of A, plus 1
180: *
181:       NZ = N + 1
182:       EPS = DLAMCH( 'Epsilon' )
183:       SAFMIN = DLAMCH( 'Safe minimum' )
184:       SAFE1 = NZ*SAFMIN
185:       SAFE2 = SAFE1 / EPS
186: *
187: *     Do for each right hand side
188: *
189:       DO 140 J = 1, NRHS
190: *
191:          COUNT = 1
192:          LSTRES = THREE
193:    20    CONTINUE
194: *
195: *        Loop until stopping criterion is satisfied.
196: *
197: *        Compute residual R = B - op(A) * X,
198: *        where op(A) = A, A**T, or A**H, depending on TRANS.
199: *
200:          CALL DCOPY( N, B( 1, J ), 1, WORK( N+1 ), 1 )
201:          CALL DGEMV( TRANS, N, N, -ONE, A, LDA, X( 1, J ), 1, ONE,
202:      $               WORK( N+1 ), 1 )
203: *
204: *        Compute componentwise relative backward error from formula
205: *
206: *        max(i) ( abs(R(i)) / ( abs(op(A))*abs(X) + abs(B) )(i) )
207: *
208: *        where abs(Z) is the componentwise absolute value of the matrix
209: *        or vector Z.  If the i-th component of the denominator is less
210: *        than SAFE2, then SAFE1 is added to the i-th components of the
211: *        numerator and denominator before dividing.
212: *
213:          DO 30 I = 1, N
214:             WORK( I ) = ABS( B( I, J ) )
215:    30    CONTINUE
216: *
217: *        Compute abs(op(A))*abs(X) + abs(B).
218: *
219:          IF( NOTRAN ) THEN
220:             DO 50 K = 1, N
221:                XK = ABS( X( K, J ) )
222:                DO 40 I = 1, N
223:                   WORK( I ) = WORK( I ) + ABS( A( I, K ) )*XK
224:    40          CONTINUE
225:    50       CONTINUE
226:          ELSE
227:             DO 70 K = 1, N
228:                S = ZERO
229:                DO 60 I = 1, N
230:                   S = S + ABS( A( I, K ) )*ABS( X( I, J ) )
231:    60          CONTINUE
232:                WORK( K ) = WORK( K ) + S
233:    70       CONTINUE
234:          END IF
235:          S = ZERO
236:          DO 80 I = 1, N
237:             IF( WORK( I ).GT.SAFE2 ) THEN
238:                S = MAX( S, ABS( WORK( N+I ) ) / WORK( I ) )
239:             ELSE
240:                S = MAX( S, ( ABS( WORK( N+I ) )+SAFE1 ) /
241:      $             ( WORK( I )+SAFE1 ) )
242:             END IF
243:    80    CONTINUE
244:          BERR( J ) = S
245: *
246: *        Test stopping criterion. Continue iterating if
247: *           1) The residual BERR(J) is larger than machine epsilon, and
248: *           2) BERR(J) decreased by at least a factor of 2 during the
249: *              last iteration, and
250: *           3) At most ITMAX iterations tried.
251: *
252:          IF( BERR( J ).GT.EPS .AND. TWO*BERR( J ).LE.LSTRES .AND.
253:      $       COUNT.LE.ITMAX ) THEN
254: *
255: *           Update solution and try again.
256: *
257:             CALL DGETRS( TRANS, N, 1, AF, LDAF, IPIV, WORK( N+1 ), N,
258:      $                   INFO )
259:             CALL DAXPY( N, ONE, WORK( N+1 ), 1, X( 1, J ), 1 )
260:             LSTRES = BERR( J )
261:             COUNT = COUNT + 1
262:             GO TO 20
263:          END IF
264: *
265: *        Bound error from formula
266: *
267: *        norm(X - XTRUE) / norm(X) .le. FERR =
268: *        norm( abs(inv(op(A)))*
269: *           ( abs(R) + NZ*EPS*( abs(op(A))*abs(X)+abs(B) ))) / norm(X)
270: *
271: *        where
272: *          norm(Z) is the magnitude of the largest component of Z
273: *          inv(op(A)) is the inverse of op(A)
274: *          abs(Z) is the componentwise absolute value of the matrix or
275: *             vector Z
276: *          NZ is the maximum number of nonzeros in any row of A, plus 1
277: *          EPS is machine epsilon
278: *
279: *        The i-th component of abs(R)+NZ*EPS*(abs(op(A))*abs(X)+abs(B))
280: *        is incremented by SAFE1 if the i-th component of
281: *        abs(op(A))*abs(X) + abs(B) is less than SAFE2.
282: *
283: *        Use DLACN2 to estimate the infinity-norm of the matrix
284: *           inv(op(A)) * diag(W),
285: *        where W = abs(R) + NZ*EPS*( abs(op(A))*abs(X)+abs(B) )))
286: *
287:          DO 90 I = 1, N
288:             IF( WORK( I ).GT.SAFE2 ) THEN
289:                WORK( I ) = ABS( WORK( N+I ) ) + NZ*EPS*WORK( I )
290:             ELSE
291:                WORK( I ) = ABS( WORK( N+I ) ) + NZ*EPS*WORK( I ) + SAFE1
292:             END IF
293:    90    CONTINUE
294: *
295:          KASE = 0
296:   100    CONTINUE
297:          CALL DLACN2( N, WORK( 2*N+1 ), WORK( N+1 ), IWORK, FERR( J ),
298:      $                KASE, ISAVE )
299:          IF( KASE.NE.0 ) THEN
300:             IF( KASE.EQ.1 ) THEN
301: *
302: *              Multiply by diag(W)*inv(op(A)**T).
303: *
304:                CALL DGETRS( TRANST, N, 1, AF, LDAF, IPIV, WORK( N+1 ),
305:      $                      N, INFO )
306:                DO 110 I = 1, N
307:                   WORK( N+I ) = WORK( I )*WORK( N+I )
308:   110          CONTINUE
309:             ELSE
310: *
311: *              Multiply by inv(op(A))*diag(W).
312: *
313:                DO 120 I = 1, N
314:                   WORK( N+I ) = WORK( I )*WORK( N+I )
315:   120          CONTINUE
316:                CALL DGETRS( TRANS, N, 1, AF, LDAF, IPIV, WORK( N+1 ), N,
317:      $                      INFO )
318:             END IF
319:             GO TO 100
320:          END IF
321: *
322: *        Normalize error.
323: *
324:          LSTRES = ZERO
325:          DO 130 I = 1, N
326:             LSTRES = MAX( LSTRES, ABS( X( I, J ) ) )
327:   130    CONTINUE
328:          IF( LSTRES.NE.ZERO )
329:      $      FERR( J ) = FERR( J ) / LSTRES
330: *
331:   140 CONTINUE
332: *
333:       RETURN
334: *
335: *     End of DGERFS
336: *
337:       END
338: