001:       SUBROUTINE ZUNMHR( SIDE, TRANS, M, N, ILO, IHI, A, LDA, TAU, C,
002:      $                   LDC, WORK, LWORK, INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          SIDE, TRANS
010:       INTEGER            IHI, ILO, INFO, LDA, LDC, LWORK, M, N
011: *     ..
012: *     .. Array Arguments ..
013:       COMPLEX*16         A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
014: *     ..
015: *
016: *  Purpose
017: *  =======
018: *
019: *  ZUNMHR overwrites the general complex M-by-N matrix C with
020: *
021: *                  SIDE = 'L'     SIDE = 'R'
022: *  TRANS = 'N':      Q * C          C * Q
023: *  TRANS = 'C':      Q**H * C       C * Q**H
024: *
025: *  where Q is a complex unitary matrix of order nq, with nq = m if
026: *  SIDE = 'L' and nq = n if SIDE = 'R'. Q is defined as the product of
027: *  IHI-ILO elementary reflectors, as returned by ZGEHRD:
028: *
029: *  Q = H(ilo) H(ilo+1) . . . H(ihi-1).
030: *
031: *  Arguments
032: *  =========
033: *
034: *  SIDE    (input) CHARACTER*1
035: *          = 'L': apply Q or Q**H from the Left;
036: *          = 'R': apply Q or Q**H from the Right.
037: *
038: *  TRANS   (input) CHARACTER*1
039: *          = 'N': apply Q  (No transpose)
040: *          = 'C': apply Q**H (Conjugate transpose)
041: *
042: *  M       (input) INTEGER
043: *          The number of rows of the matrix C. M >= 0.
044: *
045: *  N       (input) INTEGER
046: *          The number of columns of the matrix C. N >= 0.
047: *
048: *  ILO     (input) INTEGER
049: *  IHI     (input) INTEGER
050: *          ILO and IHI must have the same values as in the previous call
051: *          of ZGEHRD. Q is equal to the unit matrix except in the
052: *          submatrix Q(ilo+1:ihi,ilo+1:ihi).
053: *          If SIDE = 'L', then 1 <= ILO <= IHI <= M, if M > 0, and
054: *          ILO = 1 and IHI = 0, if M = 0;
055: *          if SIDE = 'R', then 1 <= ILO <= IHI <= N, if N > 0, and
056: *          ILO = 1 and IHI = 0, if N = 0.
057: *
058: *  A       (input) COMPLEX*16 array, dimension
059: *                               (LDA,M) if SIDE = 'L'
060: *                               (LDA,N) if SIDE = 'R'
061: *          The vectors which define the elementary reflectors, as
062: *          returned by ZGEHRD.
063: *
064: *  LDA     (input) INTEGER
065: *          The leading dimension of the array A.
066: *          LDA >= max(1,M) if SIDE = 'L'; LDA >= max(1,N) if SIDE = 'R'.
067: *
068: *  TAU     (input) COMPLEX*16 array, dimension
069: *                               (M-1) if SIDE = 'L'
070: *                               (N-1) if SIDE = 'R'
071: *          TAU(i) must contain the scalar factor of the elementary
072: *          reflector H(i), as returned by ZGEHRD.
073: *
074: *  C       (input/output) COMPLEX*16 array, dimension (LDC,N)
075: *          On entry, the M-by-N matrix C.
076: *          On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
077: *
078: *  LDC     (input) INTEGER
079: *          The leading dimension of the array C. LDC >= max(1,M).
080: *
081: *  WORK    (workspace/output) COMPLEX*16 array, dimension (MAX(1,LWORK))
082: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
083: *
084: *  LWORK   (input) INTEGER
085: *          The dimension of the array WORK.
086: *          If SIDE = 'L', LWORK >= max(1,N);
087: *          if SIDE = 'R', LWORK >= max(1,M).
088: *          For optimum performance LWORK >= N*NB if SIDE = 'L', and
089: *          LWORK >= M*NB if SIDE = 'R', where NB is the optimal
090: *          blocksize.
091: *
092: *          If LWORK = -1, then a workspace query is assumed; the routine
093: *          only calculates the optimal size of the WORK array, returns
094: *          this value as the first entry of the WORK array, and no error
095: *          message related to LWORK is issued by XERBLA.
096: *
097: *  INFO    (output) INTEGER
098: *          = 0:  successful exit
099: *          < 0:  if INFO = -i, the i-th argument had an illegal value
100: *
101: *  =====================================================================
102: *
103: *     .. Local Scalars ..
104:       LOGICAL            LEFT, LQUERY
105:       INTEGER            I1, I2, IINFO, LWKOPT, MI, NB, NH, NI, NQ, NW
106: *     ..
107: *     .. External Functions ..
108:       LOGICAL            LSAME
109:       INTEGER            ILAENV
110:       EXTERNAL           LSAME, ILAENV
111: *     ..
112: *     .. External Subroutines ..
113:       EXTERNAL           XERBLA, ZUNMQR
114: *     ..
115: *     .. Intrinsic Functions ..
116:       INTRINSIC          MAX, MIN
117: *     ..
118: *     .. Executable Statements ..
119: *
120: *     Test the input arguments
121: *
122:       INFO = 0
123:       NH = IHI - ILO
124:       LEFT = LSAME( SIDE, 'L' )
125:       LQUERY = ( LWORK.EQ.-1 )
126: *
127: *     NQ is the order of Q and NW is the minimum dimension of WORK
128: *
129:       IF( LEFT ) THEN
130:          NQ = M
131:          NW = N
132:       ELSE
133:          NQ = N
134:          NW = M
135:       END IF
136:       IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
137:          INFO = -1
138:       ELSE IF( .NOT.LSAME( TRANS, 'N' ) .AND. .NOT.LSAME( TRANS, 'C' ) )
139:      $          THEN
140:          INFO = -2
141:       ELSE IF( M.LT.0 ) THEN
142:          INFO = -3
143:       ELSE IF( N.LT.0 ) THEN
144:          INFO = -4
145:       ELSE IF( ILO.LT.1 .OR. ILO.GT.MAX( 1, NQ ) ) THEN
146:          INFO = -5
147:       ELSE IF( IHI.LT.MIN( ILO, NQ ) .OR. IHI.GT.NQ ) THEN
148:          INFO = -6
149:       ELSE IF( LDA.LT.MAX( 1, NQ ) ) THEN
150:          INFO = -8
151:       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
152:          INFO = -11
153:       ELSE IF( LWORK.LT.MAX( 1, NW ) .AND. .NOT.LQUERY ) THEN
154:          INFO = -13
155:       END IF
156: *
157:       IF( INFO.EQ.0 ) THEN
158:          IF( LEFT ) THEN
159:             NB = ILAENV( 1, 'ZUNMQR', SIDE // TRANS, NH, N, NH, -1 )
160:          ELSE
161:             NB = ILAENV( 1, 'ZUNMQR', SIDE // TRANS, M, NH, NH, -1 )
162:          END IF
163:          LWKOPT = MAX( 1, NW )*NB
164:          WORK( 1 ) = LWKOPT
165:       END IF
166: *
167:       IF( INFO.NE.0 ) THEN
168:          CALL XERBLA( 'ZUNMHR', -INFO )
169:          RETURN
170:       ELSE IF( LQUERY ) THEN
171:          RETURN
172:       END IF
173: *
174: *     Quick return if possible
175: *
176:       IF( M.EQ.0 .OR. N.EQ.0 .OR. NH.EQ.0 ) THEN
177:          WORK( 1 ) = 1
178:          RETURN
179:       END IF
180: *
181:       IF( LEFT ) THEN
182:          MI = NH
183:          NI = N
184:          I1 = ILO + 1
185:          I2 = 1
186:       ELSE
187:          MI = M
188:          NI = NH
189:          I1 = 1
190:          I2 = ILO + 1
191:       END IF
192: *
193:       CALL ZUNMQR( SIDE, TRANS, MI, NI, NH, A( ILO+1, ILO ), LDA,
194:      $             TAU( ILO ), C( I1, I2 ), LDC, WORK, LWORK, IINFO )
195: *
196:       WORK( 1 ) = LWKOPT
197:       RETURN
198: *
199: *     End of ZUNMHR
200: *
201:       END
202: