001:       SUBROUTINE SSYGS2( ITYPE, UPLO, N, A, LDA, B, LDB, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
005: *     November 2006
006: *
007: *     .. Scalar Arguments ..
008:       CHARACTER          UPLO
009:       INTEGER            INFO, ITYPE, LDA, LDB, N
010: *     ..
011: *     .. Array Arguments ..
012:       REAL               A( LDA, * ), B( LDB, * )
013: *     ..
014: *
015: *  Purpose
016: *  =======
017: *
018: *  SSYGS2 reduces a real symmetric-definite generalized eigenproblem
019: *  to standard form.
020: *
021: *  If ITYPE = 1, the problem is A*x = lambda*B*x,
022: *  and A is overwritten by inv(U')*A*inv(U) or inv(L)*A*inv(L')
023: *
024: *  If ITYPE = 2 or 3, the problem is A*B*x = lambda*x or
025: *  B*A*x = lambda*x, and A is overwritten by U*A*U` or L'*A*L.
026: *
027: *  B must have been previously factorized as U'*U or L*L' by SPOTRF.
028: *
029: *  Arguments
030: *  =========
031: *
032: *  ITYPE   (input) INTEGER
033: *          = 1: compute inv(U')*A*inv(U) or inv(L)*A*inv(L');
034: *          = 2 or 3: compute U*A*U' or L'*A*L.
035: *
036: *  UPLO    (input) CHARACTER*1
037: *          Specifies whether the upper or lower triangular part of the
038: *          symmetric matrix A is stored, and how B has been factorized.
039: *          = 'U':  Upper triangular
040: *          = 'L':  Lower triangular
041: *
042: *  N       (input) INTEGER
043: *          The order of the matrices A and B.  N >= 0.
044: *
045: *  A       (input/output) REAL array, dimension (LDA,N)
046: *          On entry, the symmetric matrix A.  If UPLO = 'U', the leading
047: *          n by n upper triangular part of A contains the upper
048: *          triangular part of the matrix A, and the strictly lower
049: *          triangular part of A is not referenced.  If UPLO = 'L', the
050: *          leading n by n lower triangular part of A contains the lower
051: *          triangular part of the matrix A, and the strictly upper
052: *          triangular part of A is not referenced.
053: *
054: *          On exit, if INFO = 0, the transformed matrix, stored in the
055: *          same format as A.
056: *
057: *  LDA     (input) INTEGER
058: *          The leading dimension of the array A.  LDA >= max(1,N).
059: *
060: *  B       (input) REAL array, dimension (LDB,N)
061: *          The triangular factor from the Cholesky factorization of B,
062: *          as returned by SPOTRF.
063: *
064: *  LDB     (input) INTEGER
065: *          The leading dimension of the array B.  LDB >= max(1,N).
066: *
067: *  INFO    (output) INTEGER
068: *          = 0:  successful exit.
069: *          < 0:  if INFO = -i, the i-th argument had an illegal value.
070: *
071: *  =====================================================================
072: *
073: *     .. Parameters ..
074:       REAL               ONE, HALF
075:       PARAMETER          ( ONE = 1.0, HALF = 0.5 )
076: *     ..
077: *     .. Local Scalars ..
078:       LOGICAL            UPPER
079:       INTEGER            K
080:       REAL               AKK, BKK, CT
081: *     ..
082: *     .. External Subroutines ..
083:       EXTERNAL           SAXPY, SSCAL, SSYR2, STRMV, STRSV, XERBLA
084: *     ..
085: *     .. Intrinsic Functions ..
086:       INTRINSIC          MAX
087: *     ..
088: *     .. External Functions ..
089:       LOGICAL            LSAME
090:       EXTERNAL           LSAME
091: *     ..
092: *     .. Executable Statements ..
093: *
094: *     Test the input parameters.
095: *
096:       INFO = 0
097:       UPPER = LSAME( UPLO, 'U' )
098:       IF( ITYPE.LT.1 .OR. ITYPE.GT.3 ) THEN
099:          INFO = -1
100:       ELSE IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
101:          INFO = -2
102:       ELSE IF( N.LT.0 ) THEN
103:          INFO = -3
104:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
105:          INFO = -5
106:       ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
107:          INFO = -7
108:       END IF
109:       IF( INFO.NE.0 ) THEN
110:          CALL XERBLA( 'SSYGS2', -INFO )
111:          RETURN
112:       END IF
113: *
114:       IF( ITYPE.EQ.1 ) THEN
115:          IF( UPPER ) THEN
116: *
117: *           Compute inv(U')*A*inv(U)
118: *
119:             DO 10 K = 1, N
120: *
121: *              Update the upper triangle of A(k:n,k:n)
122: *
123:                AKK = A( K, K )
124:                BKK = B( K, K )
125:                AKK = AKK / BKK**2
126:                A( K, K ) = AKK
127:                IF( K.LT.N ) THEN
128:                   CALL SSCAL( N-K, ONE / BKK, A( K, K+1 ), LDA )
129:                   CT = -HALF*AKK
130:                   CALL SAXPY( N-K, CT, B( K, K+1 ), LDB, A( K, K+1 ),
131:      $                        LDA )
132:                   CALL SSYR2( UPLO, N-K, -ONE, A( K, K+1 ), LDA,
133:      $                        B( K, K+1 ), LDB, A( K+1, K+1 ), LDA )
134:                   CALL SAXPY( N-K, CT, B( K, K+1 ), LDB, A( K, K+1 ),
135:      $                        LDA )
136:                   CALL STRSV( UPLO, 'Transpose', 'Non-unit', N-K,
137:      $                        B( K+1, K+1 ), LDB, A( K, K+1 ), LDA )
138:                END IF
139:    10       CONTINUE
140:          ELSE
141: *
142: *           Compute inv(L)*A*inv(L')
143: *
144:             DO 20 K = 1, N
145: *
146: *              Update the lower triangle of A(k:n,k:n)
147: *
148:                AKK = A( K, K )
149:                BKK = B( K, K )
150:                AKK = AKK / BKK**2
151:                A( K, K ) = AKK
152:                IF( K.LT.N ) THEN
153:                   CALL SSCAL( N-K, ONE / BKK, A( K+1, K ), 1 )
154:                   CT = -HALF*AKK
155:                   CALL SAXPY( N-K, CT, B( K+1, K ), 1, A( K+1, K ), 1 )
156:                   CALL SSYR2( UPLO, N-K, -ONE, A( K+1, K ), 1,
157:      $                        B( K+1, K ), 1, A( K+1, K+1 ), LDA )
158:                   CALL SAXPY( N-K, CT, B( K+1, K ), 1, A( K+1, K ), 1 )
159:                   CALL STRSV( UPLO, 'No transpose', 'Non-unit', N-K,
160:      $                        B( K+1, K+1 ), LDB, A( K+1, K ), 1 )
161:                END IF
162:    20       CONTINUE
163:          END IF
164:       ELSE
165:          IF( UPPER ) THEN
166: *
167: *           Compute U*A*U'
168: *
169:             DO 30 K = 1, N
170: *
171: *              Update the upper triangle of A(1:k,1:k)
172: *
173:                AKK = A( K, K )
174:                BKK = B( K, K )
175:                CALL STRMV( UPLO, 'No transpose', 'Non-unit', K-1, B,
176:      $                     LDB, A( 1, K ), 1 )
177:                CT = HALF*AKK
178:                CALL SAXPY( K-1, CT, B( 1, K ), 1, A( 1, K ), 1 )
179:                CALL SSYR2( UPLO, K-1, ONE, A( 1, K ), 1, B( 1, K ), 1,
180:      $                     A, LDA )
181:                CALL SAXPY( K-1, CT, B( 1, K ), 1, A( 1, K ), 1 )
182:                CALL SSCAL( K-1, BKK, A( 1, K ), 1 )
183:                A( K, K ) = AKK*BKK**2
184:    30       CONTINUE
185:          ELSE
186: *
187: *           Compute L'*A*L
188: *
189:             DO 40 K = 1, N
190: *
191: *              Update the lower triangle of A(1:k,1:k)
192: *
193:                AKK = A( K, K )
194:                BKK = B( K, K )
195:                CALL STRMV( UPLO, 'Transpose', 'Non-unit', K-1, B, LDB,
196:      $                     A( K, 1 ), LDA )
197:                CT = HALF*AKK
198:                CALL SAXPY( K-1, CT, B( K, 1 ), LDB, A( K, 1 ), LDA )
199:                CALL SSYR2( UPLO, K-1, ONE, A( K, 1 ), LDA, B( K, 1 ),
200:      $                     LDB, A, LDA )
201:                CALL SAXPY( K-1, CT, B( K, 1 ), LDB, A( K, 1 ), LDA )
202:                CALL SSCAL( K-1, BKK, A( K, 1 ), LDA )
203:                A( K, K ) = AKK*BKK**2
204:    40       CONTINUE
205:          END IF
206:       END IF
207:       RETURN
208: *
209: *     End of SSYGS2
210: *
211:       END
212: