001:       SUBROUTINE SGERQF( M, N, A, LDA, TAU, WORK, LWORK, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
005: *     November 2006
006: *
007: *     .. Scalar Arguments ..
008:       INTEGER            INFO, LDA, LWORK, M, N
009: *     ..
010: *     .. Array Arguments ..
011:       REAL               A( LDA, * ), TAU( * ), WORK( * )
012: *     ..
013: *
014: *  Purpose
015: *  =======
016: *
017: *  SGERQF computes an RQ factorization of a real M-by-N matrix A:
018: *  A = R * Q.
019: *
020: *  Arguments
021: *  =========
022: *
023: *  M       (input) INTEGER
024: *          The number of rows of the matrix A.  M >= 0.
025: *
026: *  N       (input) INTEGER
027: *          The number of columns of the matrix A.  N >= 0.
028: *
029: *  A       (input/output) REAL array, dimension (LDA,N)
030: *          On entry, the M-by-N matrix A.
031: *          On exit,
032: *          if m <= n, the upper triangle of the subarray
033: *          A(1:m,n-m+1:n) contains the M-by-M upper triangular matrix R;
034: *          if m >= n, the elements on and above the (m-n)-th subdiagonal
035: *          contain the M-by-N upper trapezoidal matrix R;
036: *          the remaining elements, with the array TAU, represent the
037: *          orthogonal matrix Q as a product of min(m,n) elementary
038: *          reflectors (see Further Details).
039: *
040: *  LDA     (input) INTEGER
041: *          The leading dimension of the array A.  LDA >= max(1,M).
042: *
043: *  TAU     (output) REAL array, dimension (min(M,N))
044: *          The scalar factors of the elementary reflectors (see Further
045: *          Details).
046: *
047: *  WORK    (workspace/output) REAL array, dimension (MAX(1,LWORK))
048: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
049: *
050: *  LWORK   (input) INTEGER
051: *          The dimension of the array WORK.  LWORK >= max(1,M).
052: *          For optimum performance LWORK >= M*NB, where NB is
053: *          the optimal blocksize.
054: *
055: *          If LWORK = -1, then a workspace query is assumed; the routine
056: *          only calculates the optimal size of the WORK array, returns
057: *          this value as the first entry of the WORK array, and no error
058: *          message related to LWORK is issued by XERBLA.
059: *
060: *  INFO    (output) INTEGER
061: *          = 0:  successful exit
062: *          < 0:  if INFO = -i, the i-th argument had an illegal value
063: *
064: *  Further Details
065: *  ===============
066: *
067: *  The matrix Q is represented as a product of elementary reflectors
068: *
069: *     Q = H(1) H(2) . . . H(k), where k = min(m,n).
070: *
071: *  Each H(i) has the form
072: *
073: *     H(i) = I - tau * v * v'
074: *
075: *  where tau is a real scalar, and v is a real vector with
076: *  v(n-k+i+1:n) = 0 and v(n-k+i) = 1; v(1:n-k+i-1) is stored on exit in
077: *  A(m-k+i,1:n-k+i-1), and tau in TAU(i).
078: *
079: *  =====================================================================
080: *
081: *     .. Local Scalars ..
082:       LOGICAL            LQUERY
083:       INTEGER            I, IB, IINFO, IWS, K, KI, KK, LDWORK, LWKOPT,
084:      $                   MU, NB, NBMIN, NU, NX
085: *     ..
086: *     .. External Subroutines ..
087:       EXTERNAL           SGERQ2, SLARFB, SLARFT, XERBLA
088: *     ..
089: *     .. Intrinsic Functions ..
090:       INTRINSIC          MAX, MIN
091: *     ..
092: *     .. External Functions ..
093:       INTEGER            ILAENV
094:       EXTERNAL           ILAENV
095: *     ..
096: *     .. Executable Statements ..
097: *
098: *     Test the input arguments
099: *
100:       INFO = 0
101:       LQUERY = ( LWORK.EQ.-1 )
102:       IF( M.LT.0 ) THEN
103:          INFO = -1
104:       ELSE IF( N.LT.0 ) THEN
105:          INFO = -2
106:       ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
107:          INFO = -4
108:       ELSE IF( LWORK.LT.MAX( 1, M ) .AND. .NOT.LQUERY ) THEN
109:          INFO = -7
110:       END IF
111: *
112:       IF( INFO.EQ.0 ) THEN
113:          K = MIN( M, N )
114:          IF( K.EQ.0 ) THEN
115:             LWKOPT = 1
116:          ELSE
117:             NB = ILAENV( 1, 'SGERQF', ' ', M, N, -1, -1 )
118:             LWKOPT = M*NB
119:             WORK( 1 ) = LWKOPT
120:          END IF
121:          WORK( 1 ) = LWKOPT
122: *
123:          IF( LWORK.LT.MAX( 1, M ) .AND. .NOT.LQUERY ) THEN
124:             INFO = -7
125:          END IF
126:       END IF
127: *
128:       IF( INFO.NE.0 ) THEN
129:          CALL XERBLA( 'SGERQF', -INFO )
130:          RETURN
131:       ELSE IF( LQUERY ) THEN
132:          RETURN
133:       END IF
134: *
135: *     Quick return if possible
136: *
137:       IF( K.EQ.0 ) THEN
138:          RETURN
139:       END IF
140: *
141:       NBMIN = 2
142:       NX = 1
143:       IWS = M
144:       IF( NB.GT.1 .AND. NB.LT.K ) THEN
145: *
146: *        Determine when to cross over from blocked to unblocked code.
147: *
148:          NX = MAX( 0, ILAENV( 3, 'SGERQF', ' ', M, N, -1, -1 ) )
149:          IF( NX.LT.K ) THEN
150: *
151: *           Determine if workspace is large enough for blocked code.
152: *
153:             LDWORK = M
154:             IWS = LDWORK*NB
155:             IF( LWORK.LT.IWS ) THEN
156: *
157: *              Not enough workspace to use optimal NB:  reduce NB and
158: *              determine the minimum value of NB.
159: *
160:                NB = LWORK / LDWORK
161:                NBMIN = MAX( 2, ILAENV( 2, 'SGERQF', ' ', M, N, -1,
162:      $                 -1 ) )
163:             END IF
164:          END IF
165:       END IF
166: *
167:       IF( NB.GE.NBMIN .AND. NB.LT.K .AND. NX.LT.K ) THEN
168: *
169: *        Use blocked code initially.
170: *        The last kk rows are handled by the block method.
171: *
172:          KI = ( ( K-NX-1 ) / NB )*NB
173:          KK = MIN( K, KI+NB )
174: *
175:          DO 10 I = K - KK + KI + 1, K - KK + 1, -NB
176:             IB = MIN( K-I+1, NB )
177: *
178: *           Compute the RQ factorization of the current block
179: *           A(m-k+i:m-k+i+ib-1,1:n-k+i+ib-1)
180: *
181:             CALL SGERQ2( IB, N-K+I+IB-1, A( M-K+I, 1 ), LDA, TAU( I ),
182:      $                   WORK, IINFO )
183:             IF( M-K+I.GT.1 ) THEN
184: *
185: *              Form the triangular factor of the block reflector
186: *              H = H(i+ib-1) . . . H(i+1) H(i)
187: *
188:                CALL SLARFT( 'Backward', 'Rowwise', N-K+I+IB-1, IB,
189:      $                      A( M-K+I, 1 ), LDA, TAU( I ), WORK, LDWORK )
190: *
191: *              Apply H to A(1:m-k+i-1,1:n-k+i+ib-1) from the right
192: *
193:                CALL SLARFB( 'Right', 'No transpose', 'Backward',
194:      $                      'Rowwise', M-K+I-1, N-K+I+IB-1, IB,
195:      $                      A( M-K+I, 1 ), LDA, WORK, LDWORK, A, LDA,
196:      $                      WORK( IB+1 ), LDWORK )
197:             END IF
198:    10    CONTINUE
199:          MU = M - K + I + NB - 1
200:          NU = N - K + I + NB - 1
201:       ELSE
202:          MU = M
203:          NU = N
204:       END IF
205: *
206: *     Use unblocked code to factor the last or only block
207: *
208:       IF( MU.GT.0 .AND. NU.GT.0 )
209:      $   CALL SGERQ2( MU, NU, A, LDA, TAU, WORK, IINFO )
210: *
211:       WORK( 1 ) = IWS
212:       RETURN
213: *
214: *     End of SGERQF
215: *
216:       END
217: