001:       SUBROUTINE SGBTRS( TRANS, N, KL, KU, NRHS, AB, LDAB, IPIV, B, LDB,
002:      $                   INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          TRANS
010:       INTEGER            INFO, KL, KU, LDAB, LDB, N, NRHS
011: *     ..
012: *     .. Array Arguments ..
013:       INTEGER            IPIV( * )
014:       REAL               AB( LDAB, * ), B( LDB, * )
015: *     ..
016: *
017: *  Purpose
018: *  =======
019: *
020: *  SGBTRS solves a system of linear equations
021: *     A * X = B  or  A' * X = B
022: *  with a general band matrix A using the LU factorization computed
023: *  by SGBTRF.
024: *
025: *  Arguments
026: *  =========
027: *
028: *  TRANS   (input) CHARACTER*1
029: *          Specifies the form of the system of equations.
030: *          = 'N':  A * X = B  (No transpose)
031: *          = 'T':  A'* X = B  (Transpose)
032: *          = 'C':  A'* X = B  (Conjugate transpose = Transpose)
033: *
034: *  N       (input) INTEGER
035: *          The order of the matrix A.  N >= 0.
036: *
037: *  KL      (input) INTEGER
038: *          The number of subdiagonals within the band of A.  KL >= 0.
039: *
040: *  KU      (input) INTEGER
041: *          The number of superdiagonals within the band of A.  KU >= 0.
042: *
043: *  NRHS    (input) INTEGER
044: *          The number of right hand sides, i.e., the number of columns
045: *          of the matrix B.  NRHS >= 0.
046: *
047: *  AB      (input) REAL array, dimension (LDAB,N)
048: *          Details of the LU factorization of the band matrix A, as
049: *          computed by SGBTRF.  U is stored as an upper triangular band
050: *          matrix with KL+KU superdiagonals in rows 1 to KL+KU+1, and
051: *          the multipliers used during the factorization are stored in
052: *          rows KL+KU+2 to 2*KL+KU+1.
053: *
054: *  LDAB    (input) INTEGER
055: *          The leading dimension of the array AB.  LDAB >= 2*KL+KU+1.
056: *
057: *  IPIV    (input) INTEGER array, dimension (N)
058: *          The pivot indices; for 1 <= i <= N, row i of the matrix was
059: *          interchanged with row IPIV(i).
060: *
061: *  B       (input/output) REAL array, dimension (LDB,NRHS)
062: *          On entry, the right hand side matrix B.
063: *          On exit, the solution matrix X.
064: *
065: *  LDB     (input) INTEGER
066: *          The leading dimension of the array B.  LDB >= max(1,N).
067: *
068: *  INFO    (output) INTEGER
069: *          = 0:  successful exit
070: *          < 0: if INFO = -i, the i-th argument had an illegal value
071: *
072: *  =====================================================================
073: *
074: *     .. Parameters ..
075:       REAL               ONE
076:       PARAMETER          ( ONE = 1.0E+0 )
077: *     ..
078: *     .. Local Scalars ..
079:       LOGICAL            LNOTI, NOTRAN
080:       INTEGER            I, J, KD, L, LM
081: *     ..
082: *     .. External Functions ..
083:       LOGICAL            LSAME
084:       EXTERNAL           LSAME
085: *     ..
086: *     .. External Subroutines ..
087:       EXTERNAL           SGEMV, SGER, SSWAP, STBSV, XERBLA
088: *     ..
089: *     .. Intrinsic Functions ..
090:       INTRINSIC          MAX, MIN
091: *     ..
092: *     .. Executable Statements ..
093: *
094: *     Test the input parameters.
095: *
096:       INFO = 0
097:       NOTRAN = LSAME( TRANS, 'N' )
098:       IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'T' ) .AND. .NOT.
099:      $    LSAME( TRANS, 'C' ) ) THEN
100:          INFO = -1
101:       ELSE IF( N.LT.0 ) THEN
102:          INFO = -2
103:       ELSE IF( KL.LT.0 ) THEN
104:          INFO = -3
105:       ELSE IF( KU.LT.0 ) THEN
106:          INFO = -4
107:       ELSE IF( NRHS.LT.0 ) THEN
108:          INFO = -5
109:       ELSE IF( LDAB.LT.( 2*KL+KU+1 ) ) THEN
110:          INFO = -7
111:       ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
112:          INFO = -10
113:       END IF
114:       IF( INFO.NE.0 ) THEN
115:          CALL XERBLA( 'SGBTRS', -INFO )
116:          RETURN
117:       END IF
118: *
119: *     Quick return if possible
120: *
121:       IF( N.EQ.0 .OR. NRHS.EQ.0 )
122:      $   RETURN
123: *
124:       KD = KU + KL + 1
125:       LNOTI = KL.GT.0
126: *
127:       IF( NOTRAN ) THEN
128: *
129: *        Solve  A*X = B.
130: *
131: *        Solve L*X = B, overwriting B with X.
132: *
133: *        L is represented as a product of permutations and unit lower
134: *        triangular matrices L = P(1) * L(1) * ... * P(n-1) * L(n-1),
135: *        where each transformation L(i) is a rank-one modification of
136: *        the identity matrix.
137: *
138:          IF( LNOTI ) THEN
139:             DO 10 J = 1, N - 1
140:                LM = MIN( KL, N-J )
141:                L = IPIV( J )
142:                IF( L.NE.J )
143:      $            CALL SSWAP( NRHS, B( L, 1 ), LDB, B( J, 1 ), LDB )
144:                CALL SGER( LM, NRHS, -ONE, AB( KD+1, J ), 1, B( J, 1 ),
145:      $                    LDB, B( J+1, 1 ), LDB )
146:    10       CONTINUE
147:          END IF
148: *
149:          DO 20 I = 1, NRHS
150: *
151: *           Solve U*X = B, overwriting B with X.
152: *
153:             CALL STBSV( 'Upper', 'No transpose', 'Non-unit', N, KL+KU,
154:      $                  AB, LDAB, B( 1, I ), 1 )
155:    20    CONTINUE
156: *
157:       ELSE
158: *
159: *        Solve A'*X = B.
160: *
161:          DO 30 I = 1, NRHS
162: *
163: *           Solve U'*X = B, overwriting B with X.
164: *
165:             CALL STBSV( 'Upper', 'Transpose', 'Non-unit', N, KL+KU, AB,
166:      $                  LDAB, B( 1, I ), 1 )
167:    30    CONTINUE
168: *
169: *        Solve L'*X = B, overwriting B with X.
170: *
171:          IF( LNOTI ) THEN
172:             DO 40 J = N - 1, 1, -1
173:                LM = MIN( KL, N-J )
174:                CALL SGEMV( 'Transpose', LM, NRHS, -ONE, B( J+1, 1 ),
175:      $                     LDB, AB( KD+1, J ), 1, ONE, B( J, 1 ), LDB )
176:                L = IPIV( J )
177:                IF( L.NE.J )
178:      $            CALL SSWAP( NRHS, B( L, 1 ), LDB, B( J, 1 ), LDB )
179:    40       CONTINUE
180:          END IF
181:       END IF
182:       RETURN
183: *
184: *     End of SGBTRS
185: *
186:       END
187: