001:       SUBROUTINE DTPTRI( UPLO, DIAG, N, AP, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
005: *     November 2006
006: *
007: *     .. Scalar Arguments ..
008:       CHARACTER          DIAG, UPLO
009:       INTEGER            INFO, N
010: *     ..
011: *     .. Array Arguments ..
012:       DOUBLE PRECISION   AP( * )
013: *     ..
014: *
015: *  Purpose
016: *  =======
017: *
018: *  DTPTRI computes the inverse of a real upper or lower triangular
019: *  matrix A stored in packed format.
020: *
021: *  Arguments
022: *  =========
023: *
024: *  UPLO    (input) CHARACTER*1
025: *          = 'U':  A is upper triangular;
026: *          = 'L':  A is lower triangular.
027: *
028: *  DIAG    (input) CHARACTER*1
029: *          = 'N':  A is non-unit triangular;
030: *          = 'U':  A is unit triangular.
031: *
032: *  N       (input) INTEGER
033: *          The order of the matrix A.  N >= 0.
034: *
035: *  AP      (input/output) DOUBLE PRECISION array, dimension (N*(N+1)/2)
036: *          On entry, the upper or lower triangular matrix A, stored
037: *          columnwise in a linear array.  The j-th column of A is stored
038: *          in the array AP as follows:
039: *          if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
040: *          if UPLO = 'L', AP(i + (j-1)*((2*n-j)/2) = A(i,j) for j<=i<=n.
041: *          See below for further details.
042: *          On exit, the (triangular) inverse of the original matrix, in
043: *          the same packed storage format.
044: *
045: *  INFO    (output) INTEGER
046: *          = 0:  successful exit
047: *          < 0:  if INFO = -i, the i-th argument had an illegal value
048: *          > 0:  if INFO = i, A(i,i) is exactly zero.  The triangular
049: *                matrix is singular and its inverse can not be computed.
050: *
051: *  Further Details
052: *  ===============
053: *
054: *  A triangular matrix A can be transferred to packed storage using one
055: *  of the following program segments:
056: *
057: *  UPLO = 'U':                      UPLO = 'L':
058: *
059: *        JC = 1                           JC = 1
060: *        DO 2 J = 1, N                    DO 2 J = 1, N
061: *           DO 1 I = 1, J                    DO 1 I = J, N
062: *              AP(JC+I-1) = A(I,J)              AP(JC+I-J) = A(I,J)
063: *      1    CONTINUE                    1    CONTINUE
064: *           JC = JC + J                      JC = JC + N - J + 1
065: *      2 CONTINUE                       2 CONTINUE
066: *
067: *  =====================================================================
068: *
069: *     .. Parameters ..
070:       DOUBLE PRECISION   ONE, ZERO
071:       PARAMETER          ( ONE = 1.0D+0, ZERO = 0.0D+0 )
072: *     ..
073: *     .. Local Scalars ..
074:       LOGICAL            NOUNIT, UPPER
075:       INTEGER            J, JC, JCLAST, JJ
076:       DOUBLE PRECISION   AJJ
077: *     ..
078: *     .. External Functions ..
079:       LOGICAL            LSAME
080:       EXTERNAL           LSAME
081: *     ..
082: *     .. External Subroutines ..
083:       EXTERNAL           DSCAL, DTPMV, XERBLA
084: *     ..
085: *     .. Executable Statements ..
086: *
087: *     Test the input parameters.
088: *
089:       INFO = 0
090:       UPPER = LSAME( UPLO, 'U' )
091:       NOUNIT = LSAME( DIAG, 'N' )
092:       IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
093:          INFO = -1
094:       ELSE IF( .NOT.NOUNIT .AND. .NOT.LSAME( DIAG, 'U' ) ) THEN
095:          INFO = -2
096:       ELSE IF( N.LT.0 ) THEN
097:          INFO = -3
098:       END IF
099:       IF( INFO.NE.0 ) THEN
100:          CALL XERBLA( 'DTPTRI', -INFO )
101:          RETURN
102:       END IF
103: *
104: *     Check for singularity if non-unit.
105: *
106:       IF( NOUNIT ) THEN
107:          IF( UPPER ) THEN
108:             JJ = 0
109:             DO 10 INFO = 1, N
110:                JJ = JJ + INFO
111:                IF( AP( JJ ).EQ.ZERO )
112:      $            RETURN
113:    10       CONTINUE
114:          ELSE
115:             JJ = 1
116:             DO 20 INFO = 1, N
117:                IF( AP( JJ ).EQ.ZERO )
118:      $            RETURN
119:                JJ = JJ + N - INFO + 1
120:    20       CONTINUE
121:          END IF
122:          INFO = 0
123:       END IF
124: *
125:       IF( UPPER ) THEN
126: *
127: *        Compute inverse of upper triangular matrix.
128: *
129:          JC = 1
130:          DO 30 J = 1, N
131:             IF( NOUNIT ) THEN
132:                AP( JC+J-1 ) = ONE / AP( JC+J-1 )
133:                AJJ = -AP( JC+J-1 )
134:             ELSE
135:                AJJ = -ONE
136:             END IF
137: *
138: *           Compute elements 1:j-1 of j-th column.
139: *
140:             CALL DTPMV( 'Upper', 'No transpose', DIAG, J-1, AP,
141:      $                  AP( JC ), 1 )
142:             CALL DSCAL( J-1, AJJ, AP( JC ), 1 )
143:             JC = JC + J
144:    30    CONTINUE
145: *
146:       ELSE
147: *
148: *        Compute inverse of lower triangular matrix.
149: *
150:          JC = N*( N+1 ) / 2
151:          DO 40 J = N, 1, -1
152:             IF( NOUNIT ) THEN
153:                AP( JC ) = ONE / AP( JC )
154:                AJJ = -AP( JC )
155:             ELSE
156:                AJJ = -ONE
157:             END IF
158:             IF( J.LT.N ) THEN
159: *
160: *              Compute elements j+1:n of j-th column.
161: *
162:                CALL DTPMV( 'Lower', 'No transpose', DIAG, N-J,
163:      $                     AP( JCLAST ), AP( JC+1 ), 1 )
164:                CALL DSCAL( N-J, AJJ, AP( JC+1 ), 1 )
165:             END IF
166:             JCLAST = JC
167:             JC = JC - N + J - 2
168:    40    CONTINUE
169:       END IF
170: *
171:       RETURN
172: *
173: *     End of DTPTRI
174: *
175:       END
176: