001:       SUBROUTINE SLASD0( N, SQRE, D, E, U, LDU, VT, LDVT, SMLSIZ, IWORK,
002:      $                   WORK, INFO )
003: *
004: *  -- LAPACK auxiliary routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       INTEGER            INFO, LDU, LDVT, N, SMLSIZ, SQRE
010: *     ..
011: *     .. Array Arguments ..
012:       INTEGER            IWORK( * )
013:       REAL               D( * ), E( * ), U( LDU, * ), VT( LDVT, * ),
014:      $                   WORK( * )
015: *     ..
016: *
017: *  Purpose
018: *  =======
019: *
020: *  Using a divide and conquer approach, SLASD0 computes the singular
021: *  value decomposition (SVD) of a real upper bidiagonal N-by-M
022: *  matrix B with diagonal D and offdiagonal E, where M = N + SQRE.
023: *  The algorithm computes orthogonal matrices U and VT such that
024: *  B = U * S * VT. The singular values S are overwritten on D.
025: *
026: *  A related subroutine, SLASDA, computes only the singular values,
027: *  and optionally, the singular vectors in compact form.
028: *
029: *  Arguments
030: *  =========
031: *
032: *  N      (input) INTEGER
033: *         On entry, the row dimension of the upper bidiagonal matrix.
034: *         This is also the dimension of the main diagonal array D.
035: *
036: *  SQRE   (input) INTEGER
037: *         Specifies the column dimension of the bidiagonal matrix.
038: *         = 0: The bidiagonal matrix has column dimension M = N;
039: *         = 1: The bidiagonal matrix has column dimension M = N+1;
040: *
041: *  D      (input/output) REAL array, dimension (N)
042: *         On entry D contains the main diagonal of the bidiagonal
043: *         matrix.
044: *         On exit D, if INFO = 0, contains its singular values.
045: *
046: *  E      (input) REAL array, dimension (M-1)
047: *         Contains the subdiagonal entries of the bidiagonal matrix.
048: *         On exit, E has been destroyed.
049: *
050: *  U      (output) REAL array, dimension at least (LDQ, N)
051: *         On exit, U contains the left singular vectors.
052: *
053: *  LDU    (input) INTEGER
054: *         On entry, leading dimension of U.
055: *
056: *  VT     (output) REAL array, dimension at least (LDVT, M)
057: *         On exit, VT' contains the right singular vectors.
058: *
059: *  LDVT   (input) INTEGER
060: *         On entry, leading dimension of VT.
061: *
062: *  SMLSIZ (input) INTEGER
063: *         On entry, maximum size of the subproblems at the
064: *         bottom of the computation tree.
065: *
066: *  IWORK  (workspace) INTEGER array, dimension (8*N)
067: *
068: *  WORK   (workspace) REAL array, dimension (3*M**2+2*M)
069: *
070: *  INFO   (output) INTEGER
071: *          = 0:  successful exit.
072: *          < 0:  if INFO = -i, the i-th argument had an illegal value.
073: *          > 0:  if INFO = 1, an singular value did not converge
074: *
075: *  Further Details
076: *  ===============
077: *
078: *  Based on contributions by
079: *     Ming Gu and Huan Ren, Computer Science Division, University of
080: *     California at Berkeley, USA
081: *
082: *  =====================================================================
083: *
084: *     .. Local Scalars ..
085:       INTEGER            I, I1, IC, IDXQ, IDXQC, IM1, INODE, ITEMP, IWK,
086:      $                   J, LF, LL, LVL, M, NCC, ND, NDB1, NDIML, NDIMR,
087:      $                   NL, NLF, NLP1, NLVL, NR, NRF, NRP1, SQREI
088:       REAL               ALPHA, BETA
089: *     ..
090: *     .. External Subroutines ..
091:       EXTERNAL           SLASD1, SLASDQ, SLASDT, XERBLA
092: *     ..
093: *     .. Executable Statements ..
094: *
095: *     Test the input parameters.
096: *
097:       INFO = 0
098: *
099:       IF( N.LT.0 ) THEN
100:          INFO = -1
101:       ELSE IF( ( SQRE.LT.0 ) .OR. ( SQRE.GT.1 ) ) THEN
102:          INFO = -2
103:       END IF
104: *
105:       M = N + SQRE
106: *
107:       IF( LDU.LT.N ) THEN
108:          INFO = -6
109:       ELSE IF( LDVT.LT.M ) THEN
110:          INFO = -8
111:       ELSE IF( SMLSIZ.LT.3 ) THEN
112:          INFO = -9
113:       END IF
114:       IF( INFO.NE.0 ) THEN
115:          CALL XERBLA( 'SLASD0', -INFO )
116:          RETURN
117:       END IF
118: *
119: *     If the input matrix is too small, call SLASDQ to find the SVD.
120: *
121:       IF( N.LE.SMLSIZ ) THEN
122:          CALL SLASDQ( 'U', SQRE, N, M, N, 0, D, E, VT, LDVT, U, LDU, U,
123:      $                LDU, WORK, INFO )
124:          RETURN
125:       END IF
126: *
127: *     Set up the computation tree.
128: *
129:       INODE = 1
130:       NDIML = INODE + N
131:       NDIMR = NDIML + N
132:       IDXQ = NDIMR + N
133:       IWK = IDXQ + N
134:       CALL SLASDT( N, NLVL, ND, IWORK( INODE ), IWORK( NDIML ),
135:      $             IWORK( NDIMR ), SMLSIZ )
136: *
137: *     For the nodes on bottom level of the tree, solve
138: *     their subproblems by SLASDQ.
139: *
140:       NDB1 = ( ND+1 ) / 2
141:       NCC = 0
142:       DO 30 I = NDB1, ND
143: *
144: *     IC : center row of each node
145: *     NL : number of rows of left  subproblem
146: *     NR : number of rows of right subproblem
147: *     NLF: starting row of the left   subproblem
148: *     NRF: starting row of the right  subproblem
149: *
150:          I1 = I - 1
151:          IC = IWORK( INODE+I1 )
152:          NL = IWORK( NDIML+I1 )
153:          NLP1 = NL + 1
154:          NR = IWORK( NDIMR+I1 )
155:          NRP1 = NR + 1
156:          NLF = IC - NL
157:          NRF = IC + 1
158:          SQREI = 1
159:          CALL SLASDQ( 'U', SQREI, NL, NLP1, NL, NCC, D( NLF ), E( NLF ),
160:      $                VT( NLF, NLF ), LDVT, U( NLF, NLF ), LDU,
161:      $                U( NLF, NLF ), LDU, WORK, INFO )
162:          IF( INFO.NE.0 ) THEN
163:             RETURN
164:          END IF
165:          ITEMP = IDXQ + NLF - 2
166:          DO 10 J = 1, NL
167:             IWORK( ITEMP+J ) = J
168:    10    CONTINUE
169:          IF( I.EQ.ND ) THEN
170:             SQREI = SQRE
171:          ELSE
172:             SQREI = 1
173:          END IF
174:          NRP1 = NR + SQREI
175:          CALL SLASDQ( 'U', SQREI, NR, NRP1, NR, NCC, D( NRF ), E( NRF ),
176:      $                VT( NRF, NRF ), LDVT, U( NRF, NRF ), LDU,
177:      $                U( NRF, NRF ), LDU, WORK, INFO )
178:          IF( INFO.NE.0 ) THEN
179:             RETURN
180:          END IF
181:          ITEMP = IDXQ + IC
182:          DO 20 J = 1, NR
183:             IWORK( ITEMP+J-1 ) = J
184:    20    CONTINUE
185:    30 CONTINUE
186: *
187: *     Now conquer each subproblem bottom-up.
188: *
189:       DO 50 LVL = NLVL, 1, -1
190: *
191: *        Find the first node LF and last node LL on the
192: *        current level LVL.
193: *
194:          IF( LVL.EQ.1 ) THEN
195:             LF = 1
196:             LL = 1
197:          ELSE
198:             LF = 2**( LVL-1 )
199:             LL = 2*LF - 1
200:          END IF
201:          DO 40 I = LF, LL
202:             IM1 = I - 1
203:             IC = IWORK( INODE+IM1 )
204:             NL = IWORK( NDIML+IM1 )
205:             NR = IWORK( NDIMR+IM1 )
206:             NLF = IC - NL
207:             IF( ( SQRE.EQ.0 ) .AND. ( I.EQ.LL ) ) THEN
208:                SQREI = SQRE
209:             ELSE
210:                SQREI = 1
211:             END IF
212:             IDXQC = IDXQ + NLF - 1
213:             ALPHA = D( IC )
214:             BETA = E( IC )
215:             CALL SLASD1( NL, NR, SQREI, D( NLF ), ALPHA, BETA,
216:      $                   U( NLF, NLF ), LDU, VT( NLF, NLF ), LDVT,
217:      $                   IWORK( IDXQC ), IWORK( IWK ), WORK, INFO )
218:             IF( INFO.NE.0 ) THEN
219:                RETURN
220:             END IF
221:    40    CONTINUE
222:    50 CONTINUE
223: *
224:       RETURN
225: *
226: *     End of SLASD0
227: *
228:       END
229: