001:       SUBROUTINE SLA_PORFSX_EXTENDED( PREC_TYPE, UPLO, N, NRHS, A, LDA,
002:      $                                AF, LDAF, COLEQU, C, B, LDB, Y,
003:      $                                LDY, BERR_OUT, N_NORMS, ERRS_N,
004:      $                                ERRS_C, RES, AYB, DY, Y_TAIL,
005:      $                                RCOND, ITHRESH, RTHRESH, DZ_UB,
006:      $                                IGNORE_CWISE, INFO )
007: *
008: *     -- LAPACK routine (version 3.2)                                 --
009: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
010: *     -- Jason Riedy of Univ. of California Berkeley.                 --
011: *     -- November 2008                                                --
012: *
013: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
014: *     -- Univ. of California Berkeley and NAG Ltd.                    --
015: *
016:       IMPLICIT NONE
017: *     ..
018: *     .. Scalar Arguments ..
019:       INTEGER            INFO, LDA, LDAF, LDB, LDY, N, NRHS, PREC_TYPE,
020:      $                   N_NORMS, ITHRESH
021:       CHARACTER          UPLO
022:       LOGICAL            COLEQU, IGNORE_CWISE
023:       REAL               RTHRESH, DZ_UB
024: *     ..
025: *     .. Array Arguments ..
026:       REAL               A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
027:      $                   Y( LDY, * ), RES( * ), DY( * ), Y_TAIL( * )
028:       REAL               C( * ), AYB(*), RCOND, BERR_OUT( * ),
029:      $                   ERRS_N( NRHS, * ), ERRS_C( NRHS, * )
030: *     ..
031: *     .. Local Scalars ..
032:       INTEGER            UPLO2, CNT, I, J, X_STATE, Z_STATE
033:       REAL               YK, DYK, YMIN, NORMY, NORMX, NORMDX, DXRAT,
034:      $                   DZRAT, PREVNORMDX, PREV_DZ_Z, DXRATMAX,
035:      $                   DZRATMAX, DX_X, DZ_Z, FINAL_DX_X, FINAL_DZ_Z,
036:      $                   EPS, HUGEVAL, INCR_THRESH
037:       LOGICAL            INCR_PREC
038: *     ..
039: *     .. Parameters ..
040:       INTEGER           UNSTABLE_STATE, WORKING_STATE, CONV_STATE,
041:      $                  NOPROG_STATE, Y_PREC_STATE, BASE_RESIDUAL,
042:      $                  EXTRA_RESIDUAL, EXTRA_Y
043:       PARAMETER         ( UNSTABLE_STATE = 0, WORKING_STATE = 1,
044:      $                  CONV_STATE = 2, NOPROG_STATE = 3 )
045:       PARAMETER         ( BASE_RESIDUAL = 0, EXTRA_RESIDUAL = 1,
046:      $                  EXTRA_Y = 2 )
047:       INTEGER            FINAL_NRM_ERR_I, FINAL_CMP_ERR_I, BERR_I
048:       INTEGER            RCOND_I, NRM_RCOND_I, NRM_ERR_I, CMP_RCOND_I
049:       INTEGER            CMP_ERR_I, PIV_GROWTH_I
050:       PARAMETER          ( FINAL_NRM_ERR_I = 1, FINAL_CMP_ERR_I = 2,
051:      $                   BERR_I = 3 )
052:       PARAMETER          ( RCOND_I = 4, NRM_RCOND_I = 5, NRM_ERR_I = 6 )
053:       PARAMETER          ( CMP_RCOND_I = 7, CMP_ERR_I = 8,
054:      $                   PIV_GROWTH_I = 9 )
055:       INTEGER            LA_LINRX_ITREF_I, LA_LINRX_ITHRESH_I,
056:      $                   LA_LINRX_CWISE_I
057:       PARAMETER          ( LA_LINRX_ITREF_I = 1,
058:      $                   LA_LINRX_ITHRESH_I = 2 )
059:       PARAMETER          ( LA_LINRX_CWISE_I = 3 )
060:       INTEGER            LA_LINRX_TRUST_I, LA_LINRX_ERR_I,
061:      $                   LA_LINRX_RCOND_I
062:       PARAMETER          ( LA_LINRX_TRUST_I = 1, LA_LINRX_ERR_I = 2 )
063:       PARAMETER          ( LA_LINRX_RCOND_I = 3 )
064:       INTEGER            LA_LINRX_MAX_N_ERRS
065:       PARAMETER          ( LA_LINRX_MAX_N_ERRS = 3 )
066: *     ..
067: *     .. External Functions ..
068:       LOGICAL            LSAME
069:       EXTERNAL           ILAUPLO
070:       INTEGER            ILAUPLO
071: *     ..
072: *     .. External Subroutines ..
073:       EXTERNAL          SAXPY, SCOPY, SPOTRS, SSYMV, BLAS_SSYMV_X,
074:      $                  BLAS_SSYMV2_X, SLA_SYAMV, SLA_WWADDW,
075:      $                  SLA_LIN_BERR
076:       REAL              SLAMCH
077: *     ..
078: *     .. Intrinsic Functions ..
079:       INTRINSIC         ABS, MAX, MIN
080: *     ..
081: *     .. Executable Statements ..
082: *
083:       IF (INFO.NE.0) RETURN
084:       EPS = SLAMCH( 'Epsilon' )
085:       HUGEVAL = SLAMCH( 'Overflow' )
086: *     Force HUGEVAL to Inf
087:       HUGEVAL = HUGEVAL * HUGEVAL
088: *     Using HUGEVAL may lead to spurious underflows.
089:       INCR_THRESH = REAL( N ) * EPS
090: 
091:       IF ( LSAME ( UPLO, 'L' ) ) THEN
092:          UPLO2 = ILAUPLO( 'L' )
093:       ELSE
094:          UPLO2 = ILAUPLO( 'U' )
095:       ENDIF
096: 
097:       DO J = 1, NRHS
098:          Y_PREC_STATE = EXTRA_RESIDUAL
099:          IF ( Y_PREC_STATE .EQ. EXTRA_Y ) THEN
100:             DO I = 1, N
101:                Y_TAIL( I ) = 0.0
102:             END DO
103:          END IF
104: 
105:          DXRAT = 0.0
106:          DXRATMAX = 0.0
107:          DZRAT = 0.0
108:          DZRATMAX = 0.0
109:          FINAL_DX_X = HUGEVAL
110:          FINAL_DZ_Z = HUGEVAL
111:          PREVNORMDX = HUGEVAL
112:          PREV_DZ_Z = HUGEVAL
113:          DZ_Z = HUGEVAL
114:          DX_X = HUGEVAL
115: 
116:          X_STATE = WORKING_STATE
117:          Z_STATE = UNSTABLE_STATE
118:          INCR_PREC = .FALSE.
119: 
120:          DO CNT = 1, ITHRESH
121: *
122: *         Compute residual RES = B_s - op(A_s) * Y,
123: *             op(A) = A, A**T, or A**H depending on TRANS (and type).
124: *
125:             CALL SCOPY( N, B( 1, J ), 1, RES, 1 )
126:             IF ( Y_PREC_STATE .EQ. BASE_RESIDUAL ) THEN
127:                CALL SSYMV( UPLO, N, -1.0, A, LDA, Y(1,J), 1,
128:      $              1.0, RES, 1 )
129:             ELSE IF ( Y_PREC_STATE .EQ. EXTRA_RESIDUAL ) THEN
130:                CALL BLAS_SSYMV_X( UPLO2, N, -1.0, A, LDA,
131:      $              Y( 1, J ), 1, 1.0, RES, 1, PREC_TYPE )
132:             ELSE
133:                CALL BLAS_SSYMV2_X(UPLO2, N, -1.0, A, LDA,
134:      $              Y(1, J), Y_TAIL, 1, 1.0, RES, 1, PREC_TYPE)
135:             END IF
136: 
137: !         XXX: RES is no longer needed.
138:             CALL SCOPY( N, RES, 1, DY, 1 )
139:             CALL SPOTRS( UPLO, N, NRHS, AF, LDAF, DY, N, INFO )
140: *
141: *         Calculate relative changes DX_X, DZ_Z and ratios DXRAT, DZRAT.
142: *
143:             NORMX = 0.0
144:             NORMY = 0.0
145:             NORMDX = 0.0
146:             DZ_Z = 0.0
147:             YMIN = HUGEVAL
148: 
149:             DO I = 1, N
150:                YK = ABS( Y( I, J ) )
151:                DYK = ABS( DY( I ) )
152: 
153:                IF ( YK .NE. 0.0 ) THEN
154:                   DZ_Z = MAX( DZ_Z, DYK / YK )
155:                ELSE IF ( DYK .NE. 0.0 ) THEN
156:                   DZ_Z = HUGEVAL
157:                END IF
158: 
159:                YMIN = MIN( YMIN, YK )
160: 
161:                NORMY = MAX( NORMY, YK )
162: 
163:                IF ( COLEQU ) THEN
164:                   NORMX = MAX( NORMX, YK * C( I ) )
165:                   NORMDX = MAX( NORMDX, DYK * C( I ) )
166:                ELSE
167:                   NORMX = NORMY
168:                   NORMDX = MAX( NORMDX, DYK )
169:                END IF
170:             END DO
171: 
172:             IF ( NORMX .NE. 0.0 ) THEN
173:                DX_X = NORMDX / NORMX
174:             ELSE IF ( NORMDX .EQ. 0.0 ) THEN
175:                DX_X = 0.0
176:             ELSE
177:                DX_X = HUGEVAL
178:             END IF
179: 
180:             DXRAT = NORMDX / PREVNORMDX
181:             DZRAT = DZ_Z / PREV_DZ_Z
182: *
183: *         Check termination criteria.
184: *
185:             IF ( YMIN*RCOND .LT. INCR_THRESH*NORMY
186:      $           .AND. Y_PREC_STATE .LT. EXTRA_Y )
187:      $           INCR_PREC = .TRUE.
188: 
189:             IF ( X_STATE .EQ. NOPROG_STATE .AND. DXRAT .LE. RTHRESH )
190:      $           X_STATE = WORKING_STATE
191:             IF ( X_STATE .EQ. WORKING_STATE ) THEN
192:                IF ( DX_X .LE. EPS ) THEN
193:                   X_STATE = CONV_STATE
194:                ELSE IF ( DXRAT .GT. RTHRESH ) THEN
195:                   IF ( Y_PREC_STATE .NE. EXTRA_Y ) THEN
196:                      INCR_PREC = .TRUE.
197:                   ELSE
198:                      X_STATE = NOPROG_STATE
199:                   END IF
200:                ELSE
201:                   IF ( DXRAT .GT. DXRATMAX ) DXRATMAX = DXRAT
202:                END IF
203:                IF ( X_STATE .GT. WORKING_STATE ) FINAL_DX_X = DX_X
204:             END IF
205: 
206:             IF ( Z_STATE .EQ. UNSTABLE_STATE .AND. DZ_Z .LE. DZ_UB )
207:      $           Z_STATE = WORKING_STATE
208:             IF ( Z_STATE .EQ. NOPROG_STATE .AND. DZRAT .LE. RTHRESH )
209:      $           Z_STATE = WORKING_STATE
210:             IF ( Z_STATE .EQ. WORKING_STATE ) THEN
211:                IF ( DZ_Z .LE. EPS ) THEN
212:                   Z_STATE = CONV_STATE
213:                ELSE IF ( DZ_Z .GT. DZ_UB ) THEN
214:                   Z_STATE = UNSTABLE_STATE
215:                   DZRATMAX = 0.0
216:                   FINAL_DZ_Z = HUGEVAL
217:                ELSE IF ( DZRAT .GT. RTHRESH ) THEN
218:                   IF ( Y_PREC_STATE .NE. EXTRA_Y ) THEN
219:                      INCR_PREC = .TRUE.
220:                   ELSE
221:                      Z_STATE = NOPROG_STATE
222:                   END IF
223:                ELSE
224:                   IF ( DZRAT .GT. DZRATMAX ) DZRATMAX = DZRAT
225:                END IF
226:                IF ( Z_STATE .GT. WORKING_STATE ) FINAL_DZ_Z = DZ_Z
227:             END IF
228: 
229:             IF ( X_STATE.NE.WORKING_STATE.AND.
230:      $           ( IGNORE_CWISE.OR.Z_STATE.NE.WORKING_STATE ) )
231:      $           GOTO 666
232: 
233:             IF ( INCR_PREC ) THEN
234:                INCR_PREC = .FALSE.
235:                Y_PREC_STATE = Y_PREC_STATE + 1
236:                DO I = 1, N
237:                   Y_TAIL( I ) = 0.0
238:                END DO
239:             END IF
240: 
241:             PREVNORMDX = NORMDX
242:             PREV_DZ_Z = DZ_Z
243: *
244: *           Update soluton.
245: *
246:             IF (Y_PREC_STATE .LT. EXTRA_Y) THEN
247:                CALL SAXPY( N, 1.0, DY, 1, Y(1,J), 1 )
248:             ELSE
249:                CALL SLA_WWADDW( N, Y( 1, J ), Y_TAIL, DY )
250:             END IF
251: 
252:          END DO
253: *        Target of "IF (Z_STOP .AND. X_STOP)".  Sun's f77 won't EXIT.
254:  666     CONTINUE
255: *
256: *     Set final_* when cnt hits ithresh.
257: *
258:          IF ( X_STATE .EQ. WORKING_STATE ) FINAL_DX_X = DX_X
259:          IF ( Z_STATE .EQ. WORKING_STATE ) FINAL_DZ_Z = DZ_Z
260: *
261: *     Compute error bounds.
262: *
263:          IF ( N_NORMS .GE. 1 ) THEN
264:             ERRS_N( J, LA_LINRX_ERR_I ) = FINAL_DX_X / (1 - DXRATMAX)
265:          END IF
266:          IF ( N_NORMS .GE. 2 ) THEN
267:             ERRS_C( J, LA_LINRX_ERR_I ) = FINAL_DZ_Z / (1 - DZRATMAX)
268:          END IF
269: *
270: *     Compute componentwise relative backward error from formula
271: *         max(i) ( abs(R(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
272: *     where abs(Z) is the componentwise absolute value of the matrix
273: *     or vector Z.
274: *
275: *        Compute residual RES = B_s - op(A_s) * Y,
276: *            op(A) = A, A**T, or A**H depending on TRANS (and type).
277: *
278:          CALL SCOPY( N, B( 1, J ), 1, RES, 1 )
279:          CALL SSYMV( UPLO, N, -1.0, A, LDA, Y(1,J), 1, 1.0, RES, 1 )
280: 
281:          DO I = 1, N
282:             AYB( I ) = ABS( B( I, J ) )
283:          END DO
284: *
285: *     Compute abs(op(A_s))*abs(Y) + abs(B_s).
286: *
287:          CALL SLA_SYAMV( UPLO2, N, 1.0,
288:      $        A, LDA, Y(1, J), 1, 1.0, AYB, 1 )
289: 
290:          CALL SLA_LIN_BERR( N, N, 1, RES, AYB, BERR_OUT( J ) )
291: *
292: *     End of loop for each RHS.
293: *
294:       END DO
295: *
296:       RETURN
297:       END
298: