001:       SUBROUTINE ZLARZB( SIDE, TRANS, DIRECT, STOREV, M, N, K, L, V,
002:      $                   LDV, T, LDT, C, LDC, WORK, LDWORK )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          DIRECT, SIDE, STOREV, TRANS
010:       INTEGER            K, L, LDC, LDT, LDV, LDWORK, M, N
011: *     ..
012: *     .. Array Arguments ..
013:       COMPLEX*16         C( LDC, * ), T( LDT, * ), V( LDV, * ),
014:      $                   WORK( LDWORK, * )
015: *     ..
016: *
017: *  Purpose
018: *  =======
019: *
020: *  ZLARZB applies a complex block reflector H or its transpose H**H
021: *  to a complex distributed M-by-N  C from the left or the right.
022: *
023: *  Currently, only STOREV = 'R' and DIRECT = 'B' are supported.
024: *
025: *  Arguments
026: *  =========
027: *
028: *  SIDE    (input) CHARACTER*1
029: *          = 'L': apply H or H' from the Left
030: *          = 'R': apply H or H' from the Right
031: *
032: *  TRANS   (input) CHARACTER*1
033: *          = 'N': apply H (No transpose)
034: *          = 'C': apply H' (Conjugate transpose)
035: *
036: *  DIRECT  (input) CHARACTER*1
037: *          Indicates how H is formed from a product of elementary
038: *          reflectors
039: *          = 'F': H = H(1) H(2) . . . H(k) (Forward, not supported yet)
040: *          = 'B': H = H(k) . . . H(2) H(1) (Backward)
041: *
042: *  STOREV  (input) CHARACTER*1
043: *          Indicates how the vectors which define the elementary
044: *          reflectors are stored:
045: *          = 'C': Columnwise                        (not supported yet)
046: *          = 'R': Rowwise
047: *
048: *  M       (input) INTEGER
049: *          The number of rows of the matrix C.
050: *
051: *  N       (input) INTEGER
052: *          The number of columns of the matrix C.
053: *
054: *  K       (input) INTEGER
055: *          The order of the matrix T (= the number of elementary
056: *          reflectors whose product defines the block reflector).
057: *
058: *  L       (input) INTEGER
059: *          The number of columns of the matrix V containing the
060: *          meaningful part of the Householder reflectors.
061: *          If SIDE = 'L', M >= L >= 0, if SIDE = 'R', N >= L >= 0.
062: *
063: *  V       (input) COMPLEX*16 array, dimension (LDV,NV).
064: *          If STOREV = 'C', NV = K; if STOREV = 'R', NV = L.
065: *
066: *  LDV     (input) INTEGER
067: *          The leading dimension of the array V.
068: *          If STOREV = 'C', LDV >= L; if STOREV = 'R', LDV >= K.
069: *
070: *  T       (input) COMPLEX*16 array, dimension (LDT,K)
071: *          The triangular K-by-K matrix T in the representation of the
072: *          block reflector.
073: *
074: *  LDT     (input) INTEGER
075: *          The leading dimension of the array T. LDT >= K.
076: *
077: *  C       (input/output) COMPLEX*16 array, dimension (LDC,N)
078: *          On entry, the M-by-N matrix C.
079: *          On exit, C is overwritten by H*C or H'*C or C*H or C*H'.
080: *
081: *  LDC     (input) INTEGER
082: *          The leading dimension of the array C. LDC >= max(1,M).
083: *
084: *  WORK    (workspace) COMPLEX*16 array, dimension (LDWORK,K)
085: *
086: *  LDWORK  (input) INTEGER
087: *          The leading dimension of the array WORK.
088: *          If SIDE = 'L', LDWORK >= max(1,N);
089: *          if SIDE = 'R', LDWORK >= max(1,M).
090: *
091: *  Further Details
092: *  ===============
093: *
094: *  Based on contributions by
095: *    A. Petitet, Computer Science Dept., Univ. of Tenn., Knoxville, USA
096: *
097: *  =====================================================================
098: *
099: *     .. Parameters ..
100:       COMPLEX*16         ONE
101:       PARAMETER          ( ONE = ( 1.0D+0, 0.0D+0 ) )
102: *     ..
103: *     .. Local Scalars ..
104:       CHARACTER          TRANST
105:       INTEGER            I, INFO, J
106: *     ..
107: *     .. External Functions ..
108:       LOGICAL            LSAME
109:       EXTERNAL           LSAME
110: *     ..
111: *     .. External Subroutines ..
112:       EXTERNAL           XERBLA, ZCOPY, ZGEMM, ZLACGV, ZTRMM
113: *     ..
114: *     .. Executable Statements ..
115: *
116: *     Quick return if possible
117: *
118:       IF( M.LE.0 .OR. N.LE.0 )
119:      $   RETURN
120: *
121: *     Check for currently supported options
122: *
123:       INFO = 0
124:       IF( .NOT.LSAME( DIRECT, 'B' ) ) THEN
125:          INFO = -3
126:       ELSE IF( .NOT.LSAME( STOREV, 'R' ) ) THEN
127:          INFO = -4
128:       END IF
129:       IF( INFO.NE.0 ) THEN
130:          CALL XERBLA( 'ZLARZB', -INFO )
131:          RETURN
132:       END IF
133: *
134:       IF( LSAME( TRANS, 'N' ) ) THEN
135:          TRANST = 'C'
136:       ELSE
137:          TRANST = 'N'
138:       END IF
139: *
140:       IF( LSAME( SIDE, 'L' ) ) THEN
141: *
142: *        Form  H * C  or  H' * C
143: *
144: *        W( 1:n, 1:k ) = conjg( C( 1:k, 1:n )' )
145: *
146:          DO 10 J = 1, K
147:             CALL ZCOPY( N, C( J, 1 ), LDC, WORK( 1, J ), 1 )
148:    10    CONTINUE
149: *
150: *        W( 1:n, 1:k ) = W( 1:n, 1:k ) + ...
151: *                        conjg( C( m-l+1:m, 1:n )' ) * V( 1:k, 1:l )'
152: *
153:          IF( L.GT.0 )
154:      $      CALL ZGEMM( 'Transpose', 'Conjugate transpose', N, K, L,
155:      $                  ONE, C( M-L+1, 1 ), LDC, V, LDV, ONE, WORK,
156:      $                  LDWORK )
157: *
158: *        W( 1:n, 1:k ) = W( 1:n, 1:k ) * T'  or  W( 1:m, 1:k ) * T
159: *
160:          CALL ZTRMM( 'Right', 'Lower', TRANST, 'Non-unit', N, K, ONE, T,
161:      $               LDT, WORK, LDWORK )
162: *
163: *        C( 1:k, 1:n ) = C( 1:k, 1:n ) - conjg( W( 1:n, 1:k )' )
164: *
165:          DO 30 J = 1, N
166:             DO 20 I = 1, K
167:                C( I, J ) = C( I, J ) - WORK( J, I )
168:    20       CONTINUE
169:    30    CONTINUE
170: *
171: *        C( m-l+1:m, 1:n ) = C( m-l+1:m, 1:n ) - ...
172: *                    conjg( V( 1:k, 1:l )' ) * conjg( W( 1:n, 1:k )' )
173: *
174:          IF( L.GT.0 )
175:      $      CALL ZGEMM( 'Transpose', 'Transpose', L, N, K, -ONE, V, LDV,
176:      $                  WORK, LDWORK, ONE, C( M-L+1, 1 ), LDC )
177: *
178:       ELSE IF( LSAME( SIDE, 'R' ) ) THEN
179: *
180: *        Form  C * H  or  C * H'
181: *
182: *        W( 1:m, 1:k ) = C( 1:m, 1:k )
183: *
184:          DO 40 J = 1, K
185:             CALL ZCOPY( M, C( 1, J ), 1, WORK( 1, J ), 1 )
186:    40    CONTINUE
187: *
188: *        W( 1:m, 1:k ) = W( 1:m, 1:k ) + ...
189: *                        C( 1:m, n-l+1:n ) * conjg( V( 1:k, 1:l )' )
190: *
191:          IF( L.GT.0 )
192:      $      CALL ZGEMM( 'No transpose', 'Transpose', M, K, L, ONE,
193:      $                  C( 1, N-L+1 ), LDC, V, LDV, ONE, WORK, LDWORK )
194: *
195: *        W( 1:m, 1:k ) = W( 1:m, 1:k ) * conjg( T )  or
196: *                        W( 1:m, 1:k ) * conjg( T' )
197: *
198:          DO 50 J = 1, K
199:             CALL ZLACGV( K-J+1, T( J, J ), 1 )
200:    50    CONTINUE
201:          CALL ZTRMM( 'Right', 'Lower', TRANS, 'Non-unit', M, K, ONE, T,
202:      $               LDT, WORK, LDWORK )
203:          DO 60 J = 1, K
204:             CALL ZLACGV( K-J+1, T( J, J ), 1 )
205:    60    CONTINUE
206: *
207: *        C( 1:m, 1:k ) = C( 1:m, 1:k ) - W( 1:m, 1:k )
208: *
209:          DO 80 J = 1, K
210:             DO 70 I = 1, M
211:                C( I, J ) = C( I, J ) - WORK( I, J )
212:    70       CONTINUE
213:    80    CONTINUE
214: *
215: *        C( 1:m, n-l+1:n ) = C( 1:m, n-l+1:n ) - ...
216: *                            W( 1:m, 1:k ) * conjg( V( 1:k, 1:l ) )
217: *
218:          DO 90 J = 1, L
219:             CALL ZLACGV( K, V( 1, J ), 1 )
220:    90    CONTINUE
221:          IF( L.GT.0 )
222:      $      CALL ZGEMM( 'No transpose', 'No transpose', M, L, K, -ONE,
223:      $                  WORK, LDWORK, V, LDV, ONE, C( 1, N-L+1 ), LDC )
224:          DO 100 J = 1, L
225:             CALL ZLACGV( K, V( 1, J ), 1 )
226:   100    CONTINUE
227: *
228:       END IF
229: *
230:       RETURN
231: *
232: *     End of ZLARZB
233: *
234:       END
235: