001:       SUBROUTINE ZLA_PORFSX_EXTENDED( PREC_TYPE, UPLO, N, NRHS, A, LDA,
002:      $                                AF, LDAF, COLEQU, C, B, LDB, Y,
003:      $                                LDY, BERR_OUT, N_NORMS, ERRS_N,
004:      $                                ERRS_C, RES, AYB, DY, Y_TAIL,
005:      $                                RCOND, ITHRESH, RTHRESH, DZ_UB,
006:      $                                IGNORE_CWISE, INFO )
007: *
008: *     -- LAPACK routine (version 3.2)                                 --
009: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
010: *     -- Jason Riedy of Univ. of California Berkeley.                 --
011: *     -- November 2008                                                --
012: *
013: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
014: *     -- Univ. of California Berkeley and NAG Ltd.                    --
015: *
016:       IMPLICIT NONE
017: *     ..
018: *     .. Scalar Arguments ..
019:       INTEGER            INFO, LDA, LDAF, LDB, LDY, N, NRHS, PREC_TYPE,
020:      $                   N_NORMS, ITHRESH
021:       CHARACTER          UPLO
022:       LOGICAL            COLEQU, IGNORE_CWISE
023:       DOUBLE PRECISION   RTHRESH, DZ_UB
024: *     ..
025: *     .. Array Arguments ..
026:       COMPLEX*16         A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
027:      $                   Y( LDY, * ), RES( * ), DY( * ), Y_TAIL( * )
028:       DOUBLE PRECISION   C( * ), AYB( * ), RCOND, BERR_OUT( * ),
029:      $                   ERRS_N( NRHS, * ), ERRS_C( NRHS, * )
030: *     ..
031: *     .. Local Scalars ..
032:       INTEGER            UPLO2, CNT, I, J, X_STATE, Z_STATE,
033:      $                   Y_PREC_STATE
034:       DOUBLE PRECISION   YK, DYK, YMIN, NORMY, NORMX, NORMDX, DXRAT,
035:      $                   DZRAT, PREVNORMDX, PREV_DZ_Z, DXRATMAX,
036:      $                   DZRATMAX, DX_X, DZ_Z, FINAL_DX_X, FINAL_DZ_Z,
037:      $                   EPS, HUGEVAL, INCR_THRESH
038:       LOGICAL            INCR_PREC
039:       COMPLEX*16         ZDUM
040: *     ..
041: *     .. Parameters ..
042:       INTEGER            UNSTABLE_STATE, WORKING_STATE, CONV_STATE,
043:      $                   NOPROG_STATE, BASE_RESIDUAL, EXTRA_RESIDUAL,
044:      $                   EXTRA_Y
045:       PARAMETER          ( UNSTABLE_STATE = 0, WORKING_STATE = 1,
046:      $                   CONV_STATE = 2, NOPROG_STATE = 3 )
047:       PARAMETER          ( BASE_RESIDUAL = 0, EXTRA_RESIDUAL = 1,
048:      $                   EXTRA_Y = 2 )
049:       INTEGER            FINAL_NRM_ERR_I, FINAL_CMP_ERR_I, BERR_I
050:       INTEGER            RCOND_I, NRM_RCOND_I, NRM_ERR_I, CMP_RCOND_I
051:       INTEGER            CMP_ERR_I, PIV_GROWTH_I
052:       PARAMETER          ( FINAL_NRM_ERR_I = 1, FINAL_CMP_ERR_I = 2,
053:      $                   BERR_I = 3 )
054:       PARAMETER          ( RCOND_I = 4, NRM_RCOND_I = 5, NRM_ERR_I = 6 )
055:       PARAMETER          ( CMP_RCOND_I = 7, CMP_ERR_I = 8,
056:      $                   PIV_GROWTH_I = 9 )
057:       INTEGER            LA_LINRX_ITREF_I, LA_LINRX_ITHRESH_I,
058:      $                   LA_LINRX_CWISE_I
059:       PARAMETER          ( LA_LINRX_ITREF_I = 1,
060:      $                   LA_LINRX_ITHRESH_I = 2 )
061:       PARAMETER          ( LA_LINRX_CWISE_I = 3 )
062:       INTEGER            LA_LINRX_TRUST_I, LA_LINRX_ERR_I,
063:      $                   LA_LINRX_RCOND_I
064:       PARAMETER          ( LA_LINRX_TRUST_I = 1, LA_LINRX_ERR_I = 2 )
065:       PARAMETER          ( LA_LINRX_RCOND_I = 3 )
066:       INTEGER            LA_LINRX_MAX_N_ERRS
067:       PARAMETER          ( LA_LINRX_MAX_N_ERRS = 3 )
068: *     ..
069: *     .. External Functions ..
070:       LOGICAL            LSAME
071:       EXTERNAL           ILAUPLO
072:       INTEGER            ILAUPLO
073: *     ..
074: *     .. External Subroutines ..
075:       EXTERNAL           ZAXPY, ZCOPY, ZPOTRS, ZHEMV, BLAS_ZHEMV_X,
076:      $                   BLAS_ZHEMV2_X, ZLA_SYAMV, ZLA_WWADDW,
077:      $                   ZLA_LIN_BERR, DLAMCH
078:       DOUBLE PRECISION   DLAMCH
079: *     ..
080: *     .. Intrinsic Functions ..
081:       INTRINSIC          ABS, REAL, DIMAG, MAX, MIN
082: *     ..
083: *     .. Statement Functions ..
084:       DOUBLE PRECISION   CABS1
085: *     ..
086: *     .. Statement Function Definitions ..
087:       CABS1( ZDUM ) = ABS( DBLE( ZDUM ) ) + ABS( DIMAG( ZDUM ) )
088: *     ..
089: *     .. Executable Statements ..
090: *
091:       IF (INFO.NE.0) RETURN
092:       EPS = DLAMCH( 'Epsilon' )
093:       HUGEVAL = DLAMCH( 'Overflow' )
094: *     Force HUGEVAL to Inf
095:       HUGEVAL = HUGEVAL * HUGEVAL
096: *     Using HUGEVAL may lead to spurious underflows.
097:       INCR_THRESH = DBLE(N) * EPS
098: 
099:       IF (LSAME (UPLO, 'L')) THEN
100:          UPLO2 = ILAUPLO( 'L' )
101:       ELSE
102:          UPLO2 = ILAUPLO( 'U' )
103:       ENDIF
104: 
105:       DO J = 1, NRHS
106:          Y_PREC_STATE = EXTRA_RESIDUAL
107:          IF (Y_PREC_STATE .EQ. EXTRA_Y) THEN
108:             DO I = 1, N
109:                Y_TAIL( I ) = 0.0D+0
110:             END DO
111:          END IF
112: 
113:          DXRAT = 0.0D+0
114:          DXRATMAX = 0.0D+0
115:          DZRAT = 0.0D+0
116:          DZRATMAX = 0.0D+0
117:          FINAL_DX_X = HUGEVAL
118:          FINAL_DZ_Z = HUGEVAL
119:          PREVNORMDX = HUGEVAL
120:          PREV_DZ_Z = HUGEVAL
121:          DZ_Z = HUGEVAL
122:          DX_X = HUGEVAL
123: 
124:          X_STATE = WORKING_STATE
125:          Z_STATE = UNSTABLE_STATE
126:          INCR_PREC = .FALSE.
127: 
128:          DO CNT = 1, ITHRESH
129: *
130: *         Compute residual RES = B_s - op(A_s) * Y,
131: *             op(A) = A, A**T, or A**H depending on TRANS (and type).
132: *
133:             CALL ZCOPY( N, B( 1, J ), 1, RES, 1 )
134:             IF (Y_PREC_STATE .EQ. BASE_RESIDUAL) THEN
135:                CALL ZHEMV(UPLO, N, DCMPLX(-1.0D+0), A, LDA, Y(1,J), 1,
136:      $              DCMPLX(1.0D+0), RES, 1)
137:             ELSE IF (Y_PREC_STATE .EQ. EXTRA_RESIDUAL) THEN
138:                CALL BLAS_ZHEMV_X(UPLO2, N, DCMPLX(-1.0D+0), A, LDA,
139:      $              Y( 1, J ), 1, DCMPLX(1.0D+0), RES, 1, PREC_TYPE)
140:             ELSE
141:                CALL BLAS_ZHEMV2_X(UPLO2, N, DCMPLX(-1.0D+0), A, LDA,
142:      $              Y(1, J), Y_TAIL, 1, DCMPLX(1.0D+0), RES, 1, 
143:      $     PREC_TYPE)
144:             END IF
145: 
146: !         XXX: RES is no longer needed.
147:             CALL ZCOPY( N, RES, 1, DY, 1 )
148:             CALL ZPOTRS( UPLO, N, NRHS, AF, LDAF, DY, N, INFO)
149: *
150: *         Calculate relative changes DX_X, DZ_Z and ratios DXRAT, DZRAT.
151: *
152:             NORMX = 0.0D+0
153:             NORMY = 0.0D+0
154:             NORMDX = 0.0D+0
155:             DZ_Z = 0.0D+0
156:             YMIN = HUGEVAL
157: 
158:             DO I = 1, N
159:                YK = CABS1(Y(I, J))
160:                DYK = CABS1(DY(I))
161: 
162:                IF (YK .NE. 0.0D+0) THEN
163:                   DZ_Z = MAX( DZ_Z, DYK / YK )
164:                ELSE IF (DYK .NE. 0.0D+0) THEN
165:                   DZ_Z = HUGEVAL
166:                END IF
167: 
168:                YMIN = MIN( YMIN, YK )
169: 
170:                NORMY = MAX( NORMY, YK )
171: 
172:                IF ( COLEQU ) THEN
173:                   NORMX = MAX(NORMX, YK * C(I))
174:                   NORMDX = MAX(NORMDX, DYK * C(I))
175:                ELSE
176:                   NORMX = NORMY
177:                   NORMDX = MAX(NORMDX, DYK)
178:                END IF
179:             END DO
180: 
181:             IF (NORMX .NE. 0.0D+0) THEN
182:                DX_X = NORMDX / NORMX
183:             ELSE IF (NORMDX .EQ. 0.0D+0) THEN
184:                DX_X = 0.0D+0
185:             ELSE
186:                DX_X = HUGEVAL
187:             END IF
188: 
189:             DXRAT = NORMDX / PREVNORMDX
190:             DZRAT = DZ_Z / PREV_DZ_Z
191: *
192: *         Check termination criteria.
193: *
194:             IF (YMIN*RCOND .LT. INCR_THRESH*NORMY
195:      $           .AND. Y_PREC_STATE .LT. EXTRA_Y)
196:      $           INCR_PREC = .TRUE.
197: 
198:             IF (X_STATE .EQ. NOPROG_STATE .AND. DXRAT .LE. RTHRESH)
199:      $           X_STATE = WORKING_STATE
200:             IF (X_STATE .EQ. WORKING_STATE) THEN
201:                IF (DX_X .LE. EPS) THEN
202:                   X_STATE = CONV_STATE
203:                ELSE IF (DXRAT .GT. RTHRESH) THEN
204:                   IF (Y_PREC_STATE .NE. EXTRA_Y) THEN
205:                      INCR_PREC = .TRUE.
206:                   ELSE
207:                      X_STATE = NOPROG_STATE
208:                   END IF
209:                ELSE
210:                   IF (DXRAT .GT. DXRATMAX) DXRATMAX = DXRAT
211:                END IF
212:                IF (X_STATE .GT. WORKING_STATE) FINAL_DX_X = DX_X
213:             END IF
214: 
215:             IF (Z_STATE .EQ. UNSTABLE_STATE .AND. DZ_Z .LE. DZ_UB)
216:      $           Z_STATE = WORKING_STATE
217:             IF (Z_STATE .EQ. NOPROG_STATE .AND. DZRAT .LE. RTHRESH)
218:      $           Z_STATE = WORKING_STATE
219:             IF (Z_STATE .EQ. WORKING_STATE) THEN
220:                IF (DZ_Z .LE. EPS) THEN
221:                   Z_STATE = CONV_STATE
222:                ELSE IF (DZ_Z .GT. DZ_UB) THEN
223:                   Z_STATE = UNSTABLE_STATE
224:                   DZRATMAX = 0.0D+0
225:                   FINAL_DZ_Z = HUGEVAL
226:                ELSE IF (DZRAT .GT. RTHRESH) THEN
227:                   IF (Y_PREC_STATE .NE. EXTRA_Y) THEN
228:                      INCR_PREC = .TRUE.
229:                   ELSE
230:                      Z_STATE = NOPROG_STATE
231:                   END IF
232:                ELSE
233:                   IF (DZRAT .GT. DZRATMAX) DZRATMAX = DZRAT
234:                END IF
235:                IF (Z_STATE .GT. WORKING_STATE) FINAL_DZ_Z = DZ_Z
236:             END IF
237: 
238:             IF ( X_STATE.NE.WORKING_STATE.AND.
239:      $           (IGNORE_CWISE.OR.Z_STATE.NE.WORKING_STATE) )
240:      $           GOTO 666
241: 
242:             IF (INCR_PREC) THEN
243:                INCR_PREC = .FALSE.
244:                Y_PREC_STATE = Y_PREC_STATE + 1
245:                DO I = 1, N
246:                   Y_TAIL( I ) = 0.0D+0
247:                END DO
248:             END IF
249: 
250:             PREVNORMDX = NORMDX
251:             PREV_DZ_Z = DZ_Z
252: *
253: *           Update soluton.
254: *
255:             IF (Y_PREC_STATE .LT. EXTRA_Y) THEN
256:                CALL ZAXPY( N, DCMPLX(1.0D+0), DY, 1, Y(1,J), 1 )
257:             ELSE
258:                CALL ZLA_WWADDW(N, Y(1,J), Y_TAIL, DY)
259:             END IF
260: 
261:          END DO
262: *        Target of "IF (Z_STOP .AND. X_STOP)".  Sun's f77 won't EXIT.
263:  666     CONTINUE
264: *
265: *     Set final_* when cnt hits ithresh.
266: *
267:          IF (X_STATE .EQ. WORKING_STATE) FINAL_DX_X = DX_X
268:          IF (Z_STATE .EQ. WORKING_STATE) FINAL_DZ_Z = DZ_Z
269: *
270: *     Compute error bounds.
271: *
272:          IF (N_NORMS .GE. 1) THEN
273:             ERRS_N( J, LA_LINRX_ERR_I ) = FINAL_DX_X / (1 - DXRATMAX)
274:          END IF
275:          IF (N_NORMS .GE. 2) THEN
276:             ERRS_C( J, LA_LINRX_ERR_I ) = FINAL_DZ_Z / (1 - DZRATMAX)
277:          END IF
278: *
279: *     Compute componentwise relative backward error from formula
280: *         max(i) ( abs(R(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
281: *     where abs(Z) is the componentwise absolute value of the matrix
282: *     or vector Z.
283: *
284: *        Compute residual RES = B_s - op(A_s) * Y,
285: *            op(A) = A, A**T, or A**H depending on TRANS (and type).
286: *
287:          CALL ZCOPY( N, B( 1, J ), 1, RES, 1 )
288:          CALL ZHEMV(UPLO, N, DCMPLX(-1.0D+0), A, LDA, Y(1,J), 1, 
289:      $        DCMPLX(1.0D+0), RES, 1)
290: 
291:          DO I = 1, N
292:             AYB( I ) = CABS1( B( I, J ) )
293:          END DO
294: *
295: *     Compute abs(op(A_s))*abs(Y) + abs(B_s).
296: *
297:          CALL ZLA_SYAMV (UPLO2, N, 1.0D+0,
298:      $        A, LDA, Y(1, J), 1, 1.0D+0, AYB, 1)
299: 
300:          CALL ZLA_LIN_BERR (N, N, 1, RES, AYB, BERR_OUT(J))
301: *
302: *     End of loop for each RHS.
303: *
304:       END DO
305: *
306:       RETURN
307:       END
308: