001:       SUBROUTINE ZUPGTR( UPLO, N, AP, TAU, Q, LDQ, WORK, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
005: *     November 2006
006: *
007: *     .. Scalar Arguments ..
008:       CHARACTER          UPLO
009:       INTEGER            INFO, LDQ, N
010: *     ..
011: *     .. Array Arguments ..
012:       COMPLEX*16         AP( * ), Q( LDQ, * ), TAU( * ), WORK( * )
013: *     ..
014: *
015: *  Purpose
016: *  =======
017: *
018: *  ZUPGTR generates a complex unitary matrix Q which is defined as the
019: *  product of n-1 elementary reflectors H(i) of order n, as returned by
020: *  ZHPTRD using packed storage:
021: *
022: *  if UPLO = 'U', Q = H(n-1) . . . H(2) H(1),
023: *
024: *  if UPLO = 'L', Q = H(1) H(2) . . . H(n-1).
025: *
026: *  Arguments
027: *  =========
028: *
029: *  UPLO    (input) CHARACTER*1
030: *          = 'U': Upper triangular packed storage used in previous
031: *                 call to ZHPTRD;
032: *          = 'L': Lower triangular packed storage used in previous
033: *                 call to ZHPTRD.
034: *
035: *  N       (input) INTEGER
036: *          The order of the matrix Q. N >= 0.
037: *
038: *  AP      (input) COMPLEX*16 array, dimension (N*(N+1)/2)
039: *          The vectors which define the elementary reflectors, as
040: *          returned by ZHPTRD.
041: *
042: *  TAU     (input) COMPLEX*16 array, dimension (N-1)
043: *          TAU(i) must contain the scalar factor of the elementary
044: *          reflector H(i), as returned by ZHPTRD.
045: *
046: *  Q       (output) COMPLEX*16 array, dimension (LDQ,N)
047: *          The N-by-N unitary matrix Q.
048: *
049: *  LDQ     (input) INTEGER
050: *          The leading dimension of the array Q. LDQ >= max(1,N).
051: *
052: *  WORK    (workspace) COMPLEX*16 array, dimension (N-1)
053: *
054: *  INFO    (output) INTEGER
055: *          = 0:  successful exit
056: *          < 0:  if INFO = -i, the i-th argument had an illegal value
057: *
058: *  =====================================================================
059: *
060: *     .. Parameters ..
061:       COMPLEX*16         CZERO, CONE
062:       PARAMETER          ( CZERO = ( 0.0D+0, 0.0D+0 ),
063:      $                   CONE = ( 1.0D+0, 0.0D+0 ) )
064: *     ..
065: *     .. Local Scalars ..
066:       LOGICAL            UPPER
067:       INTEGER            I, IINFO, IJ, J
068: *     ..
069: *     .. External Functions ..
070:       LOGICAL            LSAME
071:       EXTERNAL           LSAME
072: *     ..
073: *     .. External Subroutines ..
074:       EXTERNAL           XERBLA, ZUNG2L, ZUNG2R
075: *     ..
076: *     .. Intrinsic Functions ..
077:       INTRINSIC          MAX
078: *     ..
079: *     .. Executable Statements ..
080: *
081: *     Test the input arguments
082: *
083:       INFO = 0
084:       UPPER = LSAME( UPLO, 'U' )
085:       IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
086:          INFO = -1
087:       ELSE IF( N.LT.0 ) THEN
088:          INFO = -2
089:       ELSE IF( LDQ.LT.MAX( 1, N ) ) THEN
090:          INFO = -6
091:       END IF
092:       IF( INFO.NE.0 ) THEN
093:          CALL XERBLA( 'ZUPGTR', -INFO )
094:          RETURN
095:       END IF
096: *
097: *     Quick return if possible
098: *
099:       IF( N.EQ.0 )
100:      $   RETURN
101: *
102:       IF( UPPER ) THEN
103: *
104: *        Q was determined by a call to ZHPTRD with UPLO = 'U'
105: *
106: *        Unpack the vectors which define the elementary reflectors and
107: *        set the last row and column of Q equal to those of the unit
108: *        matrix
109: *
110:          IJ = 2
111:          DO 20 J = 1, N - 1
112:             DO 10 I = 1, J - 1
113:                Q( I, J ) = AP( IJ )
114:                IJ = IJ + 1
115:    10       CONTINUE
116:             IJ = IJ + 2
117:             Q( N, J ) = CZERO
118:    20    CONTINUE
119:          DO 30 I = 1, N - 1
120:             Q( I, N ) = CZERO
121:    30    CONTINUE
122:          Q( N, N ) = CONE
123: *
124: *        Generate Q(1:n-1,1:n-1)
125: *
126:          CALL ZUNG2L( N-1, N-1, N-1, Q, LDQ, TAU, WORK, IINFO )
127: *
128:       ELSE
129: *
130: *        Q was determined by a call to ZHPTRD with UPLO = 'L'.
131: *
132: *        Unpack the vectors which define the elementary reflectors and
133: *        set the first row and column of Q equal to those of the unit
134: *        matrix
135: *
136:          Q( 1, 1 ) = CONE
137:          DO 40 I = 2, N
138:             Q( I, 1 ) = CZERO
139:    40    CONTINUE
140:          IJ = 3
141:          DO 60 J = 2, N
142:             Q( 1, J ) = CZERO
143:             DO 50 I = J + 1, N
144:                Q( I, J ) = AP( IJ )
145:                IJ = IJ + 1
146:    50       CONTINUE
147:             IJ = IJ + 2
148:    60    CONTINUE
149:          IF( N.GT.1 ) THEN
150: *
151: *           Generate Q(2:n,2:n)
152: *
153:             CALL ZUNG2R( N-1, N-1, N-1, Q( 2, 2 ), LDQ, TAU, WORK,
154:      $                   IINFO )
155:          END IF
156:       END IF
157:       RETURN
158: *
159: *     End of ZUPGTR
160: *
161:       END
162: