001:       SUBROUTINE SLA_GEAMV ( TRANS, M, N, ALPHA, A, LDA, X, INCX, BETA,
002:      $                       Y, INCY )
003: *
004: *     -- LAPACK routine (version 3.2)                                 --
005: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
006: *     -- Jason Riedy of Univ. of California Berkeley.                 --
007: *     -- November 2008                                                --
008: *
009: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
010: *     -- Univ. of California Berkeley and NAG Ltd.                    --
011: *
012:       IMPLICIT NONE
013: *     ..
014: *     .. Scalar Arguments ..
015:       REAL               ALPHA, BETA
016:       INTEGER            INCX, INCY, LDA, M, N, TRANS
017: *     ..
018: *     .. Array Arguments ..
019:       REAL               A( LDA, * ), X( * ), Y( * )
020: *     ..
021: *
022: *  Purpose
023: *  =======
024: *
025: *  SLA_GEAMV  performs one of the matrix-vector operations
026: *
027: *          y := alpha*abs(A)*abs(x) + beta*abs(y),
028: *     or   y := alpha*abs(A)'*abs(x) + beta*abs(y),
029: *
030: *  where alpha and beta are scalars, x and y are vectors and A is an
031: *  m by n matrix.
032: *
033: *  This function is primarily used in calculating error bounds.
034: *  To protect against underflow during evaluation, components in
035: *  the resulting vector are perturbed away from zero by (N+1)
036: *  times the underflow threshold.  To prevent unnecessarily large
037: *  errors for block-structure embedded in general matrices,
038: *  "symbolically" zero components are not perturbed.  A zero
039: *  entry is considered "symbolic" if all multiplications involved
040: *  in computing that entry have at least one zero multiplicand.
041: *
042: *  Parameters
043: *  ==========
044: *
045: *  TRANS  - INTEGER
046: *           On entry, TRANS specifies the operation to be performed as
047: *           follows:
048: *
049: *             BLAS_NO_TRANS      y := alpha*abs(A)*abs(x) + beta*abs(y)
050: *             BLAS_TRANS         y := alpha*abs(A')*abs(x) + beta*abs(y)
051: *             BLAS_CONJ_TRANS    y := alpha*abs(A')*abs(x) + beta*abs(y)
052: *
053: *           Unchanged on exit.
054: *
055: *  M      - INTEGER
056: *           On entry, M specifies the number of rows of the matrix A.
057: *           M must be at least zero.
058: *           Unchanged on exit.
059: *
060: *  N      - INTEGER
061: *           On entry, N specifies the number of columns of the matrix A.
062: *           N must be at least zero.
063: *           Unchanged on exit.
064: *
065: *  ALPHA  - REAL
066: *           On entry, ALPHA specifies the scalar alpha.
067: *           Unchanged on exit.
068: *
069: *  A      - REAL             array of DIMENSION ( LDA, n )
070: *           Before entry, the leading m by n part of the array A must
071: *           contain the matrix of coefficients.
072: *           Unchanged on exit.
073: *
074: *  LDA    - INTEGER
075: *           On entry, LDA specifies the first dimension of A as declared
076: *           in the calling (sub) program. LDA must be at least
077: *           max( 1, m ).
078: *           Unchanged on exit.
079: *
080: *  X      - REAL             array of DIMENSION at least
081: *           ( 1 + ( n - 1 )*abs( INCX ) ) when TRANS = 'N' or 'n'
082: *           and at least
083: *           ( 1 + ( m - 1 )*abs( INCX ) ) otherwise.
084: *           Before entry, the incremented array X must contain the
085: *           vector x.
086: *           Unchanged on exit.
087: *
088: *  INCX   - INTEGER
089: *           On entry, INCX specifies the increment for the elements of
090: *           X. INCX must not be zero.
091: *           Unchanged on exit.
092: *
093: *  BETA   - REAL
094: *           On entry, BETA specifies the scalar beta. When BETA is
095: *           supplied as zero then Y need not be set on input.
096: *           Unchanged on exit.
097: *
098: *  Y      - REAL
099: *           Array of DIMENSION at least
100: *           ( 1 + ( m - 1 )*abs( INCY ) ) when TRANS = 'N' or 'n'
101: *           and at least
102: *           ( 1 + ( n - 1 )*abs( INCY ) ) otherwise.
103: *           Before entry with BETA non-zero, the incremented array Y
104: *           must contain the vector y. On exit, Y is overwritten by the
105: *           updated vector y.
106: *
107: *  INCY   - INTEGER
108: *           On entry, INCY specifies the increment for the elements of
109: *           Y. INCY must not be zero.
110: *           Unchanged on exit.
111: *
112: *  Level 2 Blas routine.
113: *
114: *     ..
115: *     .. Parameters ..
116:       REAL               ONE, ZERO
117:       PARAMETER          ( ONE = 1.0E+0, ZERO = 0.0E+0 )
118: *     ..
119: *     .. Local Scalars ..
120:       LOGICAL            SYMB_ZERO
121:       REAL               TEMP, SAFE1
122:       INTEGER            I, INFO, IY, J, JX, KX, KY, LENX, LENY
123: *     ..
124: *     .. External Subroutines ..
125:       EXTERNAL           XERBLA, SLAMCH
126:       REAL               SLAMCH
127: *     ..
128: *     .. External Functions ..
129:       EXTERNAL           ILATRANS
130:       INTEGER            ILATRANS
131: *     ..
132: *     .. Intrinsic Functions ..
133:       INTRINSIC          MAX, ABS, SIGN
134: *     ..
135: *     .. Executable Statements ..
136: *
137: *     Test the input parameters.
138: *
139:       INFO = 0
140:       IF     ( .NOT.( ( TRANS.EQ.ILATRANS( 'N' ) )
141:      $           .OR. ( TRANS.EQ.ILATRANS( 'T' ) ) 
142:      $           .OR. ( TRANS.EQ.ILATRANS( 'C' ) ) ) ) THEN
143:          INFO = 1
144:       ELSE IF( M.LT.0 )THEN
145:          INFO = 2
146:       ELSE IF( N.LT.0 )THEN
147:          INFO = 3
148:       ELSE IF( LDA.LT.MAX( 1, M ) )THEN
149:          INFO = 6
150:       ELSE IF( INCX.EQ.0 )THEN
151:          INFO = 8
152:       ELSE IF( INCY.EQ.0 )THEN
153:          INFO = 11
154:       END IF
155:       IF( INFO.NE.0 )THEN
156:          CALL XERBLA( 'SLA_GEAMV ', INFO )
157:          RETURN
158:       END IF
159: *
160: *     Quick return if possible.
161: *
162:       IF( ( M.EQ.0 ).OR.( N.EQ.0 ).OR.
163:      $    ( ( ALPHA.EQ.ZERO ).AND.( BETA.EQ.ONE ) ) )
164:      $   RETURN
165: *
166: *     Set  LENX  and  LENY, the lengths of the vectors x and y, and set
167: *     up the start points in  X  and  Y.
168: *
169:       IF( TRANS.EQ.ILATRANS( 'N' ) )THEN
170:          LENX = N
171:          LENY = M
172:       ELSE
173:          LENX = M
174:          LENY = N
175:       END IF
176:       IF( INCX.GT.0 )THEN
177:          KX = 1
178:       ELSE
179:          KX = 1 - ( LENX - 1 )*INCX
180:       END IF
181:       IF( INCY.GT.0 )THEN
182:          KY = 1
183:       ELSE
184:          KY = 1 - ( LENY - 1 )*INCY
185:       END IF
186: *
187: *     Set SAFE1 essentially to be the underflow threshold times the
188: *     number of additions in each row.
189: *
190:       SAFE1 = SLAMCH( 'Safe minimum' )
191:       SAFE1 = (N+1)*SAFE1
192: *
193: *     Form  y := alpha*abs(A)*abs(x) + beta*abs(y).
194: *
195: *     The O(M*N) SYMB_ZERO tests could be replaced by O(N) queries to
196: *     the inexact flag.  Still doesn't help change the iteration order
197: *     to per-column.
198: *
199:       IY = KY
200:       IF ( INCX.EQ.1 ) THEN
201:          DO I = 1, LENY
202:             IF ( BETA .EQ. ZERO ) THEN
203:                SYMB_ZERO = .TRUE.
204:                Y( IY ) = 0.0
205:             ELSE IF ( Y( IY ) .EQ. ZERO ) THEN
206:                SYMB_ZERO = .TRUE.
207:             ELSE
208:                SYMB_ZERO = .FALSE.
209:                Y( IY ) = BETA * ABS( Y( IY ) )
210:             END IF
211:             IF ( ALPHA .NE. ZERO ) THEN
212:                DO J = 1, LENX
213:                   IF( TRANS.EQ.ILATRANS( 'N' ) )THEN
214:                      TEMP = ABS( A( I, J ) )
215:                   ELSE
216:                      TEMP = ABS( A( J, I ) )
217:                   END IF
218: 
219:                   SYMB_ZERO = SYMB_ZERO .AND.
220:      $                 ( X( J ) .EQ. ZERO .OR. TEMP .EQ. ZERO )
221: 
222:                   Y( IY ) = Y( IY ) + ALPHA*ABS( X( J ) )*TEMP
223:                END DO
224:             END IF
225: 
226:             IF ( .NOT.SYMB_ZERO )
227:      $           Y( IY ) = Y( IY ) + SIGN( SAFE1, Y( IY ) )
228: 
229:             IY = IY + INCY
230:          END DO
231:       ELSE
232:          DO I = 1, LENY
233:             IF ( BETA .EQ. ZERO ) THEN
234:                SYMB_ZERO = .TRUE.
235:                Y( IY ) = 0.0
236:             ELSE IF ( Y( IY ) .EQ. ZERO ) THEN
237:                SYMB_ZERO = .TRUE.
238:             ELSE
239:                SYMB_ZERO = .FALSE.
240:                Y( IY ) = BETA * ABS( Y( IY ) )
241:             END IF
242:             IF ( ALPHA .NE. ZERO ) THEN
243:                JX = KX
244:                DO J = 1, LENX
245: 
246:                   IF( TRANS.EQ.ILATRANS( 'N' ) )THEN
247:                      TEMP = ABS( A( I, J ) )
248:                   ELSE
249:                      TEMP = ABS( A( J, I ) )
250:                   END IF
251: 
252:                   SYMB_ZERO = SYMB_ZERO .AND.
253:      $                 ( X( JX ) .EQ. ZERO .OR. TEMP .EQ. ZERO )
254: 
255:                   Y( IY ) = Y( IY ) + ALPHA*ABS( X( JX ) )*TEMP
256:                   JX = JX + INCX
257:                END DO
258:             END IF
259: 
260:             IF (.NOT.SYMB_ZERO)
261:      $           Y( IY ) = Y( IY ) + SIGN( SAFE1, Y( IY ) )
262: 
263:             IY = IY + INCY
264:          END DO
265:       END IF
266: *
267:       RETURN
268: *
269: *     End of SLA_GEAMV
270: *
271:       END
272: