001:       SUBROUTINE SGGSVD( JOBU, JOBV, JOBQ, M, N, P, K, L, A, LDA, B,
002:      $                   LDB, ALPHA, BETA, U, LDU, V, LDV, Q, LDQ, WORK,
003:      $                   IWORK, INFO )
004: *
005: *  -- LAPACK driver routine (version 3.2) --
006: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
007: *     November 2006
008: *
009: *     .. Scalar Arguments ..
010:       CHARACTER          JOBQ, JOBU, JOBV
011:       INTEGER            INFO, K, L, LDA, LDB, LDQ, LDU, LDV, M, N, P
012: *     ..
013: *     .. Array Arguments ..
014:       INTEGER            IWORK( * )
015:       REAL               A( LDA, * ), ALPHA( * ), B( LDB, * ),
016:      $                   BETA( * ), Q( LDQ, * ), U( LDU, * ),
017:      $                   V( LDV, * ), WORK( * )
018: *     ..
019: *
020: *  Purpose
021: *  =======
022: *
023: *  SGGSVD computes the generalized singular value decomposition (GSVD)
024: *  of an M-by-N real matrix A and P-by-N real matrix B:
025: *
026: *      U'*A*Q = D1*( 0 R ),    V'*B*Q = D2*( 0 R )
027: *
028: *  where U, V and Q are orthogonal matrices, and Z' is the transpose
029: *  of Z.  Let K+L = the effective numerical rank of the matrix (A',B')',
030: *  then R is a K+L-by-K+L nonsingular upper triangular matrix, D1 and
031: *  D2 are M-by-(K+L) and P-by-(K+L) "diagonal" matrices and of the
032: *  following structures, respectively:
033: *
034: *  If M-K-L >= 0,
035: *
036: *                      K  L
037: *         D1 =     K ( I  0 )
038: *                  L ( 0  C )
039: *              M-K-L ( 0  0 )
040: *
041: *                    K  L
042: *         D2 =   L ( 0  S )
043: *              P-L ( 0  0 )
044: *
045: *                  N-K-L  K    L
046: *    ( 0 R ) = K (  0   R11  R12 )
047: *              L (  0    0   R22 )
048: *
049: *  where
050: *
051: *    C = diag( ALPHA(K+1), ... , ALPHA(K+L) ),
052: *    S = diag( BETA(K+1),  ... , BETA(K+L) ),
053: *    C**2 + S**2 = I.
054: *
055: *    R is stored in A(1:K+L,N-K-L+1:N) on exit.
056: *
057: *  If M-K-L < 0,
058: *
059: *                    K M-K K+L-M
060: *         D1 =   K ( I  0    0   )
061: *              M-K ( 0  C    0   )
062: *
063: *                      K M-K K+L-M
064: *         D2 =   M-K ( 0  S    0  )
065: *              K+L-M ( 0  0    I  )
066: *                P-L ( 0  0    0  )
067: *
068: *                     N-K-L  K   M-K  K+L-M
069: *    ( 0 R ) =     K ( 0    R11  R12  R13  )
070: *                M-K ( 0     0   R22  R23  )
071: *              K+L-M ( 0     0    0   R33  )
072: *
073: *  where
074: *
075: *    C = diag( ALPHA(K+1), ... , ALPHA(M) ),
076: *    S = diag( BETA(K+1),  ... , BETA(M) ),
077: *    C**2 + S**2 = I.
078: *
079: *    (R11 R12 R13 ) is stored in A(1:M, N-K-L+1:N), and R33 is stored
080: *    ( 0  R22 R23 )
081: *    in B(M-K+1:L,N+M-K-L+1:N) on exit.
082: *
083: *  The routine computes C, S, R, and optionally the orthogonal
084: *  transformation matrices U, V and Q.
085: *
086: *  In particular, if B is an N-by-N nonsingular matrix, then the GSVD of
087: *  A and B implicitly gives the SVD of A*inv(B):
088: *                       A*inv(B) = U*(D1*inv(D2))*V'.
089: *  If ( A',B')' has orthonormal columns, then the GSVD of A and B is
090: *  also equal to the CS decomposition of A and B. Furthermore, the GSVD
091: *  can be used to derive the solution of the eigenvalue problem:
092: *                       A'*A x = lambda* B'*B x.
093: *  In some literature, the GSVD of A and B is presented in the form
094: *                   U'*A*X = ( 0 D1 ),   V'*B*X = ( 0 D2 )
095: *  where U and V are orthogonal and X is nonsingular, D1 and D2 are
096: *  ``diagonal''.  The former GSVD form can be converted to the latter
097: *  form by taking the nonsingular matrix X as
098: *
099: *                       X = Q*( I   0    )
100: *                             ( 0 inv(R) ).
101: *
102: *  Arguments
103: *  =========
104: *
105: *  JOBU    (input) CHARACTER*1
106: *          = 'U':  Orthogonal matrix U is computed;
107: *          = 'N':  U is not computed.
108: *
109: *  JOBV    (input) CHARACTER*1
110: *          = 'V':  Orthogonal matrix V is computed;
111: *          = 'N':  V is not computed.
112: *
113: *  JOBQ    (input) CHARACTER*1
114: *          = 'Q':  Orthogonal matrix Q is computed;
115: *          = 'N':  Q is not computed.
116: *
117: *  M       (input) INTEGER
118: *          The number of rows of the matrix A.  M >= 0.
119: *
120: *  N       (input) INTEGER
121: *          The number of columns of the matrices A and B.  N >= 0.
122: *
123: *  P       (input) INTEGER
124: *          The number of rows of the matrix B.  P >= 0.
125: *
126: *  K       (output) INTEGER
127: *  L       (output) INTEGER
128: *          On exit, K and L specify the dimension of the subblocks
129: *          described in the Purpose section.
130: *          K + L = effective numerical rank of (A',B')'.
131: *
132: *  A       (input/output) REAL array, dimension (LDA,N)
133: *          On entry, the M-by-N matrix A.
134: *          On exit, A contains the triangular matrix R, or part of R.
135: *          See Purpose for details.
136: *
137: *  LDA     (input) INTEGER
138: *          The leading dimension of the array A. LDA >= max(1,M).
139: *
140: *  B       (input/output) REAL array, dimension (LDB,N)
141: *          On entry, the P-by-N matrix B.
142: *          On exit, B contains the triangular matrix R if M-K-L < 0.
143: *          See Purpose for details.
144: *
145: *  LDB     (input) INTEGER
146: *          The leading dimension of the array B. LDB >= max(1,P).
147: *
148: *  ALPHA   (output) REAL array, dimension (N)
149: *  BETA    (output) REAL array, dimension (N)
150: *          On exit, ALPHA and BETA contain the generalized singular
151: *          value pairs of A and B;
152: *            ALPHA(1:K) = 1,
153: *            BETA(1:K)  = 0,
154: *          and if M-K-L >= 0,
155: *            ALPHA(K+1:K+L) = C,
156: *            BETA(K+1:K+L)  = S,
157: *          or if M-K-L < 0,
158: *            ALPHA(K+1:M)=C, ALPHA(M+1:K+L)=0
159: *            BETA(K+1:M) =S, BETA(M+1:K+L) =1
160: *          and
161: *            ALPHA(K+L+1:N) = 0
162: *            BETA(K+L+1:N)  = 0
163: *
164: *  U       (output) REAL array, dimension (LDU,M)
165: *          If JOBU = 'U', U contains the M-by-M orthogonal matrix U.
166: *          If JOBU = 'N', U is not referenced.
167: *
168: *  LDU     (input) INTEGER
169: *          The leading dimension of the array U. LDU >= max(1,M) if
170: *          JOBU = 'U'; LDU >= 1 otherwise.
171: *
172: *  V       (output) REAL array, dimension (LDV,P)
173: *          If JOBV = 'V', V contains the P-by-P orthogonal matrix V.
174: *          If JOBV = 'N', V is not referenced.
175: *
176: *  LDV     (input) INTEGER
177: *          The leading dimension of the array V. LDV >= max(1,P) if
178: *          JOBV = 'V'; LDV >= 1 otherwise.
179: *
180: *  Q       (output) REAL array, dimension (LDQ,N)
181: *          If JOBQ = 'Q', Q contains the N-by-N orthogonal matrix Q.
182: *          If JOBQ = 'N', Q is not referenced.
183: *
184: *  LDQ     (input) INTEGER
185: *          The leading dimension of the array Q. LDQ >= max(1,N) if
186: *          JOBQ = 'Q'; LDQ >= 1 otherwise.
187: *
188: *  WORK    (workspace) REAL array,
189: *                      dimension (max(3*N,M,P)+N)
190: *
191: *  IWORK   (workspace/output) INTEGER array, dimension (N)
192: *          On exit, IWORK stores the sorting information. More
193: *          precisely, the following loop will sort ALPHA
194: *             for I = K+1, min(M,K+L)
195: *                 swap ALPHA(I) and ALPHA(IWORK(I))
196: *             endfor
197: *          such that ALPHA(1) >= ALPHA(2) >= ... >= ALPHA(N).
198: *
199: *  INFO    (output) INTEGER
200: *          = 0:  successful exit
201: *          < 0:  if INFO = -i, the i-th argument had an illegal value.
202: *          > 0:  if INFO = 1, the Jacobi-type procedure failed to
203: *                converge.  For further details, see subroutine STGSJA.
204: *
205: *  Internal Parameters
206: *  ===================
207: *
208: *  TOLA    REAL
209: *  TOLB    REAL
210: *          TOLA and TOLB are the thresholds to determine the effective
211: *          rank of (A',B')'. Generally, they are set to
212: *                   TOLA = MAX(M,N)*norm(A)*MACHEPS,
213: *                   TOLB = MAX(P,N)*norm(B)*MACHEPS.
214: *          The size of TOLA and TOLB may affect the size of backward
215: *          errors of the decomposition.
216: *
217: *  Further Details
218: *  ===============
219: *
220: *  2-96 Based on modifications by
221: *     Ming Gu and Huan Ren, Computer Science Division, University of
222: *     California at Berkeley, USA
223: *
224: *  =====================================================================
225: *
226: *     .. Local Scalars ..
227:       LOGICAL            WANTQ, WANTU, WANTV
228:       INTEGER            I, IBND, ISUB, J, NCYCLE
229:       REAL               ANORM, BNORM, SMAX, TEMP, TOLA, TOLB, ULP, UNFL
230: *     ..
231: *     .. External Functions ..
232:       LOGICAL            LSAME
233:       REAL               SLAMCH, SLANGE
234:       EXTERNAL           LSAME, SLAMCH, SLANGE
235: *     ..
236: *     .. External Subroutines ..
237:       EXTERNAL           SCOPY, SGGSVP, STGSJA, XERBLA
238: *     ..
239: *     .. Intrinsic Functions ..
240:       INTRINSIC          MAX, MIN
241: *     ..
242: *     .. Executable Statements ..
243: *
244: *     Test the input parameters
245: *
246:       WANTU = LSAME( JOBU, 'U' )
247:       WANTV = LSAME( JOBV, 'V' )
248:       WANTQ = LSAME( JOBQ, 'Q' )
249: *
250:       INFO = 0
251:       IF( .NOT.( WANTU .OR. LSAME( JOBU, 'N' ) ) ) THEN
252:          INFO = -1
253:       ELSE IF( .NOT.( WANTV .OR. LSAME( JOBV, 'N' ) ) ) THEN
254:          INFO = -2
255:       ELSE IF( .NOT.( WANTQ .OR. LSAME( JOBQ, 'N' ) ) ) THEN
256:          INFO = -3
257:       ELSE IF( M.LT.0 ) THEN
258:          INFO = -4
259:       ELSE IF( N.LT.0 ) THEN
260:          INFO = -5
261:       ELSE IF( P.LT.0 ) THEN
262:          INFO = -6
263:       ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
264:          INFO = -10
265:       ELSE IF( LDB.LT.MAX( 1, P ) ) THEN
266:          INFO = -12
267:       ELSE IF( LDU.LT.1 .OR. ( WANTU .AND. LDU.LT.M ) ) THEN
268:          INFO = -16
269:       ELSE IF( LDV.LT.1 .OR. ( WANTV .AND. LDV.LT.P ) ) THEN
270:          INFO = -18
271:       ELSE IF( LDQ.LT.1 .OR. ( WANTQ .AND. LDQ.LT.N ) ) THEN
272:          INFO = -20
273:       END IF
274:       IF( INFO.NE.0 ) THEN
275:          CALL XERBLA( 'SGGSVD', -INFO )
276:          RETURN
277:       END IF
278: *
279: *     Compute the Frobenius norm of matrices A and B
280: *
281:       ANORM = SLANGE( '1', M, N, A, LDA, WORK )
282:       BNORM = SLANGE( '1', P, N, B, LDB, WORK )
283: *
284: *     Get machine precision and set up threshold for determining
285: *     the effective numerical rank of the matrices A and B.
286: *
287:       ULP = SLAMCH( 'Precision' )
288:       UNFL = SLAMCH( 'Safe Minimum' )
289:       TOLA = MAX( M, N )*MAX( ANORM, UNFL )*ULP
290:       TOLB = MAX( P, N )*MAX( BNORM, UNFL )*ULP
291: *
292: *     Preprocessing
293: *
294:       CALL SGGSVP( JOBU, JOBV, JOBQ, M, P, N, A, LDA, B, LDB, TOLA,
295:      $             TOLB, K, L, U, LDU, V, LDV, Q, LDQ, IWORK, WORK,
296:      $             WORK( N+1 ), INFO )
297: *
298: *     Compute the GSVD of two upper "triangular" matrices
299: *
300:       CALL STGSJA( JOBU, JOBV, JOBQ, M, P, N, K, L, A, LDA, B, LDB,
301:      $             TOLA, TOLB, ALPHA, BETA, U, LDU, V, LDV, Q, LDQ,
302:      $             WORK, NCYCLE, INFO )
303: *
304: *     Sort the singular values and store the pivot indices in IWORK
305: *     Copy ALPHA to WORK, then sort ALPHA in WORK
306: *
307:       CALL SCOPY( N, ALPHA, 1, WORK, 1 )
308:       IBND = MIN( L, M-K )
309:       DO 20 I = 1, IBND
310: *
311: *        Scan for largest ALPHA(K+I)
312: *
313:          ISUB = I
314:          SMAX = WORK( K+I )
315:          DO 10 J = I + 1, IBND
316:             TEMP = WORK( K+J )
317:             IF( TEMP.GT.SMAX ) THEN
318:                ISUB = J
319:                SMAX = TEMP
320:             END IF
321:    10    CONTINUE
322:          IF( ISUB.NE.I ) THEN
323:             WORK( K+ISUB ) = WORK( K+I )
324:             WORK( K+I ) = SMAX
325:             IWORK( K+I ) = K + ISUB
326:          ELSE
327:             IWORK( K+I ) = K + I
328:          END IF
329:    20 CONTINUE
330: *
331:       RETURN
332: *
333: *     End of SGGSVD
334: *
335:       END
336: