001:       SUBROUTINE ZUNMRQ( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
002:      $                   WORK, LWORK, INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          SIDE, TRANS
010:       INTEGER            INFO, K, LDA, LDC, LWORK, M, N
011: *     ..
012: *     .. Array Arguments ..
013:       COMPLEX*16         A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
014: *     ..
015: *
016: *  Purpose
017: *  =======
018: *
019: *  ZUNMRQ overwrites the general complex M-by-N matrix C with
020: *
021: *                  SIDE = 'L'     SIDE = 'R'
022: *  TRANS = 'N':      Q * C          C * Q
023: *  TRANS = 'C':      Q**H * C       C * Q**H
024: *
025: *  where Q is a complex unitary matrix defined as the product of k
026: *  elementary reflectors
027: *
028: *        Q = H(1)' H(2)' . . . H(k)'
029: *
030: *  as returned by ZGERQF. Q is of order M if SIDE = 'L' and of order N
031: *  if SIDE = 'R'.
032: *
033: *  Arguments
034: *  =========
035: *
036: *  SIDE    (input) CHARACTER*1
037: *          = 'L': apply Q or Q**H from the Left;
038: *          = 'R': apply Q or Q**H from the Right.
039: *
040: *  TRANS   (input) CHARACTER*1
041: *          = 'N':  No transpose, apply Q;
042: *          = 'C':  Transpose, apply Q**H.
043: *
044: *  M       (input) INTEGER
045: *          The number of rows of the matrix C. M >= 0.
046: *
047: *  N       (input) INTEGER
048: *          The number of columns of the matrix C. N >= 0.
049: *
050: *  K       (input) INTEGER
051: *          The number of elementary reflectors whose product defines
052: *          the matrix Q.
053: *          If SIDE = 'L', M >= K >= 0;
054: *          if SIDE = 'R', N >= K >= 0.
055: *
056: *  A       (input) COMPLEX*16 array, dimension
057: *                               (LDA,M) if SIDE = 'L',
058: *                               (LDA,N) if SIDE = 'R'
059: *          The i-th row must contain the vector which defines the
060: *          elementary reflector H(i), for i = 1,2,...,k, as returned by
061: *          ZGERQF in the last k rows of its array argument A.
062: *          A is modified by the routine but restored on exit.
063: *
064: *  LDA     (input) INTEGER
065: *          The leading dimension of the array A. LDA >= max(1,K).
066: *
067: *  TAU     (input) COMPLEX*16 array, dimension (K)
068: *          TAU(i) must contain the scalar factor of the elementary
069: *          reflector H(i), as returned by ZGERQF.
070: *
071: *  C       (input/output) COMPLEX*16 array, dimension (LDC,N)
072: *          On entry, the M-by-N matrix C.
073: *          On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
074: *
075: *  LDC     (input) INTEGER
076: *          The leading dimension of the array C. LDC >= max(1,M).
077: *
078: *  WORK    (workspace/output) COMPLEX*16 array, dimension (MAX(1,LWORK))
079: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
080: *
081: *  LWORK   (input) INTEGER
082: *          The dimension of the array WORK.
083: *          If SIDE = 'L', LWORK >= max(1,N);
084: *          if SIDE = 'R', LWORK >= max(1,M).
085: *          For optimum performance LWORK >= N*NB if SIDE = 'L', and
086: *          LWORK >= M*NB if SIDE = 'R', where NB is the optimal
087: *          blocksize.
088: *
089: *          If LWORK = -1, then a workspace query is assumed; the routine
090: *          only calculates the optimal size of the WORK array, returns
091: *          this value as the first entry of the WORK array, and no error
092: *          message related to LWORK is issued by XERBLA.
093: *
094: *  INFO    (output) INTEGER
095: *          = 0:  successful exit
096: *          < 0:  if INFO = -i, the i-th argument had an illegal value
097: *
098: *  =====================================================================
099: *
100: *     .. Parameters ..
101:       INTEGER            NBMAX, LDT
102:       PARAMETER          ( NBMAX = 64, LDT = NBMAX+1 )
103: *     ..
104: *     .. Local Scalars ..
105:       LOGICAL            LEFT, LQUERY, NOTRAN
106:       CHARACTER          TRANST
107:       INTEGER            I, I1, I2, I3, IB, IINFO, IWS, LDWORK, LWKOPT,
108:      $                   MI, NB, NBMIN, NI, NQ, NW
109: *     ..
110: *     .. Local Arrays ..
111:       COMPLEX*16         T( LDT, NBMAX )
112: *     ..
113: *     .. External Functions ..
114:       LOGICAL            LSAME
115:       INTEGER            ILAENV
116:       EXTERNAL           LSAME, ILAENV
117: *     ..
118: *     .. External Subroutines ..
119:       EXTERNAL           XERBLA, ZLARFB, ZLARFT, ZUNMR2
120: *     ..
121: *     .. Intrinsic Functions ..
122:       INTRINSIC          MAX, MIN
123: *     ..
124: *     .. Executable Statements ..
125: *
126: *     Test the input arguments
127: *
128:       INFO = 0
129:       LEFT = LSAME( SIDE, 'L' )
130:       NOTRAN = LSAME( TRANS, 'N' )
131:       LQUERY = ( LWORK.EQ.-1 )
132: *
133: *     NQ is the order of Q and NW is the minimum dimension of WORK
134: *
135:       IF( LEFT ) THEN
136:          NQ = M
137:          NW = MAX( 1, N )
138:       ELSE
139:          NQ = N
140:          NW = MAX( 1, M )
141:       END IF
142:       IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
143:          INFO = -1
144:       ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'C' ) ) THEN
145:          INFO = -2
146:       ELSE IF( M.LT.0 ) THEN
147:          INFO = -3
148:       ELSE IF( N.LT.0 ) THEN
149:          INFO = -4
150:       ELSE IF( K.LT.0 .OR. K.GT.NQ ) THEN
151:          INFO = -5
152:       ELSE IF( LDA.LT.MAX( 1, K ) ) THEN
153:          INFO = -7
154:       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
155:          INFO = -10
156:       END IF
157: *
158:       IF( INFO.EQ.0 ) THEN
159:          IF( M.EQ.0 .OR. N.EQ.0 ) THEN
160:             LWKOPT = 1
161:          ELSE
162: *
163: *           Determine the block size.  NB may be at most NBMAX, where
164: *           NBMAX is used to define the local array T.
165: *
166:             NB = MIN( NBMAX, ILAENV( 1, 'ZUNMRQ', SIDE // TRANS, M, N,
167:      $                               K, -1 ) )
168:             LWKOPT = NW*NB
169:          END IF
170:          WORK( 1 ) = LWKOPT
171: *
172:          IF( LWORK.LT.NW .AND. .NOT.LQUERY ) THEN
173:             INFO = -12
174:          END IF
175:       END IF
176: *
177:       IF( INFO.NE.0 ) THEN
178:          CALL XERBLA( 'ZUNMRQ', -INFO )
179:          RETURN
180:       ELSE IF( LQUERY ) THEN
181:          RETURN
182:       END IF
183: *
184: *     Quick return if possible
185: *
186:       IF( M.EQ.0 .OR. N.EQ.0 ) THEN
187:          RETURN
188:       END IF
189: *
190:       NBMIN = 2
191:       LDWORK = NW
192:       IF( NB.GT.1 .AND. NB.LT.K ) THEN
193:          IWS = NW*NB
194:          IF( LWORK.LT.IWS ) THEN
195:             NB = LWORK / LDWORK
196:             NBMIN = MAX( 2, ILAENV( 2, 'ZUNMRQ', SIDE // TRANS, M, N, K,
197:      $              -1 ) )
198:          END IF
199:       ELSE
200:          IWS = NW
201:       END IF
202: *
203:       IF( NB.LT.NBMIN .OR. NB.GE.K ) THEN
204: *
205: *        Use unblocked code
206: *
207:          CALL ZUNMR2( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK,
208:      $                IINFO )
209:       ELSE
210: *
211: *        Use blocked code
212: *
213:          IF( ( LEFT .AND. .NOT.NOTRAN ) .OR.
214:      $       ( .NOT.LEFT .AND. NOTRAN ) ) THEN
215:             I1 = 1
216:             I2 = K
217:             I3 = NB
218:          ELSE
219:             I1 = ( ( K-1 ) / NB )*NB + 1
220:             I2 = 1
221:             I3 = -NB
222:          END IF
223: *
224:          IF( LEFT ) THEN
225:             NI = N
226:          ELSE
227:             MI = M
228:          END IF
229: *
230:          IF( NOTRAN ) THEN
231:             TRANST = 'C'
232:          ELSE
233:             TRANST = 'N'
234:          END IF
235: *
236:          DO 10 I = I1, I2, I3
237:             IB = MIN( NB, K-I+1 )
238: *
239: *           Form the triangular factor of the block reflector
240: *           H = H(i+ib-1) . . . H(i+1) H(i)
241: *
242:             CALL ZLARFT( 'Backward', 'Rowwise', NQ-K+I+IB-1, IB,
243:      $                   A( I, 1 ), LDA, TAU( I ), T, LDT )
244:             IF( LEFT ) THEN
245: *
246: *              H or H' is applied to C(1:m-k+i+ib-1,1:n)
247: *
248:                MI = M - K + I + IB - 1
249:             ELSE
250: *
251: *              H or H' is applied to C(1:m,1:n-k+i+ib-1)
252: *
253:                NI = N - K + I + IB - 1
254:             END IF
255: *
256: *           Apply H or H'
257: *
258:             CALL ZLARFB( SIDE, TRANST, 'Backward', 'Rowwise', MI, NI,
259:      $                   IB, A( I, 1 ), LDA, T, LDT, C, LDC, WORK,
260:      $                   LDWORK )
261:    10    CONTINUE
262:       END IF
263:       WORK( 1 ) = LWKOPT
264:       RETURN
265: *
266: *     End of ZUNMRQ
267: *
268:       END
269: