001:       SUBROUTINE CTRTRI( UPLO, DIAG, N, A, LDA, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
005: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          DIAG, UPLO
010:       INTEGER            INFO, LDA, N
011: *     ..
012: *     .. Array Arguments ..
013:       COMPLEX            A( LDA, * )
014: *     ..
015: *
016: *  Purpose
017: *  =======
018: *
019: *  CTRTRI computes the inverse of a complex upper or lower triangular
020: *  matrix A.
021: *
022: *  This is the Level 3 BLAS version of the algorithm.
023: *
024: *  Arguments
025: *  =========
026: *
027: *  UPLO    (input) CHARACTER*1
028: *          = 'U':  A is upper triangular;
029: *          = 'L':  A is lower triangular.
030: *
031: *  DIAG    (input) CHARACTER*1
032: *          = 'N':  A is non-unit triangular;
033: *          = 'U':  A is unit triangular.
034: *
035: *  N       (input) INTEGER
036: *          The order of the matrix A.  N >= 0.
037: *
038: *  A       (input/output) COMPLEX array, dimension (LDA,N)
039: *          On entry, the triangular matrix A.  If UPLO = 'U', the
040: *          leading N-by-N upper triangular part of the array A contains
041: *          the upper triangular matrix, and the strictly lower
042: *          triangular part of A is not referenced.  If UPLO = 'L', the
043: *          leading N-by-N lower triangular part of the array A contains
044: *          the lower triangular matrix, and the strictly upper
045: *          triangular part of A is not referenced.  If DIAG = 'U', the
046: *          diagonal elements of A are also not referenced and are
047: *          assumed to be 1.
048: *          On exit, the (triangular) inverse of the original matrix, in
049: *          the same storage format.
050: *
051: *  LDA     (input) INTEGER
052: *          The leading dimension of the array A.  LDA >= max(1,N).
053: *
054: *  INFO    (output) INTEGER
055: *          = 0: successful exit
056: *          < 0: if INFO = -i, the i-th argument had an illegal value
057: *          > 0: if INFO = i, A(i,i) is exactly zero.  The triangular
058: *               matrix is singular and its inverse can not be computed.
059: *
060: *  =====================================================================
061: *
062: *     .. Parameters ..
063:       COMPLEX            ONE, ZERO
064:       PARAMETER          ( ONE = ( 1.0E+0, 0.0E+0 ),
065:      $                   ZERO = ( 0.0E+0, 0.0E+0 ) )
066: *     ..
067: *     .. Local Scalars ..
068:       LOGICAL            NOUNIT, UPPER
069:       INTEGER            J, JB, NB, NN
070: *     ..
071: *     .. External Functions ..
072:       LOGICAL            LSAME
073:       INTEGER            ILAENV
074:       EXTERNAL           LSAME, ILAENV
075: *     ..
076: *     .. External Subroutines ..
077:       EXTERNAL           CTRMM, CTRSM, CTRTI2, XERBLA
078: *     ..
079: *     .. Intrinsic Functions ..
080:       INTRINSIC          MAX, MIN
081: *     ..
082: *     .. Executable Statements ..
083: *
084: *     Test the input parameters.
085: *
086:       INFO = 0
087:       UPPER = LSAME( UPLO, 'U' )
088:       NOUNIT = LSAME( DIAG, 'N' )
089:       IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
090:          INFO = -1
091:       ELSE IF( .NOT.NOUNIT .AND. .NOT.LSAME( DIAG, 'U' ) ) THEN
092:          INFO = -2
093:       ELSE IF( N.LT.0 ) THEN
094:          INFO = -3
095:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
096:          INFO = -5
097:       END IF
098:       IF( INFO.NE.0 ) THEN
099:          CALL XERBLA( 'CTRTRI', -INFO )
100:          RETURN
101:       END IF
102: *
103: *     Quick return if possible
104: *
105:       IF( N.EQ.0 )
106:      $   RETURN
107: *
108: *     Check for singularity if non-unit.
109: *
110:       IF( NOUNIT ) THEN
111:          DO 10 INFO = 1, N
112:             IF( A( INFO, INFO ).EQ.ZERO )
113:      $         RETURN
114:    10    CONTINUE
115:          INFO = 0
116:       END IF
117: *
118: *     Determine the block size for this environment.
119: *
120:       NB = ILAENV( 1, 'CTRTRI', UPLO // DIAG, N, -1, -1, -1 )
121:       IF( NB.LE.1 .OR. NB.GE.N ) THEN
122: *
123: *        Use unblocked code
124: *
125:          CALL CTRTI2( UPLO, DIAG, N, A, LDA, INFO )
126:       ELSE
127: *
128: *        Use blocked code
129: *
130:          IF( UPPER ) THEN
131: *
132: *           Compute inverse of upper triangular matrix
133: *
134:             DO 20 J = 1, N, NB
135:                JB = MIN( NB, N-J+1 )
136: *
137: *              Compute rows 1:j-1 of current block column
138: *
139:                CALL CTRMM( 'Left', 'Upper', 'No transpose', DIAG, J-1,
140:      $                     JB, ONE, A, LDA, A( 1, J ), LDA )
141:                CALL CTRSM( 'Right', 'Upper', 'No transpose', DIAG, J-1,
142:      $                     JB, -ONE, A( J, J ), LDA, A( 1, J ), LDA )
143: *
144: *              Compute inverse of current diagonal block
145: *
146:                CALL CTRTI2( 'Upper', DIAG, JB, A( J, J ), LDA, INFO )
147:    20       CONTINUE
148:          ELSE
149: *
150: *           Compute inverse of lower triangular matrix
151: *
152:             NN = ( ( N-1 ) / NB )*NB + 1
153:             DO 30 J = NN, 1, -NB
154:                JB = MIN( NB, N-J+1 )
155:                IF( J+JB.LE.N ) THEN
156: *
157: *                 Compute rows j+jb:n of current block column
158: *
159:                   CALL CTRMM( 'Left', 'Lower', 'No transpose', DIAG,
160:      $                        N-J-JB+1, JB, ONE, A( J+JB, J+JB ), LDA,
161:      $                        A( J+JB, J ), LDA )
162:                   CALL CTRSM( 'Right', 'Lower', 'No transpose', DIAG,
163:      $                        N-J-JB+1, JB, -ONE, A( J, J ), LDA,
164:      $                        A( J+JB, J ), LDA )
165:                END IF
166: *
167: *              Compute inverse of current diagonal block
168: *
169:                CALL CTRTI2( 'Lower', DIAG, JB, A( J, J ), LDA, INFO )
170:    30       CONTINUE
171:          END IF
172:       END IF
173: *
174:       RETURN
175: *
176: *     End of CTRTRI
177: *
178:       END
179: