001:       SUBROUTINE CSYRK(UPLO,TRANS,N,K,ALPHA,A,LDA,BETA,C,LDC)
002: *     .. Scalar Arguments ..
003:       COMPLEX ALPHA,BETA
004:       INTEGER K,LDA,LDC,N
005:       CHARACTER TRANS,UPLO
006: *     ..
007: *     .. Array Arguments ..
008:       COMPLEX A(LDA,*),C(LDC,*)
009: *     ..
010: *
011: *  Purpose
012: *  =======
013: *
014: *  CSYRK  performs one of the symmetric rank k operations
015: *
016: *     C := alpha*A*A' + beta*C,
017: *
018: *  or
019: *
020: *     C := alpha*A'*A + beta*C,
021: *
022: *  where  alpha and beta  are scalars,  C is an  n by n symmetric matrix
023: *  and  A  is an  n by k  matrix in the first case and a  k by n  matrix
024: *  in the second case.
025: *
026: *  Arguments
027: *  ==========
028: *
029: *  UPLO   - CHARACTER*1.
030: *           On  entry,   UPLO  specifies  whether  the  upper  or  lower
031: *           triangular  part  of the  array  C  is to be  referenced  as
032: *           follows:
033: *
034: *              UPLO = 'U' or 'u'   Only the  upper triangular part of  C
035: *                                  is to be referenced.
036: *
037: *              UPLO = 'L' or 'l'   Only the  lower triangular part of  C
038: *                                  is to be referenced.
039: *
040: *           Unchanged on exit.
041: *
042: *  TRANS  - CHARACTER*1.
043: *           On entry,  TRANS  specifies the operation to be performed as
044: *           follows:
045: *
046: *              TRANS = 'N' or 'n'   C := alpha*A*A' + beta*C.
047: *
048: *              TRANS = 'T' or 't'   C := alpha*A'*A + beta*C.
049: *
050: *           Unchanged on exit.
051: *
052: *  N      - INTEGER.
053: *           On entry,  N specifies the order of the matrix C.  N must be
054: *           at least zero.
055: *           Unchanged on exit.
056: *
057: *  K      - INTEGER.
058: *           On entry with  TRANS = 'N' or 'n',  K  specifies  the number
059: *           of  columns   of  the   matrix   A,   and  on   entry   with
060: *           TRANS = 'T' or 't',  K  specifies  the number of rows of the
061: *           matrix A.  K must be at least zero.
062: *           Unchanged on exit.
063: *
064: *  ALPHA  - COMPLEX         .
065: *           On entry, ALPHA specifies the scalar alpha.
066: *           Unchanged on exit.
067: *
068: *  A      - COMPLEX          array of DIMENSION ( LDA, ka ), where ka is
069: *           k  when  TRANS = 'N' or 'n',  and is  n  otherwise.
070: *           Before entry with  TRANS = 'N' or 'n',  the  leading  n by k
071: *           part of the array  A  must contain the matrix  A,  otherwise
072: *           the leading  k by n  part of the array  A  must contain  the
073: *           matrix A.
074: *           Unchanged on exit.
075: *
076: *  LDA    - INTEGER.
077: *           On entry, LDA specifies the first dimension of A as declared
078: *           in  the  calling  (sub)  program.   When  TRANS = 'N' or 'n'
079: *           then  LDA must be at least  max( 1, n ), otherwise  LDA must
080: *           be at least  max( 1, k ).
081: *           Unchanged on exit.
082: *
083: *  BETA   - COMPLEX         .
084: *           On entry, BETA specifies the scalar beta.
085: *           Unchanged on exit.
086: *
087: *  C      - COMPLEX          array of DIMENSION ( LDC, n ).
088: *           Before entry  with  UPLO = 'U' or 'u',  the leading  n by n
089: *           upper triangular part of the array C must contain the upper
090: *           triangular part  of the  symmetric matrix  and the strictly
091: *           lower triangular part of C is not referenced.  On exit, the
092: *           upper triangular part of the array  C is overwritten by the
093: *           upper triangular part of the updated matrix.
094: *           Before entry  with  UPLO = 'L' or 'l',  the leading  n by n
095: *           lower triangular part of the array C must contain the lower
096: *           triangular part  of the  symmetric matrix  and the strictly
097: *           upper triangular part of C is not referenced.  On exit, the
098: *           lower triangular part of the array  C is overwritten by the
099: *           lower triangular part of the updated matrix.
100: *
101: *  LDC    - INTEGER.
102: *           On entry, LDC specifies the first dimension of C as declared
103: *           in  the  calling  (sub)  program.   LDC  must  be  at  least
104: *           max( 1, n ).
105: *           Unchanged on exit.
106: *
107: *  Further Details
108: *  ===============
109: *
110: *  Level 3 Blas routine.
111: *
112: *  -- Written on 8-February-1989.
113: *     Jack Dongarra, Argonne National Laboratory.
114: *     Iain Duff, AERE Harwell.
115: *     Jeremy Du Croz, Numerical Algorithms Group Ltd.
116: *     Sven Hammarling, Numerical Algorithms Group Ltd.
117: *
118: *  =====================================================================
119: *
120: *     .. External Functions ..
121:       LOGICAL LSAME
122:       EXTERNAL LSAME
123: *     ..
124: *     .. External Subroutines ..
125:       EXTERNAL XERBLA
126: *     ..
127: *     .. Intrinsic Functions ..
128:       INTRINSIC MAX
129: *     ..
130: *     .. Local Scalars ..
131:       COMPLEX TEMP
132:       INTEGER I,INFO,J,L,NROWA
133:       LOGICAL UPPER
134: *     ..
135: *     .. Parameters ..
136:       COMPLEX ONE
137:       PARAMETER (ONE= (1.0E+0,0.0E+0))
138:       COMPLEX ZERO
139:       PARAMETER (ZERO= (0.0E+0,0.0E+0))
140: *     ..
141: *
142: *     Test the input parameters.
143: *
144:       IF (LSAME(TRANS,'N')) THEN
145:           NROWA = N
146:       ELSE
147:           NROWA = K
148:       END IF
149:       UPPER = LSAME(UPLO,'U')
150: *
151:       INFO = 0
152:       IF ((.NOT.UPPER) .AND. (.NOT.LSAME(UPLO,'L'))) THEN
153:           INFO = 1
154:       ELSE IF ((.NOT.LSAME(TRANS,'N')) .AND.
155:      +         (.NOT.LSAME(TRANS,'T'))) THEN
156:           INFO = 2
157:       ELSE IF (N.LT.0) THEN
158:           INFO = 3
159:       ELSE IF (K.LT.0) THEN
160:           INFO = 4
161:       ELSE IF (LDA.LT.MAX(1,NROWA)) THEN
162:           INFO = 7
163:       ELSE IF (LDC.LT.MAX(1,N)) THEN
164:           INFO = 10
165:       END IF
166:       IF (INFO.NE.0) THEN
167:           CALL XERBLA('CSYRK ',INFO)
168:           RETURN
169:       END IF
170: *
171: *     Quick return if possible.
172: *
173:       IF ((N.EQ.0) .OR. (((ALPHA.EQ.ZERO).OR.
174:      +    (K.EQ.0)).AND. (BETA.EQ.ONE))) RETURN
175: *
176: *     And when  alpha.eq.zero.
177: *
178:       IF (ALPHA.EQ.ZERO) THEN
179:           IF (UPPER) THEN
180:               IF (BETA.EQ.ZERO) THEN
181:                   DO 20 J = 1,N
182:                       DO 10 I = 1,J
183:                           C(I,J) = ZERO
184:    10                 CONTINUE
185:    20             CONTINUE
186:               ELSE
187:                   DO 40 J = 1,N
188:                       DO 30 I = 1,J
189:                           C(I,J) = BETA*C(I,J)
190:    30                 CONTINUE
191:    40             CONTINUE
192:               END IF
193:           ELSE
194:               IF (BETA.EQ.ZERO) THEN
195:                   DO 60 J = 1,N
196:                       DO 50 I = J,N
197:                           C(I,J) = ZERO
198:    50                 CONTINUE
199:    60             CONTINUE
200:               ELSE
201:                   DO 80 J = 1,N
202:                       DO 70 I = J,N
203:                           C(I,J) = BETA*C(I,J)
204:    70                 CONTINUE
205:    80             CONTINUE
206:               END IF
207:           END IF
208:           RETURN
209:       END IF
210: *
211: *     Start the operations.
212: *
213:       IF (LSAME(TRANS,'N')) THEN
214: *
215: *        Form  C := alpha*A*A' + beta*C.
216: *
217:           IF (UPPER) THEN
218:               DO 130 J = 1,N
219:                   IF (BETA.EQ.ZERO) THEN
220:                       DO 90 I = 1,J
221:                           C(I,J) = ZERO
222:    90                 CONTINUE
223:                   ELSE IF (BETA.NE.ONE) THEN
224:                       DO 100 I = 1,J
225:                           C(I,J) = BETA*C(I,J)
226:   100                 CONTINUE
227:                   END IF
228:                   DO 120 L = 1,K
229:                       IF (A(J,L).NE.ZERO) THEN
230:                           TEMP = ALPHA*A(J,L)
231:                           DO 110 I = 1,J
232:                               C(I,J) = C(I,J) + TEMP*A(I,L)
233:   110                     CONTINUE
234:                       END IF
235:   120             CONTINUE
236:   130         CONTINUE
237:           ELSE
238:               DO 180 J = 1,N
239:                   IF (BETA.EQ.ZERO) THEN
240:                       DO 140 I = J,N
241:                           C(I,J) = ZERO
242:   140                 CONTINUE
243:                   ELSE IF (BETA.NE.ONE) THEN
244:                       DO 150 I = J,N
245:                           C(I,J) = BETA*C(I,J)
246:   150                 CONTINUE
247:                   END IF
248:                   DO 170 L = 1,K
249:                       IF (A(J,L).NE.ZERO) THEN
250:                           TEMP = ALPHA*A(J,L)
251:                           DO 160 I = J,N
252:                               C(I,J) = C(I,J) + TEMP*A(I,L)
253:   160                     CONTINUE
254:                       END IF
255:   170             CONTINUE
256:   180         CONTINUE
257:           END IF
258:       ELSE
259: *
260: *        Form  C := alpha*A'*A + beta*C.
261: *
262:           IF (UPPER) THEN
263:               DO 210 J = 1,N
264:                   DO 200 I = 1,J
265:                       TEMP = ZERO
266:                       DO 190 L = 1,K
267:                           TEMP = TEMP + A(L,I)*A(L,J)
268:   190                 CONTINUE
269:                       IF (BETA.EQ.ZERO) THEN
270:                           C(I,J) = ALPHA*TEMP
271:                       ELSE
272:                           C(I,J) = ALPHA*TEMP + BETA*C(I,J)
273:                       END IF
274:   200             CONTINUE
275:   210         CONTINUE
276:           ELSE
277:               DO 240 J = 1,N
278:                   DO 230 I = J,N
279:                       TEMP = ZERO
280:                       DO 220 L = 1,K
281:                           TEMP = TEMP + A(L,I)*A(L,J)
282:   220                 CONTINUE
283:                       IF (BETA.EQ.ZERO) THEN
284:                           C(I,J) = ALPHA*TEMP
285:                       ELSE
286:                           C(I,J) = ALPHA*TEMP + BETA*C(I,J)
287:                       END IF
288:   230             CONTINUE
289:   240         CONTINUE
290:           END IF
291:       END IF
292: *
293:       RETURN
294: *
295: *     End of CSYRK .
296: *
297:       END
298: