001:       SUBROUTINE CGEQRF( M, N, A, LDA, TAU, WORK, LWORK, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
005: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       INTEGER            INFO, LDA, LWORK, M, N
010: *     ..
011: *     .. Array Arguments ..
012:       COMPLEX            A( LDA, * ), TAU( * ), WORK( * )
013: *     ..
014: *
015: *  Purpose
016: *  =======
017: *
018: *  CGEQRF computes a QR factorization of a complex M-by-N matrix A:
019: *  A = Q * R.
020: *
021: *  Arguments
022: *  =========
023: *
024: *  M       (input) INTEGER
025: *          The number of rows of the matrix A.  M >= 0.
026: *
027: *  N       (input) INTEGER
028: *          The number of columns of the matrix A.  N >= 0.
029: *
030: *  A       (input/output) COMPLEX array, dimension (LDA,N)
031: *          On entry, the M-by-N matrix A.
032: *          On exit, the elements on and above the diagonal of the array
033: *          contain the min(M,N)-by-N upper trapezoidal matrix R (R is
034: *          upper triangular if m >= n); the elements below the diagonal,
035: *          with the array TAU, represent the unitary matrix Q as a
036: *          product of min(m,n) elementary reflectors (see Further
037: *          Details).
038: *
039: *  LDA     (input) INTEGER
040: *          The leading dimension of the array A.  LDA >= max(1,M).
041: *
042: *  TAU     (output) COMPLEX array, dimension (min(M,N))
043: *          The scalar factors of the elementary reflectors (see Further
044: *          Details).
045: *
046: *  WORK    (workspace/output) COMPLEX array, dimension (MAX(1,LWORK))
047: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
048: *
049: *  LWORK   (input) INTEGER
050: *          The dimension of the array WORK.  LWORK >= max(1,N).
051: *          For optimum performance LWORK >= N*NB, where NB is
052: *          the optimal blocksize.
053: *
054: *          If LWORK = -1, then a workspace query is assumed; the routine
055: *          only calculates the optimal size of the WORK array, returns
056: *          this value as the first entry of the WORK array, and no error
057: *          message related to LWORK is issued by XERBLA.
058: *
059: *  INFO    (output) INTEGER
060: *          = 0:  successful exit
061: *          < 0:  if INFO = -i, the i-th argument had an illegal value
062: *
063: *  Further Details
064: *  ===============
065: *
066: *  The matrix Q is represented as a product of elementary reflectors
067: *
068: *     Q = H(1) H(2) . . . H(k), where k = min(m,n).
069: *
070: *  Each H(i) has the form
071: *
072: *     H(i) = I - tau * v * v'
073: *
074: *  where tau is a complex scalar, and v is a complex vector with
075: *  v(1:i-1) = 0 and v(i) = 1; v(i+1:m) is stored on exit in A(i+1:m,i),
076: *  and tau in TAU(i).
077: *
078: *  =====================================================================
079: *
080: *     .. Local Scalars ..
081:       LOGICAL            LQUERY
082:       INTEGER            I, IB, IINFO, IWS, K, LDWORK, LWKOPT, NB,
083:      $                   NBMIN, NX
084: *     ..
085: *     .. External Subroutines ..
086:       EXTERNAL           CGEQR2, CLARFB, CLARFT, XERBLA
087: *     ..
088: *     .. Intrinsic Functions ..
089:       INTRINSIC          MAX, MIN
090: *     ..
091: *     .. External Functions ..
092:       INTEGER            ILAENV
093:       EXTERNAL           ILAENV
094: *     ..
095: *     .. Executable Statements ..
096: *
097: *     Test the input arguments
098: *
099:       INFO = 0
100:       NB = ILAENV( 1, 'CGEQRF', ' ', M, N, -1, -1 )
101:       LWKOPT = N*NB
102:       WORK( 1 ) = LWKOPT
103:       LQUERY = ( LWORK.EQ.-1 )
104:       IF( M.LT.0 ) THEN
105:          INFO = -1
106:       ELSE IF( N.LT.0 ) THEN
107:          INFO = -2
108:       ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
109:          INFO = -4
110:       ELSE IF( LWORK.LT.MAX( 1, N ) .AND. .NOT.LQUERY ) THEN
111:          INFO = -7
112:       END IF
113:       IF( INFO.NE.0 ) THEN
114:          CALL XERBLA( 'CGEQRF', -INFO )
115:          RETURN
116:       ELSE IF( LQUERY ) THEN
117:          RETURN
118:       END IF
119: *
120: *     Quick return if possible
121: *
122:       K = MIN( M, N )
123:       IF( K.EQ.0 ) THEN
124:          WORK( 1 ) = 1
125:          RETURN
126:       END IF
127: *
128:       NBMIN = 2
129:       NX = 0
130:       IWS = N
131:       IF( NB.GT.1 .AND. NB.LT.K ) THEN
132: *
133: *        Determine when to cross over from blocked to unblocked code.
134: *
135:          NX = MAX( 0, ILAENV( 3, 'CGEQRF', ' ', M, N, -1, -1 ) )
136:          IF( NX.LT.K ) THEN
137: *
138: *           Determine if workspace is large enough for blocked code.
139: *
140:             LDWORK = N
141:             IWS = LDWORK*NB
142:             IF( LWORK.LT.IWS ) THEN
143: *
144: *              Not enough workspace to use optimal NB:  reduce NB and
145: *              determine the minimum value of NB.
146: *
147:                NB = LWORK / LDWORK
148:                NBMIN = MAX( 2, ILAENV( 2, 'CGEQRF', ' ', M, N, -1,
149:      $                 -1 ) )
150:             END IF
151:          END IF
152:       END IF
153: *
154:       IF( NB.GE.NBMIN .AND. NB.LT.K .AND. NX.LT.K ) THEN
155: *
156: *        Use blocked code initially
157: *
158:          DO 10 I = 1, K - NX, NB
159:             IB = MIN( K-I+1, NB )
160: *
161: *           Compute the QR factorization of the current block
162: *           A(i:m,i:i+ib-1)
163: *
164:             CALL CGEQR2( M-I+1, IB, A( I, I ), LDA, TAU( I ), WORK,
165:      $                   IINFO )
166:             IF( I+IB.LE.N ) THEN
167: *
168: *              Form the triangular factor of the block reflector
169: *              H = H(i) H(i+1) . . . H(i+ib-1)
170: *
171:                CALL CLARFT( 'Forward', 'Columnwise', M-I+1, IB,
172:      $                      A( I, I ), LDA, TAU( I ), WORK, LDWORK )
173: *
174: *              Apply H' to A(i:m,i+ib:n) from the left
175: *
176:                CALL CLARFB( 'Left', 'Conjugate transpose', 'Forward',
177:      $                      'Columnwise', M-I+1, N-I-IB+1, IB,
178:      $                      A( I, I ), LDA, WORK, LDWORK, A( I, I+IB ),
179:      $                      LDA, WORK( IB+1 ), LDWORK )
180:             END IF
181:    10    CONTINUE
182:       ELSE
183:          I = 1
184:       END IF
185: *
186: *     Use unblocked code to factor the last or only block.
187: *
188:       IF( I.LE.K )
189:      $   CALL CGEQR2( M-I+1, N-I+1, A( I, I ), LDA, TAU( I ), WORK,
190:      $                IINFO )
191: *
192:       WORK( 1 ) = IWS
193:       RETURN
194: *
195: *     End of CGEQRF
196: *
197:       END
198: