01:       COMPLEX FUNCTION CDOTC(N,CX,INCX,CY,INCY)
02: *     .. Scalar Arguments ..
03:       INTEGER INCX,INCY,N
04: *     ..
05: *     .. Array Arguments ..
06:       COMPLEX CX(*),CY(*)
07: *     ..
08: *
09: *  Purpose
10: *  =======
11: *
12: *     forms the dot product of two vectors, conjugating the first
13: *     vector.
14: *
15: *  Further Details
16: *  ===============
17: *
18: *     jack dongarra, linpack,  3/11/78.
19: *     modified 12/3/93, array(1) declarations changed to array(*)
20: *
21: *  =====================================================================
22: *
23: *     .. Local Scalars ..
24:       COMPLEX CTEMP
25:       INTEGER I,IX,IY
26: *     ..
27: *     .. Intrinsic Functions ..
28:       INTRINSIC CONJG
29: *     ..
30:       CTEMP = (0.0,0.0)
31:       CDOTC = (0.0,0.0)
32:       IF (N.LE.0) RETURN
33:       IF (INCX.EQ.1 .AND. INCY.EQ.1) GO TO 20
34: *
35: *        code for unequal increments or equal increments
36: *          not equal to 1
37: *
38:       IX = 1
39:       IY = 1
40:       IF (INCX.LT.0) IX = (-N+1)*INCX + 1
41:       IF (INCY.LT.0) IY = (-N+1)*INCY + 1
42:       DO 10 I = 1,N
43:           CTEMP = CTEMP + CONJG(CX(IX))*CY(IY)
44:           IX = IX + INCX
45:           IY = IY + INCY
46:    10 CONTINUE
47:       CDOTC = CTEMP
48:       RETURN
49: *
50: *        code for both increments equal to 1
51: *
52:    20 DO 30 I = 1,N
53:           CTEMP = CTEMP + CONJG(CX(I))*CY(I)
54:    30 CONTINUE
55:       CDOTC = CTEMP
56:       RETURN
57:       END
58: